Volume_Weighted_Average_Price

ÿþ//+------------------------------------------------------------------+

//|                                Volume_Weighted_Average_Price.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property description "Volume Weighted Average Price indicator"

#property indicator_chart_window

#property indicator_buffers 3

#property indicator_plots   1

//--- plot VWAP

#property indicator_label1  "VWAP"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- input parameters

input uint     InpPeriod   =  14;   // Period

//--- indicator buffers

double         BufferVWAP[];

double         BufferMedian[];

double         BufferVolRAW[];

//--- global variables

int            period_ma;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- set global variables

   period_ma=int(InpPeriod<1 ? 1 : InpPeriod);

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferVWAP,INDICATOR_DATA);

   SetIndexBuffer(1,BufferMedian,INDICATOR_CALCULATIONS);

   SetIndexBuffer(2,BufferVolRAW,INDICATOR_CALCULATIONS);

//--- setting indicator parameters

   IndicatorSetString(INDICATOR_SHORTNAME,"Volume Weighted Average Price ("+(string)period_ma+")");

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- setting plot buffer parameters

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,period_ma);

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferVWAP,true);

   ArraySetAsSeries(BufferMedian,true);

   ArraySetAsSeries(BufferVolRAW,true);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- #AB0=>2:0 <0AA82>2 1CD5@>2 :0: B09<A5@89

   ArraySetAsSeries(high,true);

   ArraySetAsSeries(low,true);

   ArraySetAsSeries(tick_volume,true);

//--- @>25@:0 :>;8G5AB20 4>ABC?=KE 10@>2

   if(rates_total<fmax(period_ma,4)) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-1;

      ArrayInitialize(BufferVWAP,EMPTY_VALUE);

      ArrayInitialize(BufferMedian,0);

      ArrayInitialize(BufferVolRAW,0);

     }

     

//--- >43>B>2:0 40==KE

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      BufferMedian[i]=((high[i]+low[i])/2.0)*tick_volume[i];

      BufferVolRAW[i]=(double)tick_volume[i];

     }



//---  0AGQB 8=48:0B>@0

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      double volume_sum=GetSMA(rates_total,i,period_ma,BufferVolRAW)*period_ma;

      double total_sum=GetSMA(rates_total,i,period_ma,BufferMedian)*period_ma;

      BufferVWAP[i]=(volume_sum!=0 ? total_sum/volume_sum : EMPTY_VALUE);

     }

   

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Simple Moving Average                                            |

//+------------------------------------------------------------------+

double GetSMA(const int rates_total,const int index,const int period,const double &price[],const bool as_series=true)

  {

//---

   double result=0.0;

//--- check position

   bool check_index=(as_series ? index<=rates_total-period-1 : index>=period-1);

   if(period<1 || !check_index)

      return 0;

//--- calculate value

   for(int i=0; i<period; i++)

      result+=(as_series ? price[index+i]: price[index-i]);

//---

   return(result/period);

  }

//+------------------------------------------------------------------+