Two MAOnRSI

ÿþ//+------------------------------------------------------------------+

//|                                                  Two MAOnRSI.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                      https://www.mql5.com/en/users/barabashkakvn |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2021, Vladimir Karputov"

#property link      "https://www.mql5.com/en/users/barabashkakvn"

#property version   "1.000"

#property indicator_separate_window

#property indicator_minimum 0

#property indicator_maximum 100

#property indicator_level1  30

#property indicator_level2  70

#property indicator_buffers 2

#property indicator_plots   2

//--- plot RSI_Fast

#property indicator_label1  "RSI Fast OnMA"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot RSI_Slow

#property indicator_label2  "RSI Slow OnMA"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- input parameters

input group             "MA"

input int                  Inp_MA_ma_period           = 3;           // MA: averaging period

input ENUM_MA_METHOD       Inp_MA_ma_method           = MODE_SMA;    // MA: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_applied_price       = PRICE_CLOSE; // MA: type of price

input group             "RSI Fast and Slow"

input int                  Inp_RSI_Fast_ma_period     = 3;            // RSI Fast: averaging period

input ENUM_APPLIED_PRICE   Inp_RSI_Fast_applied_price = PRICE_CLOSE;  // RSI Fast: type of price

input int                  Inp_RSI_Slow_ma_period     = 14;           // RSI Slow: averaging period

input ENUM_APPLIED_PRICE   Inp_RSI_Slow_applied_price = PRICE_CLOSE;  // RSI Slow: type of price

//--- indicator buffers

double   MA_OnFastRSI[];

double   MA_OnSlowRSI[];

//---

int      handle_iRSI_Fast;                      // variable for storing the handle of the iRSI indicator

int      handle_iRSI_Slow;                      // variable for storing the handle of the iRSI indicator

int      handle_iMA_OnFastRSI;                  // variable for storing the handle of the iMA indicator

int      handle_iMA_OnSlowRSI;                  // variable for storing the handle of the iMA indicator

int      bars_calculated            = 0;        // we will keep the number of values in the Moving Average Index indicator

bool     m_init_error               = false;    // error on InInit

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,MA_OnFastRSI,INDICATOR_DATA);

   SetIndexBuffer(1,MA_OnSlowRSI,INDICATOR_DATA);

//--- set accuracy

   IndicatorSetInteger(INDICATOR_DIGITS,2);

//--- sets first bar from what index will be drawn

   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,Inp_RSI_Fast_ma_period);

   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,Inp_RSI_Slow_ma_period);

//--- name for DataWindow and indicator subwindow label

   PlotIndexSetString(0,PLOT_LABEL,"MA On Fast RSI("+IntegerToString(Inp_RSI_Fast_ma_period)+","+EnumToString(Inp_RSI_Fast_applied_price)+")");

   PlotIndexSetString(1,PLOT_LABEL,"MA On Slow RSI("+IntegerToString(Inp_RSI_Slow_ma_period)+","+EnumToString(Inp_RSI_Slow_applied_price)+")");

//--- create handle of the indicator iRSI

   handle_iRSI_Fast=iRSI(Symbol(),Period(),Inp_RSI_Fast_ma_period,Inp_MA_applied_price);

//--- if the handle is not created

   if(handle_iRSI_Fast==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iRSI indicator ('Fast') for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator iRSI

   handle_iRSI_Slow=iRSI(Symbol(),Period(),Inp_RSI_Slow_ma_period,Inp_MA_applied_price);

//--- if the handle is not created

   if(handle_iRSI_Slow==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iRSI indicator ('Slow') for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator iMA

   handle_iMA_OnFastRSI=iMA(Symbol(),Period(),Inp_MA_ma_period,0,

                            Inp_MA_ma_method,handle_iRSI_Fast);

//--- if the handle is not created

   if(handle_iMA_OnFastRSI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator ('Fast') for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator iMA

   handle_iMA_OnSlowRSI=iMA(Symbol(),Period(),Inp_MA_ma_period,0,

                            Inp_MA_ma_method,handle_iRSI_Slow);

//--- if the handle is not created

   if(handle_iMA_OnSlowRSI==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA indicator ('Slow') for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- number of values copied from the iRSI indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   ResetLastError();

   int calculated_fast=BarsCalculated(handle_iRSI_Fast);

   if(calculated_fast<=0)

     {

      PrintFormat("BarsCalculated(handle_iRSI_Fast) returned %d, error code %d",calculated_fast,GetLastError());

      return(0);

     }

   ResetLastError();

   int calculated_slow=BarsCalculated(handle_iRSI_Fast);

   if(calculated_slow<=0)

     {

      PrintFormat("BarsCalculated(handle_iRSI_Fast) returned %d, error code %d",calculated_slow,GetLastError());

      return(0);

     }

   if(calculated_fast!=calculated_slow)

     {

      PrintFormat("BarsCalculated(handle_iRSI_Fast) returned %d, BarsCalculated(handle_iRSI_Fast) returned %d",calculated_fast,calculated_slow);

      return(0);

     }

   int calculated=calculated_fast;

//--- if it is the first start of calculation of the indicator or if the number of values in the iRSI indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iRSIBuffer array is greater than the number of values in the iRSI indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iMABuffer array with values of the Moving Average indicator

//--- if FillArrayFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArrayFromBuffer(MA_OnFastRSI,0,handle_iMA_OnFastRSI,values_to_copy))

      return(0);

   if(!FillArrayFromBuffer(MA_OnSlowRSI,0,handle_iMA_OnSlowRSI,values_to_copy))

      return(0);

//--- memorize the number of values in the Relative Strength Index indicator

   bars_calculated=calculated;

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the MA indicator                  |

//+------------------------------------------------------------------+

bool FillArrayFromBuffer(double &values[],   // indicator buffer of Moving Average values

                         int shift,          // shift

                         int ind_handle,     // handle of the iMA indicator

                         int amount          // number of copied values

                        )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iMABuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,-shift,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iMA indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iRSI_Fast!=INVALID_HANDLE)

      IndicatorRelease(handle_iRSI_Fast);

   if(handle_iRSI_Slow!=INVALID_HANDLE)

      IndicatorRelease(handle_iRSI_Slow);

   if(handle_iMA_OnFastRSI!=INVALID_HANDLE)

      IndicatorRelease(handle_iMA_OnFastRSI);

   if(handle_iMA_OnSlowRSI!=INVALID_HANDLE)

      IndicatorRelease(handle_iMA_OnSlowRSI);

  }

//+------------------------------------------------------------------+