Two Horizontal Line

ÿþ//+------------------------------------------------------------------+

//|                                          Two Horizontal Line.mq5 |

//|                              Copyright © 2019, Vladimir Karputov |

//|                                           http://wmua.ru/slesar/ |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2019, Vladimir Karputov"

#property link      "http://wmua.ru/slesar/"

#property version   "1.005"

/*

   barabashkakvn Trading engine 3.035

*/

#include <Trade\PositionInfo.mqh>

#include <Trade\Trade.mqh>

#include <Trade\SymbolInfo.mqh>

#include <Trade\AccountInfo.mqh>

#include <Trade\DealInfo.mqh>

#include <Trade\OrderInfo.mqh>

#include <Expert\Money\MoneyFixedMargin.mqh>

CPositionInfo  m_position;                   // trade position object

CTrade         m_array_trade[];              // dynamic array of pointers to instances of CTrade class

CSymbolInfo    m_array_symbol[];             // dynamic array of pointers to instances of CSymbolInfo class

CAccountInfo   m_account;                    // account info wrapper

CDealInfo      m_deal;                       // deals object

COrderInfo     m_order;                      // pending orders object

CMoneyFixedMargin m_array_money[];           // dynamic array of pointers to instances of CMoneyFixedMargin class

//+------------------------------------------------------------------+

//| Enum Lor or Risk                                                 |

//+------------------------------------------------------------------+

enum ENUM_LOT_OR_RISK

  {

   lots_min=0, // Lots Min

   lot=1,      // Constant lot

   risk=2,     // Risk in percent for a deal

  };

//--- input parameters

input ushort   InpStopLoss          = 0;           // Stop Loss, in pips (1.00045-1.00055=1 pips)

input ushort   InpTakeProfit        = 0;           // Take Profit, in pips (1.00045-1.00055=1 pips)

input ushort   InpTrailingFrequency = 9;           // Trailing, in seconds (< "10" -> only on a new bar)

input ushort   InpSignalsFrequency  = 10;          // Search signals, in seconds (< "10" -> only on a new bar)

input ushort   InpTrailingStop      = 0;           // Trailing Stop (min distance from price to Stop Loss, in pips

input ushort   InpTrailingStep      = 5;           // Trailing Step, in pips (1.00045-1.00055=1 pips)

input ENUM_LOT_OR_RISK InpLotOrRisk = risk;        // Money management: Lot OR Risk

input double   InpVolumeLotOrRisk   = 3.0;         // The value for "Money management"

//---

input bool     InpCurrenBarZero     = true;        // Current Bar #0

input string   InpLineUPName        = "UP";        // Horizontal Line "UP" Name

input string   InpLineDOWNName      = "DOWN";      // Horizontal Line "DOWN" Name

input ENUM_TIMEFRAMES InpWorkTimeFrame=PERIOD_CURRENT;// Work Time Frame

//---

input bool     InpOnlyOne           = true;        // Only one positions

input bool     InpReverse           = false;       // Reverse

input bool     InpCloseOpposite     = false;       // Close opposite

input bool     InpPrintLog          = false;       // Print log

input ulong    InpMagicUP           = 312169352;   // Magic UP number

input ulong    InpMagicDOWN         = 312169353;   // Magic DOWN number

//---

ulong  ExtSlippage=10;              // Slippage



double ExtStopLoss      = 0.0;      // Stop Loss      -> double

double ExtTakeProfit    = 0.0;      // Take Profit    -> double

double ExtTrailingStop  = 0.0;      // Trailing Stop  -> double

double ExtTrailingStep  = 0.0;      // Trailing Step  -> double



double   array_ExtAdjustedPoint[];           // point value adjusted for 3 or 5 points

bool     ExtNeedCloseAll         = false;    //

bool     ExtNeedCloseBuyUP       = false;    //

bool     ExtNeedCloseSellUP      = false;    //

bool     ExtNeedCloseBuyDOWN     = false;    //

bool     ExtNeedCloseSellDOWN    = false;    //

datetime ExtLastTrailing         = 0;        // "0" -> D'1970.01.01 00:00';

datetime ExtLastSignals          = 0;        // "0" -> D'1970.01.01 00:00';

datetime ExtPrevBars             = 0;        // "0" -> D'1970.01.01 00:00';

datetime ExtPrevBarsD1           = 0;        // "0" -> D'1970.01.01 00:00';

//--- B0:B8:0 B0:0O: 4;O ?>78F89 65AB:> >BA;568205< @57C;LB0B ***

//+------------------------------------------------------------------+

//| Structure Need Positions                                         |

//+------------------------------------------------------------------+

struct STRUCT_NEED_POSITION

  {

   ENUM_POSITION_TYPE pos_type;              // position type

   double            volume;                 // position volume (if "0.0" -> the lot is "Money management")

   CSymbolInfo       *symbol;                 // position symbol

   CMoneyFixedMargin *money;                 // money

   CTrade            *trade;                  // trade

   double            lot_coefficient;        // lot coefficient

   double            stop_loss;              // position stop loss, in pips * ExtAdjustedPoint (if "0.0" -> the ExtStopLoss)

   double            take_profit;            // position take profit, in pips * ExtAdjustedPoint (if "0.0" -> the ExtTakeProfit)

   string            comment;                // position comment

   bool              waiting_transaction;    // waiting transaction, "true" -> it's forbidden to trade, we expect a transaction

   ulong             waiting_order_ticket;   // waiting order ticket, ticket of the expected order

   bool              transaction_confirmed;  // transaction confirmed, "true" -> transaction confirmed

   ulong             magic;                  // magic

   //--- Constructor

                     STRUCT_NEED_POSITION()

     {

      pos_type                   = WRONG_VALUE;

      volume                     = 0.0;

      lot_coefficient            = 0.0;

      stop_loss                  = 0.0;

      take_profit                = 0.0;

      comment                    = "";

      waiting_transaction        = false;

      waiting_order_ticket       = 0;

      transaction_confirmed      = false;

      magic                      = 0;

     }

  };

STRUCT_NEED_POSITION SNeedPosition[];

//+------------------------------------------------------------------+

//| Expert initialization function                                   |

//+------------------------------------------------------------------+

int OnInit()

  {

//---

   if(InpTrailingStop!=0 && InpTrailingStep==0)

     {

      string err_text=(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")?

                      ""@59;8=3 =52>7<>65=: ?0@0<5B@ \"Trailing Step\" @025= =C;N!":

                      "Trailing is not possible: parameter \"Trailing Step\" is zero!";

      //--- when testing, we will only output to the log about incorrect input parameters

      if(MQLInfoInteger(MQL_TESTER))

        {

         Print(__FUNCTION__,", ERROR: ",err_text);

         return(INIT_FAILED);

        }

      else // if the Expert Advisor is run on the chart, tell the user about the error

        {

         Alert(__FUNCTION__,", ERROR: ",err_text);

         return(INIT_PARAMETERS_INCORRECT);

        }

     }

//---

   CSymbolInfo   *symbol_info;

   int size_symbol=ArraySize(m_array_symbol);

   for(int i=0; i<size_symbol; i++)

     {

      symbol_info=GetPointer(m_array_symbol[i]);

      if(CheckPointer(symbol_info)!=POINTER_INVALID)

         delete symbol_info;

     }

   ArrayFree(m_array_symbol);

//---

   CMoneyFixedMargin   *money_fixed_margin;

   int size_money=ArraySize(m_array_money);

   for(int i=0; i<size_money; i++)

     {

      money_fixed_margin=GetPointer(m_array_money[i]);

      if(CheckPointer(money_fixed_margin)!=POINTER_INVALID)

         delete money_fixed_margin;

     }

   ArrayFree(m_array_money);

//---

   CTrade   *trade;

   int size_trade=ArraySize(m_array_trade);

   for(int i=0; i<size_trade; i++)

     {

      trade=GetPointer(m_array_trade[i]);

      if(CheckPointer(trade)!=POINTER_INVALID)

         delete trade;

     }

   ArrayFree(m_array_trade);



   ArrayResize(m_array_symbol,1);

   if(!m_array_symbol[0].Name(Symbol())) // sets symbol name

      return(INIT_FAILED);

   RefreshRates(m_array_symbol[0]);

//---

   ArrayResize(m_array_trade,2);

   m_array_trade[0].SetExpertMagicNumber(InpMagicUP);

   m_array_trade[0].SetMarginMode();

   m_array_trade[0].SetTypeFillingBySymbol(m_array_symbol[0].Name());

   m_array_trade[0].SetDeviationInPoints(ExtSlippage);

   m_array_trade[1].SetExpertMagicNumber(InpMagicDOWN);

   m_array_trade[1].SetMarginMode();

   m_array_trade[1].SetTypeFillingBySymbol(m_array_symbol[0].Name());

   m_array_trade[1].SetDeviationInPoints(ExtSlippage);

//--- tuning for 3 or 5 digits

   ArrayResize(array_ExtAdjustedPoint,1);

   int digits_adjust=1;

   if(m_array_symbol[0].Digits()==3 || m_array_symbol[0].Digits()==5)

      digits_adjust=10;

   array_ExtAdjustedPoint[0]=m_array_symbol[0].Point()*digits_adjust;



   ExtStopLoss       = InpStopLoss        * array_ExtAdjustedPoint[0];

   ExtTakeProfit     = InpTakeProfit      * array_ExtAdjustedPoint[0];

   ExtTrailingStop   = InpTrailingStop    * array_ExtAdjustedPoint[0];

   ExtTrailingStep   = InpTrailingStep    * array_ExtAdjustedPoint[0];

//--- check the input parameter "Lots"

   string err_text="";

   if(InpLotOrRisk==lot)

     {

      if(!CheckVolumeValue(InpVolumeLotOrRisk,err_text,m_array_symbol[0]))

        {

         //--- when testing, we will only output to the log about incorrect input parameters

         if(MQLInfoInteger(MQL_TESTER))

           {

            Print(__FUNCTION__,", ERROR: ",err_text);

            return(INIT_FAILED);

           }

         else // if the Expert Advisor is run on the chart, tell the user about the error

           {

            Alert(__FUNCTION__,", ERROR: ",err_text);

            return(INIT_PARAMETERS_INCORRECT);

           }

        }

     }

   else

      if(InpLotOrRisk==risk)

        {

         ArrayResize(m_array_money,1);

         if(InpVolumeLotOrRisk<1 || InpVolumeLotOrRisk>100)

           {

            Print("The value for \"Money management\" (",DoubleToString(InpVolumeLotOrRisk,2),") -> invalid parameters");

            Print("   parameter must be in the range: from 1.00 to 100.00");

            return(INIT_FAILED);

           }

         if(!m_array_money[0].Init(GetPointer(m_array_symbol[0]),Period(),m_array_symbol[0].Point()*digits_adjust))

            return(INIT_FAILED);

         m_array_money[0].Percent(InpVolumeLotOrRisk);

        }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Expert deinitialization function                                 |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

//---



  }

//+------------------------------------------------------------------+

//| Expert tick function                                             |

//+------------------------------------------------------------------+

void OnTick()

  {

//--- need close all

   if(ExtNeedCloseAll)

     {

      if(IsPositionExists(m_array_symbol[0]))

        {

         double level;

         if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

           {

            CloseAllPositions(level,m_array_symbol[0],m_array_trade[0]);

            return;

           }

         else

            return;

        }

      else

         ExtNeedCloseAll=false;

     }

//--- need close XXXX UP

   if(ExtNeedCloseBuyUP || ExtNeedCloseSellUP)

     {

      int count_buys = 0;

      double volume_buys   = 0.0;

      double volume_biggest_buys = 0.0;

      int count_sells= 0;

      double volume_sells  = 0.0;

      double volume_biggest_sells= 0.0;

      CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                            count_sells,volume_sells,volume_biggest_sells,

                            m_array_symbol[0],InpMagicUP);

      if(ExtNeedCloseBuyUP)

        {

         if(count_buys>0)

           {

            double level;

            if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

              {

               ClosePositions(POSITION_TYPE_BUY,level,m_array_symbol[0],m_array_trade[0],InpMagicUP);

               return;

              }

            else

               return;

           }

         else

            ExtNeedCloseBuyUP=false;

        }



      if(ExtNeedCloseSellUP)

        {

         if(count_sells>0)

           {

            double level;

            if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

              {

               ClosePositions(POSITION_TYPE_SELL,level,m_array_symbol[0],m_array_trade[0],InpMagicUP);

               return;

              }

            else

               return;

           }

         else

            ExtNeedCloseSellUP=false;

        }

     }

//--- need close XXXX DOWN

   if(ExtNeedCloseBuyDOWN || ExtNeedCloseSellDOWN)

     {

      int count_buys = 0;

      double volume_buys   = 0.0;

      double volume_biggest_buys = 0.0;

      int count_sells= 0;

      double volume_sells  = 0.0;

      double volume_biggest_sells= 0.0;

      CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                            count_sells,volume_sells,volume_biggest_sells,

                            m_array_symbol[0],InpMagicDOWN);

      if(ExtNeedCloseBuyDOWN)

        {

         if(count_buys>0)

           {

            double level;

            if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

              {

               ClosePositions(POSITION_TYPE_BUY,level,m_array_symbol[0],m_array_trade[1],InpMagicDOWN);

               return;

              }

            else

               return;

           }

         else

            ExtNeedCloseBuyDOWN=false;

        }



      if(ExtNeedCloseSellDOWN)

        {

         if(count_sells>0)

           {

            double level;

            if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

              {

               ClosePositions(POSITION_TYPE_SELL,level,m_array_symbol[0],m_array_trade[1],InpMagicDOWN);

               return;

              }

            else

               return;

           }

         else

            ExtNeedCloseSellDOWN=false;

        }

     }

//---

   int size_need_position=ArraySize(SNeedPosition);

   if(size_need_position>0)

     {

      for(int i=size_need_position-1; i>=0; i--)

        {

         if(SNeedPosition[i].waiting_transaction)

           {

            if(!SNeedPosition[i].transaction_confirmed)

              {

               Print("transaction_confirmed: ",SNeedPosition[i].transaction_confirmed);

               return;

              }

            else

               if(SNeedPosition[i].transaction_confirmed)

                 {

                  ArrayRemove(SNeedPosition,i,1);

                  return;

                 }

           }

         if(SNeedPosition[i].pos_type==POSITION_TYPE_BUY)

           {

            if(InpCloseOpposite || InpOnlyOne)

              {

               int count_buys=0;

               double volume_buys=0.0;

               double volume_biggest_buys=0.0;

               int count_sells=0;

               double volume_sells=0.0;

               double volume_biggest_sells=0.0;

               CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                                     count_sells,volume_sells,volume_biggest_sells,

                                     SNeedPosition[i].symbol,SNeedPosition[i].magic);

               if(InpCloseOpposite)

                 {

                  if(count_sells>0)

                    {

                     double level;

                     if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

                        ClosePositions(POSITION_TYPE_SELL,level,

                                       SNeedPosition[i].symbol,SNeedPosition[i].trade,

                                       SNeedPosition[i].magic);

                     return;

                    }

                 }

               if(InpOnlyOne)

                 {

                  if(count_buys+count_sells==0)

                    {

                     double level;

                     if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

                       {

                        SNeedPosition[i].waiting_transaction=true;

                        OpenPosition(i,level);

                       }

                     return;

                    }

                  else

                     ArrayRemove(SNeedPosition,i,1);

                  return;

                 }

              }

            double level;

            if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

              {

               SNeedPosition[i].waiting_transaction=true;

               OpenPosition(i,level);

              }

            return;

           }

         if(SNeedPosition[i].pos_type==POSITION_TYPE_SELL)

           {

            if(InpCloseOpposite || InpOnlyOne)

              {

               int count_buys=0;

               double volume_buys=0.0;

               double volume_biggest_buys=0.0;

               int count_sells=0;

               double volume_sells=0.0;

               double volume_biggest_sells=0.0;

               CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                                     count_sells,volume_sells,volume_biggest_sells,

                                     SNeedPosition[i].symbol,SNeedPosition[i].magic);

               if(InpCloseOpposite)

                 {

                  if(count_buys>0)

                    {

                     double level;

                     if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

                        ClosePositions(POSITION_TYPE_BUY,level,

                                       SNeedPosition[i].symbol,SNeedPosition[i].trade,

                                       SNeedPosition[i].magic);

                     return;

                    }

                 }

               if(InpOnlyOne)

                 {

                  if(count_buys+count_sells==0)

                    {

                     double level;

                     if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

                       {

                        SNeedPosition[i].waiting_transaction=true;

                        OpenPosition(i,level);

                       }

                     return;

                    }

                  else

                     ArrayRemove(SNeedPosition,i,1);

                  return;

                 }

              }

            double level;

            if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

              {

               SNeedPosition[i].waiting_transaction=true;

               OpenPosition(i,level);

              }

            return;

           }

        }

     }

//--- if time >=23:58 -> close all position

   MqlDateTime STimeCurrent;

   TimeToStruct(TimeCurrent(),STimeCurrent);

   if(STimeCurrent.hour==23 && STimeCurrent.min>=58)

     {

      ExtNeedCloseAll=true;

      return;

     }

//---

   if(InpTrailingFrequency>=10) // trailing no more than once every 10 seconds

     {

      datetime time_current=TimeCurrent();

      if(time_current-ExtLastTrailing>10)

        {

         double level;

         if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

            Trailing(level,m_array_symbol[0],m_array_trade[0]);

         else

            return;

         ExtLastTrailing=time_current;

        }

     }

   if(InpSignalsFrequency>=10) // search for trading signals no more than once every 10 seconds

     {

      datetime time_current=TimeCurrent();

      if(time_current-ExtLastSignals>10)

        {

         //--- search for trading signals

         if(!RefreshRates(m_array_symbol[0]))

           {

            ExtPrevBars=0;

            return;

           }

         if(!SearchTradingSignals())

           {

            ExtPrevBars=0;

            return;

           }

         ExtLastSignals=time_current;

        }

     }

//--- we work only at the time of the birth of new bar

   datetime time_0=iTime(m_array_symbol[0].Name(),InpWorkTimeFrame,0);

   if(time_0==ExtPrevBars)

      return;

   ExtPrevBars=time_0;

   if(InpTrailingFrequency<10) // trailing only at the time of the birth of new bar

     {

      double level;

      if(FreezeStopsLevels(level,m_array_symbol[0],array_ExtAdjustedPoint[0]))

         Trailing(level,m_array_symbol[0],m_array_trade[0]);

     }

   if(InpSignalsFrequency<10) // search for trading signals only at the time of the birth of new bar

     {

      if(!RefreshRates(m_array_symbol[0]))

        {

         ExtPrevBars=0;

         return;

        }

      //--- search for trading signals

      if(!SearchTradingSignals())

        {

         ExtPrevBars=0;

         return;

        }

     }

//---

  }

//+------------------------------------------------------------------+

//| TradeTransaction function                                        |

//+------------------------------------------------------------------+

void OnTradeTransaction(const MqlTradeTransaction &trans,

                        const MqlTradeRequest &request,

                        const MqlTradeResult &result)

  {

//--- get transaction type as enumeration value

   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;

//--- if transaction is result of addition of the transaction in history

   if(type==TRADE_TRANSACTION_DEAL_ADD)

     {

      long     deal_ticket       =0;

      long     deal_order        =0;

      long     deal_time         =0;

      long     deal_time_msc     =0;

      long     deal_type         =-1;

      long     deal_entry        =-1;

      long     deal_magic        =0;

      long     deal_reason       =-1;

      long     deal_position_id  =0;

      double   deal_volume       =0.0;

      double   deal_price        =0.0;

      double   deal_commission   =0.0;

      double   deal_swap         =0.0;

      double   deal_profit       =0.0;

      string   deal_symbol       ="";

      string   deal_comment      ="";

      string   deal_external_id  ="";

      if(HistoryDealSelect(trans.deal))

        {

         deal_ticket       =HistoryDealGetInteger(trans.deal,DEAL_TICKET);

         deal_order        =HistoryDealGetInteger(trans.deal,DEAL_ORDER);

         deal_time         =HistoryDealGetInteger(trans.deal,DEAL_TIME);

         deal_time_msc     =HistoryDealGetInteger(trans.deal,DEAL_TIME_MSC);

         deal_type         =HistoryDealGetInteger(trans.deal,DEAL_TYPE);

         deal_entry        =HistoryDealGetInteger(trans.deal,DEAL_ENTRY);

         deal_magic        =HistoryDealGetInteger(trans.deal,DEAL_MAGIC);

         deal_reason       =HistoryDealGetInteger(trans.deal,DEAL_REASON);

         deal_position_id  =HistoryDealGetInteger(trans.deal,DEAL_POSITION_ID);



         deal_volume       =HistoryDealGetDouble(trans.deal,DEAL_VOLUME);

         deal_price        =HistoryDealGetDouble(trans.deal,DEAL_PRICE);

         deal_commission   =HistoryDealGetDouble(trans.deal,DEAL_COMMISSION);

         deal_swap         =HistoryDealGetDouble(trans.deal,DEAL_SWAP);

         deal_profit       =HistoryDealGetDouble(trans.deal,DEAL_PROFIT);



         deal_symbol       =HistoryDealGetString(trans.deal,DEAL_SYMBOL);

         deal_comment      =HistoryDealGetString(trans.deal,DEAL_COMMENT);

         deal_external_id  =HistoryDealGetString(trans.deal,DEAL_EXTERNAL_ID);

        }

      else

         return;

      ENUM_DEAL_ENTRY enum_deal_entry=(ENUM_DEAL_ENTRY)deal_entry;

      if(deal_symbol==m_array_symbol[0].Name() && (deal_magic==InpMagicUP || deal_magic==InpMagicDOWN))

        {

         if(deal_type==DEAL_TYPE_BUY || deal_type==DEAL_TYPE_SELL)

           {

            int size_need_position=ArraySize(SNeedPosition);

            if(size_need_position>0)

              {

               for(int i=0; i<size_need_position; i++)

                 {

                  if(SNeedPosition[i].waiting_transaction)

                     if(SNeedPosition[i].waiting_order_ticket==deal_order)

                       {

                        Print(__FUNCTION__," Transaction confirmed");

                        SNeedPosition[i].transaction_confirmed=true;

                        break;

                       }

                 }

              }

           }

        }

     }

  }

//+------------------------------------------------------------------+

//| Refreshes the symbol quotes data                                 |

//+------------------------------------------------------------------+

bool RefreshRates(CSymbolInfo &symbol)

  {

//--- refresh rates

   if(!symbol.RefreshRates())

     {

      Print("RefreshRates error");

      return(false);

     }

//--- protection against the return value of "zero"

   if(symbol.Ask()==0 || symbol.Bid()==0)

      return(false);

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Check the correctness of the position volume                     |

//+------------------------------------------------------------------+

bool CheckVolumeValue(double volume,string &error_description,CSymbolInfo &symbol)

  {

//--- minimal allowed volume for trade operations

   double min_volume=symbol.LotsMin();

   if(volume<min_volume)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< <5=LH5 <8=8<0;L=> 4>?CAB8<>3> SYMBOL_VOLUME_MIN=%.2f",min_volume);

      else

         error_description=StringFormat("Volume is less than the minimal allowed SYMBOL_VOLUME_MIN=%.2f",min_volume);

      return(false);

     }

//--- maximal allowed volume of trade operations

   double max_volume=symbol.LotsMax();

   if(volume>max_volume)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< 1>;LH5 <0:A8<0;L=> 4>?CAB8<>3> SYMBOL_VOLUME_MAX=%.2f",max_volume);

      else

         error_description=StringFormat("Volume is greater than the maximal allowed SYMBOL_VOLUME_MAX=%.2f",max_volume);

      return(false);

     }

//--- get minimal step of volume changing

   double volume_step=symbol.LotsStep();

   int ratio=(int)MathRound(volume/volume_step);

   if(MathAbs(ratio*volume_step-volume)>0.0000001)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< =5 :@0B5= <8=8<0;L=><C H03C SYMBOL_VOLUME_STEP=%.2f, 1;8609H89 ?@028;L=K9 >1J5< %.2f",

                                        volume_step,ratio*volume_step);

      else

         error_description=StringFormat("Volume is not a multiple of the minimal step SYMBOL_VOLUME_STEP=%.2f, the closest correct volume is %.2f",

                                        volume_step,ratio*volume_step);

      return(false);

     }

   error_description="Correct volume value";

   return(true);

  }

//+------------------------------------------------------------------+

//| Lot Check                                                        |

//+------------------------------------------------------------------+

double LotCheck(double lots,CSymbolInfo &symbol)

  {

//--- calculate maximum volume

   double volume=NormalizeDouble(lots,2);

   double stepvol=symbol.LotsStep();

   if(stepvol>0.0)

      volume=stepvol*MathFloor(volume/stepvol);

//---

   double minvol=symbol.LotsMin();

   if(volume<minvol)

      volume=0.0;

//---

   double maxvol=symbol.LotsMax();

   if(volume>maxvol)

      volume=maxvol;

   return(volume);

  }

//+------------------------------------------------------------------+

//| Check Freeze and Stops levels                                    |

//+------------------------------------------------------------------+

bool FreezeStopsLevels(double &level,CSymbolInfo &symbol,const double ExtAdjustedPoint)

  {

//--- check Freeze and Stops levels

   /*

      Type of order/position  |  Activation price  |  Check

      ------------------------|--------------------|--------------------------------------------

      Buy Limit order         |  Ask               |  Ask-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

      Buy Stop order          |  Ask               |  OpenPrice-Ask  >= SYMBOL_TRADE_FREEZE_LEVEL

      Sell Limit order        |  Bid               |  OpenPrice-Bid  >= SYMBOL_TRADE_FREEZE_LEVEL

      Sell Stop order         |  Bid               |  Bid-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

      Buy position            |  Bid               |  TakeProfit-Bid >= SYMBOL_TRADE_FREEZE_LEVEL

                              |                    |  Bid-StopLoss   >= SYMBOL_TRADE_FREEZE_LEVEL

      Sell position           |  Ask               |  Ask-TakeProfit >= SYMBOL_TRADE_FREEZE_LEVEL

                              |                    |  StopLoss-Ask   >= SYMBOL_TRADE_FREEZE_LEVEL



      Buying is done at the Ask price                 |  Selling is done at the Bid price

      ------------------------------------------------|----------------------------------

      TakeProfit        >= Bid                        |  TakeProfit        <= Ask

      StopLoss          <= Bid                        |  StopLoss          >= Ask

      TakeProfit - Bid  >= SYMBOL_TRADE_STOPS_LEVEL   |  Ask - TakeProfit  >= SYMBOL_TRADE_STOPS_LEVEL

      Bid - StopLoss    >= SYMBOL_TRADE_STOPS_LEVEL   |  StopLoss - Ask    >= SYMBOL_TRADE_STOPS_LEVEL

   */

   if(!RefreshRates(symbol) || !symbol.Refresh())

      return(false);

//--- FreezeLevel -> for pending order and modification

   double freeze_level=symbol.FreezeLevel()*symbol.Point();

   if(freeze_level==0.0)

      freeze_level=(symbol.Ask()-symbol.Bid())*3.0;

//--- StopsLevel -> for TakeProfit and StopLoss

   double stop_level=symbol.StopsLevel()*symbol.Point();

   if(stop_level==0.0)

      stop_level=(symbol.Ask()-symbol.Bid())*3.0;



   if(freeze_level<=0.0 || stop_level<=0.0)

      return(false);



   level=(freeze_level>stop_level)?freeze_level:stop_level;



   double spread=symbol.Spread()*ExtAdjustedPoint;

   level=(level>spread)?level:spread;

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Open position                                                    |

//|   double stop_loss                                               |

//|      -> pips * ExtAdjustedPoint (if "0.0" -> the ExtStopLoss)    |

//|   double take_profit                                             |

//|      -> pips * ExtAdjustedPoint (if "0.0" -> the ExtTakeProfit)  |

//+------------------------------------------------------------------+

void OpenPosition(const int index,const double level)

  {

   /*

      Buying is done at the Ask price                 |  Selling is done at the Bid price

      ------------------------------------------------|----------------------------------

      TakeProfit        >= Bid                        |  TakeProfit        <= Ask

      StopLoss          <= Bid                        |  StopLoss          >= Ask

      TakeProfit - Bid  >= SYMBOL_TRADE_STOPS_LEVEL   |  Ask - TakeProfit  >= SYMBOL_TRADE_STOPS_LEVEL

      Bid - StopLoss    >= SYMBOL_TRADE_STOPS_LEVEL   |  StopLoss - Ask    >= SYMBOL_TRADE_STOPS_LEVEL

   */

//--- buy

   if(SNeedPosition[index].pos_type==POSITION_TYPE_BUY)

     {

      double sl=SNeedPosition[index].stop_loss;

      if(sl<=0.0)

         sl=0.0;

      else

         if(SNeedPosition[index].symbol.Bid()-sl<level)

            sl=SNeedPosition[index].symbol.Bid()-level;



      double tp=SNeedPosition[index].take_profit;

      if(tp<=0.0)

         tp=0.0;

      else

         if(tp-SNeedPosition[index].symbol.Ask()<level)

            tp=SNeedPosition[index].symbol.Ask()+level;



      OpenBuy(index,sl,tp);

      return;

     }

//--- sell

   if(SNeedPosition[index].pos_type==POSITION_TYPE_SELL)

     {

      double sl=SNeedPosition[index].stop_loss;

      if(sl<=0.0)

         sl=0.0;

      else

         if(sl-SNeedPosition[index].symbol.Ask()<level)

            sl=SNeedPosition[index].symbol.Ask()+level;



      double tp=SNeedPosition[index].take_profit;

      if(tp<=0.0)

         tp=0.0;

      else

         if(SNeedPosition[index].symbol.Bid()-tp<level)

            tp=SNeedPosition[index].symbol.Bid()-level;



      OpenSell(index,sl,tp);

      return;

     }

  }

//+------------------------------------------------------------------+

//| Open Buy position                                                |

//+------------------------------------------------------------------+

void OpenBuy(const int index,double sl,double tp)

  {

   SNeedPosition[index].trade.SetExpertMagicNumber(SNeedPosition[index].magic);

   sl=SNeedPosition[index].symbol.NormalizePrice(sl);

   tp=SNeedPosition[index].symbol.NormalizePrice(tp);



   double long_lot=0.0;

   if(SNeedPosition[index].volume>0.0)

      long_lot=SNeedPosition[index].volume;

   else

     {

      if(InpLotOrRisk==risk)

        {

         long_lot=SNeedPosition[index].money.CheckOpenLong(SNeedPosition[index].symbol.Ask(),sl);

         if(InpPrintLog)

            Print("sl=",DoubleToString(sl,SNeedPosition[index].symbol.Digits()),

                  ", CheckOpenLong: ",DoubleToString(long_lot,2),

                  ", Balance: ",    DoubleToString(m_account.Balance(),2),

                  ", Equity: ",     DoubleToString(m_account.Equity(),2),

                  ", FreeMargin: ", DoubleToString(m_account.FreeMargin(),2));

         if(long_lot==0.0)

           {

            ArrayRemove(SNeedPosition,index,1);

            if(InpPrintLog)

               Print(__FUNCTION__,", ERROR: method CheckOpenLong returned the value of 0.0");

            return;

           }

        }

      else

         if(InpLotOrRisk==lot)

            long_lot=InpVolumeLotOrRisk;

         else

            if(InpLotOrRisk==lots_min)

               long_lot=SNeedPosition[index].symbol.LotsMin();

            else

              {

               ArrayRemove(SNeedPosition,index,1);

               return;

              }

     }

   if(SNeedPosition[index].lot_coefficient>0.0)

     {

      long_lot=LotCheck(long_lot*SNeedPosition[index].lot_coefficient,

                        SNeedPosition[index].symbol);

      if(long_lot==0)

        {

         ArrayRemove(SNeedPosition,index,1);

         if(InpPrintLog)

            Print(__FUNCTION__,", ERROR: LotCheck returned the 0.0");

         return;

        }

     }



   if(SNeedPosition[index].symbol.LotsLimit()>0.0)

     {

      int count_buys = 0;

      double volume_buys   = 0.0;

      double volume_biggest_buys = 0.0;

      int count_sells= 0;

      double volume_sells  = 0.0;

      double volume_biggest_sells= 0.0;

      CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                            count_sells,volume_sells,volume_biggest_sells,

                            SNeedPosition[index].symbol,SNeedPosition[index].magic);

      if(volume_buys+volume_sells+long_lot>SNeedPosition[index].symbol.LotsLimit())

        {

         ArrayRemove(SNeedPosition,index,1);

         Print("#0 Buy, Volume Buy (",DoubleToString(volume_buys,2),

               ") + Volume Sell (",DoubleToString(volume_sells,2),

               ") + Volume long (",DoubleToString(long_lot,2),

               ") > Lots Limit (",DoubleToString(SNeedPosition[index].symbol.LotsLimit(),2),")");

         return;

        }

     }

//--- check volume before OrderSend to avoid "not enough money" error (CTrade)

   double free_margin_check=m_account.FreeMarginCheck(SNeedPosition[index].symbol.Name(),

                            ORDER_TYPE_BUY,

                            long_lot,

                            SNeedPosition[index].symbol.Ask());

   double margin_check=m_account.MarginCheck(SNeedPosition[index].symbol.Name(),

                       ORDER_TYPE_SELL,

                       long_lot,

                       SNeedPosition[index].symbol.Bid());

   if(free_margin_check>margin_check)

     {

      if(SNeedPosition[index].trade.Buy(long_lot,SNeedPosition[index].symbol.Name(),

                                        SNeedPosition[index].symbol.Ask(),sl,tp,SNeedPosition[index].comment)) // CTrade::Buy -> "true"

        {

         if(SNeedPosition[index].trade.ResultDeal()==0)

           {

            if(SNeedPosition[index].trade.ResultRetcode()==10009) // trade order went to the exchange

              {

               SNeedPosition[index].waiting_transaction=true;

               SNeedPosition[index].waiting_order_ticket=SNeedPosition[index].trade.ResultOrder();

              }

            else

              {

               SNeedPosition[index].waiting_transaction=false;

               if(InpPrintLog)

                  Print("#1 Buy -> false. Result Retcode: ",SNeedPosition[index].trade.ResultRetcode(),

                        ", description of result: ",SNeedPosition[index].trade.ResultRetcodeDescription());

              }

            if(InpPrintLog)

               PrintResultTrade(SNeedPosition[index].trade,SNeedPosition[index].symbol);

           }

         else

           {

            if(SNeedPosition[index].trade.ResultRetcode()==10009)

              {

               SNeedPosition[index].waiting_transaction=true;

               SNeedPosition[index].waiting_order_ticket=SNeedPosition[index].trade.ResultOrder();

              }

            else

              {

               SNeedPosition[index].waiting_transaction=false;

               if(InpPrintLog)

                  Print("#2 Buy -> true. Result Retcode: ",SNeedPosition[index].trade.ResultRetcode(),

                        ", description of result: ",SNeedPosition[index].trade.ResultRetcodeDescription());

              }

            if(InpPrintLog)

               PrintResultTrade(SNeedPosition[index].trade,SNeedPosition[index].symbol);

           }

        }

      else

        {

         SNeedPosition[index].waiting_transaction=false;

         if(InpPrintLog)

            Print("#3 Buy -> false. Result Retcode: ",SNeedPosition[index].trade.ResultRetcode(),

                  ", description of result: ",SNeedPosition[index].trade.ResultRetcodeDescription());

         if(InpPrintLog)

            PrintResultTrade(SNeedPosition[index].trade,SNeedPosition[index].symbol);

        }

     }

   else

     {

      ArrayRemove(SNeedPosition,index,1);

      if(InpPrintLog)

         Print(__FUNCTION__,", ERROR: method CAccountInfo::FreeMarginCheck returned the value ",DoubleToString(free_margin_check,2));

      return;

     }

//---

  }

//+------------------------------------------------------------------+

//| Open Sell position                                               |

//+------------------------------------------------------------------+

void OpenSell(const int index,double sl,double tp)

  {

   SNeedPosition[index].trade.SetExpertMagicNumber(SNeedPosition[index].magic);

   sl=SNeedPosition[index].symbol.NormalizePrice(sl);

   tp=SNeedPosition[index].symbol.NormalizePrice(tp);



   double short_lot=0.0;

   if(SNeedPosition[index].volume>0.0)

      short_lot=SNeedPosition[index].volume;

   else

     {

      if(InpLotOrRisk==risk)

        {

         short_lot=SNeedPosition[index].money.CheckOpenShort(SNeedPosition[index].symbol.Bid(),sl);

         if(InpPrintLog)

            Print("sl=",DoubleToString(sl,SNeedPosition[index].symbol.Digits()),

                  ", CheckOpenLong: ",DoubleToString(short_lot,2),

                  ", Balance: ",    DoubleToString(m_account.Balance(),2),

                  ", Equity: ",     DoubleToString(m_account.Equity(),2),

                  ", FreeMargin: ", DoubleToString(m_account.FreeMargin(),2));

         if(short_lot==0.0)

           {

            ArrayRemove(SNeedPosition,index,1);

            if(InpPrintLog)

               Print(__FUNCTION__,", ERROR: method CheckOpenShort returned the value of \"0.0\"");

            return;

           }

        }

      else

         if(InpLotOrRisk==lot)

            short_lot=InpVolumeLotOrRisk;

         else

            if(InpLotOrRisk==lots_min)

               short_lot=SNeedPosition[index].symbol.LotsMin();

            else

              {

               ArrayRemove(SNeedPosition,index,1);

               return;

              }

     }

   if(SNeedPosition[index].lot_coefficient>0.0)

     {

      short_lot=LotCheck(short_lot*SNeedPosition[index].lot_coefficient,SNeedPosition[index].symbol);

      if(short_lot==0)

        {

         ArrayRemove(SNeedPosition,index,1);

         if(InpPrintLog)

            Print(__FUNCTION__,", ERROR: LotCheck returned the 0.0");

         return;

        }

     }

   if(SNeedPosition[index].symbol.LotsLimit()>0.0)

     {

      int count_buys=0;

      double volume_buys=0.0;

      double volume_biggest_buys=0.0;

      int count_sells=0;

      double volume_sells=0.0;

      double volume_biggest_sells=0.0;

      CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                            count_sells,volume_sells,volume_biggest_sells,

                            SNeedPosition[index].symbol,SNeedPosition[index].magic);

      if(volume_buys+volume_sells+short_lot>SNeedPosition[index].symbol.LotsLimit())

        {

         ArrayRemove(SNeedPosition,index,1);

         Print("#0 Buy, Volume Buy (",DoubleToString(volume_buys,2),

               ") + Volume Sell (",DoubleToString(volume_sells,2),

               ") + Volume short (",DoubleToString(short_lot,2),

               ") > Lots Limit (",DoubleToString(SNeedPosition[index].symbol.LotsLimit(),2),")");

         return;

        }

     }

//--- check volume before OrderSend to avoid "not enough money" error (CTrade)

   double free_margin_check=m_account.FreeMarginCheck(SNeedPosition[index].symbol.Name(),

                            ORDER_TYPE_SELL,short_lot,SNeedPosition[index].symbol.Bid());

   double margin_check=m_account.MarginCheck(SNeedPosition[index].symbol.Name(),

                       ORDER_TYPE_SELL,short_lot,SNeedPosition[index].symbol.Bid());

   if(free_margin_check>margin_check)

     {

      if(SNeedPosition[index].trade.Sell(short_lot,SNeedPosition[index].symbol.Name(),

                                         SNeedPosition[index].symbol.Bid(),sl,tp,SNeedPosition[index].comment)) // CTrade::Sell -> "true"

        {

         if(SNeedPosition[index].trade.ResultDeal()==0)

           {

            if(SNeedPosition[index].trade.ResultRetcode()==10009) // trade order went to the exchange

              {

               SNeedPosition[index].waiting_transaction=true;

               SNeedPosition[index].waiting_order_ticket=SNeedPosition[index].trade.ResultOrder();

              }

            else

              {

               SNeedPosition[index].waiting_transaction=false;

               if(InpPrintLog)

                  Print("#1 Sell -> false. Result Retcode: ",SNeedPosition[index].trade.ResultRetcode(),

                        ", description of result: ",SNeedPosition[index].trade.ResultRetcodeDescription());

              }

            if(InpPrintLog)

               PrintResultTrade(SNeedPosition[index].trade,SNeedPosition[index].symbol);

           }

         else

           {

            if(SNeedPosition[index].trade.ResultRetcode()==10009)

              {

               SNeedPosition[index].waiting_transaction=true;

               SNeedPosition[index].waiting_order_ticket=SNeedPosition[index].trade.ResultOrder();

              }

            else

              {

               SNeedPosition[index].waiting_transaction=false;

               if(InpPrintLog)

                  Print("#2 Sell -> true. Result Retcode: ",SNeedPosition[index].trade.ResultRetcode(),

                        ", description of result: ",SNeedPosition[index].trade.ResultRetcodeDescription());

              }

            if(InpPrintLog)

               PrintResultTrade(SNeedPosition[index].trade,SNeedPosition[index].symbol);

           }

        }

      else

        {

         SNeedPosition[index].waiting_transaction=false;

         if(InpPrintLog)

            Print("#3 Sell -> false. Result Retcode: ",SNeedPosition[index].trade.ResultRetcode(),

                  ", description of result: ",SNeedPosition[index].trade.ResultRetcodeDescription());

         if(InpPrintLog)

            PrintResultTrade(SNeedPosition[index].trade,SNeedPosition[index].symbol);

        }

     }

   else

     {

      ArrayRemove(SNeedPosition,index,1);

      if(InpPrintLog)

         Print(__FUNCTION__,", ERROR: method CAccountInfo::FreeMarginCheck returned the value ",DoubleToString(free_margin_check,2));

      return;

     }

//---

  }

//+------------------------------------------------------------------+

//| Print CTrade result                                              |

//+------------------------------------------------------------------+

void PrintResultTrade(CTrade &trade,CSymbolInfo &symbol)

  {

   Print("File: ",__FILE__,", symbol: ",symbol.Name());

   Print("Code of request result: "+IntegerToString(trade.ResultRetcode()));

   Print("code of request result as a string: "+trade.ResultRetcodeDescription());

   Print("Deal ticket: "+IntegerToString(trade.ResultDeal()));

   Print("Order ticket: "+IntegerToString(trade.ResultOrder()));

   Print("Volume of deal or order: "+DoubleToString(trade.ResultVolume(),2));

   Print("Price, confirmed by broker: "+DoubleToString(trade.ResultPrice(),symbol.Digits()));

   Print("Current bid price: "+DoubleToString(symbol.Bid(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultBid(),symbol.Digits()));

   Print("Current ask price: "+DoubleToString(symbol.Ask(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultAsk(),symbol.Digits()));

   Print("Broker comment: "+trade.ResultComment());

  }

//+------------------------------------------------------------------+

//| Get value of buffers                                             |

//+------------------------------------------------------------------+

double iGetArray(const int handle,const int buffer,const int start_pos,

                 const int count,double &arr_buffer[])

  {

   bool result=true;

   if(!ArrayIsDynamic(arr_buffer))

     {

      Print("This a no dynamic array!");

      return(false);

     }

   ArrayFree(arr_buffer);

//--- reset error code

   ResetLastError();

//--- fill a part of the iBands array with values from the indicator buffer

   int copied=CopyBuffer(handle,buffer,start_pos,count,arr_buffer);

   if(copied!=count)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

   return(result);

  }

//+------------------------------------------------------------------+

//| Trailing                                                         |

//|   InpTrailingStop: min distance from price to Stop Loss          |

//+------------------------------------------------------------------+

void Trailing(const double stop_level,CSymbolInfo &symbol,CTrade &trade)

  {

   /*

      Buying is done at the Ask price                 |  Selling is done at the Bid price

      ------------------------------------------------|----------------------------------

      TakeProfit        >= Bid                        |  TakeProfit        <= Ask

      StopLoss          <= Bid                        |  StopLoss          >= Ask

      TakeProfit - Bid  >= SYMBOL_TRADE_STOPS_LEVEL   |  Ask - TakeProfit  >= SYMBOL_TRADE_STOPS_LEVEL

      Bid - StopLoss    >= SYMBOL_TRADE_STOPS_LEVEL   |  StopLoss - Ask    >= SYMBOL_TRADE_STOPS_LEVEL

   */

   if(InpTrailingStop==0)

      return;

   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of open positions

      if(m_position.SelectByIndex(i))

         if(m_position.Symbol()==symbol.Name() && (m_position.Magic()==InpMagicUP || m_position.Magic()==InpMagicDOWN))

           {

            double price_current = m_position.PriceCurrent();

            double price_open    = m_position.PriceOpen();

            double stop_loss     = m_position.StopLoss();

            double take_profit   = m_position.TakeProfit();

            double ask           = symbol.Ask();

            double bid           = symbol.Ask();

            //---

            if(m_position.PositionType()==POSITION_TYPE_BUY)

              {

               if(price_current-price_open>ExtTrailingStop+ExtTrailingStep)

                  if(stop_loss<price_current-(ExtTrailingStop+ExtTrailingStep))

                     if(ExtTrailingStop>=stop_level && (take_profit-bid>=stop_level || take_profit==0.0))

                       {

                        if(!trade.PositionModify(m_position.Ticket(),

                                                 symbol.NormalizePrice(price_current-ExtTrailingStop),

                                                 take_profit))

                           Print("Modify BUY ",m_position.Ticket(),

                                 " Position -> false. Result Retcode: ",trade.ResultRetcode(),

                                 ", description of result: ",trade.ResultRetcodeDescription());

                        RefreshRates(symbol);

                        m_position.SelectByIndex(i);

                        PrintResultModify(trade,symbol,m_position);

                        continue;

                       }

              }

            else

              {

               if(price_open-price_current>ExtTrailingStop+ExtTrailingStep)

                  if((stop_loss>(price_current+(ExtTrailingStop+ExtTrailingStep))) || (stop_loss==0))

                     if(ExtTrailingStop>=stop_level && ask-take_profit>=stop_level)

                       {

                        if(!trade.PositionModify(m_position.Ticket(),

                                                 symbol.NormalizePrice(price_current+ExtTrailingStop),

                                                 take_profit))

                           Print("Modify SELL ",m_position.Ticket(),

                                 " Position -> false. Result Retcode: ",trade.ResultRetcode(),

                                 ", description of result: ",trade.ResultRetcodeDescription());

                        RefreshRates(symbol);

                        m_position.SelectByIndex(i);

                        PrintResultModify(trade,symbol,m_position);

                       }

              }

           }

  }

//+------------------------------------------------------------------+

//| Print CTrade result                                              |

//+------------------------------------------------------------------+

void PrintResultModify(CTrade &trade,CSymbolInfo &symbol,CPositionInfo &position)

  {

   Print("File: ",__FILE__,", symbol: ",symbol.Name());

   Print("Code of request result: "+IntegerToString(trade.ResultRetcode()));

   Print("code of request result as a string: "+trade.ResultRetcodeDescription());

   Print("Deal ticket: "+IntegerToString(trade.ResultDeal()));

   Print("Order ticket: "+IntegerToString(trade.ResultOrder()));

   Print("Volume of deal or order: "+DoubleToString(trade.ResultVolume(),2));

   Print("Price, confirmed by broker: "+DoubleToString(trade.ResultPrice(),symbol.Digits()));

   Print("Current bid price: "+DoubleToString(symbol.Bid(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultBid(),symbol.Digits()));

   Print("Current ask price: "+DoubleToString(symbol.Ask(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultAsk(),symbol.Digits()));

   Print("Broker comment: "+trade.ResultComment());

   Print("Freeze Level: "+DoubleToString(symbol.FreezeLevel(),0),", Stops Level: "+DoubleToString(symbol.StopsLevel(),0));

   Print("Price of position opening: "+DoubleToString(position.PriceOpen(),symbol.Digits()));

   Print("Price of position's Stop Loss: "+DoubleToString(position.StopLoss(),symbol.Digits()));

   Print("Price of position's Take Profit: "+DoubleToString(position.TakeProfit(),symbol.Digits()));

   Print("Current price by position: "+DoubleToString(position.PriceCurrent(),symbol.Digits()));

  }

//+------------------------------------------------------------------+

//| Close positions                                                  |

//+------------------------------------------------------------------+

void ClosePositions(const ENUM_POSITION_TYPE pos_type,const double level,

                    CSymbolInfo &symbol,CTrade &trade,

                    const ulong magic)

  {

   /*

      Buying is done at the Ask price                 |  Selling is done at the Bid price

      ------------------------------------------------|----------------------------------

      TakeProfit        >= Bid                        |  TakeProfit        <= Ask

      StopLoss          <= Bid                        |  StopLoss          >= Ask

      TakeProfit - Bid  >= SYMBOL_TRADE_STOPS_LEVEL   |  Ask - TakeProfit  >= SYMBOL_TRADE_STOPS_LEVEL

      Bid - StopLoss    >= SYMBOL_TRADE_STOPS_LEVEL   |  StopLoss - Ask    >= SYMBOL_TRADE_STOPS_LEVEL

   */

   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of current positions

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==symbol.Name() && m_position.Magic()==magic)

            if(m_position.PositionType()==pos_type)

              {

               if(m_position.PositionType()==POSITION_TYPE_BUY)

                 {

                  bool take_profit_level=(m_position.TakeProfit()!=0.0 && m_position.TakeProfit()-m_position.PriceCurrent()>=level) || m_position.TakeProfit()==0.0;

                  bool stop_loss_level=(m_position.StopLoss()!=0.0 && m_position.PriceCurrent()-m_position.StopLoss()>=level) || m_position.StopLoss()==0.0;

                  if(take_profit_level && stop_loss_level)

                     trade.PositionClose(m_position.Ticket()); // close a position by the specified symbol

                 }

               if(m_position.PositionType()==POSITION_TYPE_SELL)

                 {

                  bool take_profit_level=(m_position.TakeProfit()!=0.0 && m_position.PriceCurrent()-m_position.TakeProfit()>=level) || m_position.TakeProfit()==0.0;

                  bool stop_loss_level=(m_position.StopLoss()!=0.0 && m_position.StopLoss()-m_position.PriceCurrent()>=level) || m_position.StopLoss()==0.0;

                  if(take_profit_level && stop_loss_level)

                     trade.PositionClose(m_position.Ticket()); // close a position by the specified symbol

                 }

              }

  }

//+------------------------------------------------------------------+

//| Calculate all positions                                          |

//+------------------------------------------------------------------+

void CalculateAllPositions(int &count_buys,double &volume_buys,double &volume_biggest_buys,

                           int &count_sells,double &volume_sells,double &volume_biggest_sells,

                           CSymbolInfo &symbol,const ulong magic)

  {

   count_buys  = 0;

   volume_buys   = 0.0;

   volume_biggest_buys  = 0.0;

   count_sells = 0;

   volume_sells  = 0.0;

   volume_biggest_sells = 0.0;

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==symbol.Name() && m_position.Magic()==magic)

           {

            if(m_position.PositionType()==POSITION_TYPE_BUY)

              {

               count_buys++;

               volume_buys+=m_position.Volume();

               if(m_position.Volume()>volume_biggest_buys)

                  volume_biggest_buys=m_position.Volume();

               continue;

              }

            else

               if(m_position.PositionType()==POSITION_TYPE_SELL)

                 {

                  count_sells++;

                  volume_sells+=m_position.Volume();

                  if(m_position.Volume()>volume_biggest_sells)

                     volume_biggest_sells=m_position.Volume();

                 }

           }

  }

//+------------------------------------------------------------------+

//| Search trading signals                                           |

//+------------------------------------------------------------------+

bool SearchTradingSignals(void)

  {

   MqlRates rates_curr[],rates_h1[],rates_d1[];

   ArraySetAsSeries(rates_curr,true);

   ArraySetAsSeries(rates_h1,true);

   ArraySetAsSeries(rates_d1,true);

   int start_pos=0,count=3;

   if(CopyRates(m_array_symbol[0].Name(),InpWorkTimeFrame,start_pos,count,rates_curr)!=count ||

      CopyRates(m_array_symbol[0].Name(),PERIOD_D1,start_pos,count,rates_d1)!=count)

     {

      return(false);

     }



//--- on period D1 a new day?

   datetime time_0=rates_d1[0].time;

   if(time_0!=ExtPrevBarsD1)

     {

      ExtPrevBarsD1=time_0;

      //--- search for minimum and maximum on H1

      int result=CopyRates(m_array_symbol[0].Name(),PERIOD_H1,rates_d1[1].time,rates_d1[0].time,rates_h1);

      if(result<0)

        {

         ExtPrevBarsD1=0;

         return(false);

        }

      double prev_day_price_max=DBL_MIN,prev_day_price_min=DBL_MAX;

      for(int i=0; i<result; i++)

        {

         if(rates_h1[i].open>rates_h1[i].close)

           {

            if(rates_h1[i].open>prev_day_price_max)

               prev_day_price_max=rates_h1[i].open;

            if(rates_h1[i].close<prev_day_price_min)

               prev_day_price_min=rates_h1[i].close;

           }

         else

           {

            if(rates_h1[i].close>prev_day_price_max)

               prev_day_price_max=rates_h1[i].close;

            if(rates_h1[i].open<prev_day_price_min)

               prev_day_price_min=rates_h1[i].open;

           }

        }

      HLineMove(0,InpLineUPName,prev_day_price_max);

      HLineMove(0,InpLineDOWNName,prev_day_price_min);

     }



   double price_line_up=ObjectGetDouble(0,InpLineUPName,OBJPROP_PRICE);

   double price_line_down=ObjectGetDouble(0,InpLineDOWNName,OBJPROP_PRICE);

   if(price_line_up==0.0 || price_line_down==0.0)

      return(true);

//--- intersection UP

   int current_bar=(InpCurrenBarZero)?0:1;

   if(rates_curr[current_bar].close>price_line_up) // close sell up

      ExtNeedCloseSellUP=true;

   if(rates_curr[current_bar].open<price_line_up && rates_curr[current_bar].close>price_line_up)

     {

      int size_need_position=ArraySize(SNeedPosition);

      ArrayResize(SNeedPosition,size_need_position+1);

      SNeedPosition[size_need_position].pos_type=POSITION_TYPE_BUY;

      SNeedPosition[size_need_position].symbol=GetPointer(m_array_symbol[0]);

      if(InpLotOrRisk==risk)

         SNeedPosition[size_need_position].money=GetPointer(m_array_money[0]);

      SNeedPosition[size_need_position].trade=GetPointer(m_array_trade[0]);

      SNeedPosition[size_need_position].stop_loss=(ExtStopLoss==0.0)?0.0:m_array_symbol[0].Ask()-ExtStopLoss;

      SNeedPosition[size_need_position].take_profit=(ExtTakeProfit==0.0)?0.0:m_array_symbol[0].Ask()+ExtTakeProfit;

      SNeedPosition[size_need_position].comment="UP";

      SNeedPosition[size_need_position].magic=InpMagicUP;

      return(true);

     }

   if(rates_curr[current_bar].close<price_line_up) // close buy up

      ExtNeedCloseBuyUP=true;

   if(rates_curr[current_bar].open>price_line_up && rates_curr[current_bar].close<price_line_up)

     {

      int size_need_position=ArraySize(SNeedPosition);

      ArrayResize(SNeedPosition,size_need_position+1);

      SNeedPosition[size_need_position].pos_type=POSITION_TYPE_SELL;

      SNeedPosition[size_need_position].symbol=GetPointer(m_array_symbol[0]);

      if(InpLotOrRisk==risk)

         SNeedPosition[size_need_position].money=GetPointer(m_array_money[0]);

      SNeedPosition[size_need_position].trade=GetPointer(m_array_trade[0]);

      SNeedPosition[size_need_position].stop_loss=(ExtStopLoss==0.0)?0.0:m_array_symbol[0].Bid()+ExtStopLoss;

      SNeedPosition[size_need_position].take_profit=(ExtTakeProfit==0.0)?0.0:m_array_symbol[0].Bid()-ExtTakeProfit;

      SNeedPosition[size_need_position].comment="UP";

      SNeedPosition[size_need_position].magic=InpMagicUP;

      return(true);

     }

//--- intersection DOWN

   if(rates_curr[current_bar].close>price_line_down) // close sell down

      ExtNeedCloseSellDOWN=true;

   if(rates_curr[current_bar].open<price_line_down && rates_curr[current_bar].close>price_line_down)

     {

      int size_need_position=ArraySize(SNeedPosition);

      ArrayResize(SNeedPosition,size_need_position+1);

      SNeedPosition[size_need_position].pos_type=POSITION_TYPE_BUY;

      SNeedPosition[size_need_position].symbol=GetPointer(m_array_symbol[0]);

      if(InpLotOrRisk==risk)

         SNeedPosition[size_need_position].money=GetPointer(m_array_money[0]);

      SNeedPosition[size_need_position].trade=GetPointer(m_array_trade[1]);

      SNeedPosition[size_need_position].stop_loss=(ExtStopLoss==0.0)?0.0:m_array_symbol[0].Ask()-ExtStopLoss;

      SNeedPosition[size_need_position].take_profit=(ExtTakeProfit==0.0)?0.0:m_array_symbol[0].Ask()+ExtTakeProfit;

      SNeedPosition[size_need_position].comment="DOWN";

      SNeedPosition[size_need_position].magic=InpMagicDOWN;

      return(true);

     }

   if(rates_curr[current_bar].close<price_line_down) // close buy down

      ExtNeedCloseBuyDOWN=true;

   if(rates_curr[current_bar].open>price_line_down && rates_curr[current_bar].close<price_line_down)

     {

      int size_need_position=ArraySize(SNeedPosition);

      ArrayResize(SNeedPosition,size_need_position+1);

      SNeedPosition[size_need_position].pos_type=POSITION_TYPE_SELL;

      SNeedPosition[size_need_position].symbol=GetPointer(m_array_symbol[0]);

      if(InpLotOrRisk==risk)

         SNeedPosition[size_need_position].money=GetPointer(m_array_money[0]);

      SNeedPosition[size_need_position].trade=GetPointer(m_array_trade[1]);

      SNeedPosition[size_need_position].stop_loss=(ExtStopLoss==0.0)?0.0:m_array_symbol[0].Bid()+ExtStopLoss;

      SNeedPosition[size_need_position].take_profit=(ExtTakeProfit==0.0)?0.0:m_array_symbol[0].Bid()-ExtTakeProfit;

      SNeedPosition[size_need_position].comment="DOWN";

      SNeedPosition[size_need_position].magic=InpMagicDOWN;

      return(true);

     }

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Is position exists                                               |

//+------------------------------------------------------------------+

bool IsPositionExists(CSymbolInfo &symbol)

  {

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==symbol.Name() && (m_position.Magic()==InpMagicUP || m_position.Magic()==InpMagicDOWN))

            return(true);

//---

   return(false);

  }

//+------------------------------------------------------------------+

//| Close all positions                                              |

//+------------------------------------------------------------------+

void CloseAllPositions(const double level,CSymbolInfo &symbol,CTrade &trade)

  {

   /*

      Buying is done at the Ask price                 |  Selling is done at the Bid price

      ------------------------------------------------|----------------------------------

      TakeProfit        >= Bid                        |  TakeProfit        <= Ask

      StopLoss          <= Bid                        |  StopLoss          >= Ask

      TakeProfit - Bid  >= SYMBOL_TRADE_STOPS_LEVEL   |  Ask - TakeProfit  >= SYMBOL_TRADE_STOPS_LEVEL

      Bid - StopLoss    >= SYMBOL_TRADE_STOPS_LEVEL   |  StopLoss - Ask    >= SYMBOL_TRADE_STOPS_LEVEL

   */

   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of current positions

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==symbol.Name() && (m_position.Magic()==InpMagicUP || m_position.Magic()==InpMagicDOWN))

           {

            if(m_position.PositionType()==POSITION_TYPE_BUY)

              {

               bool take_profit_level=(m_position.TakeProfit()!=0.0 && m_position.TakeProfit()-m_position.PriceCurrent()>=level) || m_position.TakeProfit()==0.0;

               bool stop_loss_level=(m_position.StopLoss()!=0.0 && m_position.PriceCurrent()-m_position.StopLoss()>=level) || m_position.StopLoss()==0.0;

               if(take_profit_level && stop_loss_level)

                  trade.PositionClose(m_position.Ticket()); // close a position by the specified symbol

              }

            if(m_position.PositionType()==POSITION_TYPE_SELL)

              {

               bool take_profit_level=(m_position.TakeProfit()!=0.0 && m_position.PriceCurrent()-m_position.TakeProfit()>=level) || m_position.TakeProfit()==0.0;

               bool stop_loss_level=(m_position.StopLoss()!=0.0 && m_position.StopLoss()-m_position.PriceCurrent()>=level) || m_position.StopLoss()==0.0;

               if(take_profit_level && stop_loss_level)

                  trade.PositionClose(m_position.Ticket()); // close a position by the specified symbol

              }

           }

  }

//+------------------------------------------------------------------+

//| Move horizontal line                                             |

//+------------------------------------------------------------------+

bool HLineMove(const long   chart_ID=0,   // chart's ID

               const string name="HLine", // line name

               double       price=0)      // line price

  {

//--- if the line price is not set, move it to the current Bid price level

   if(!price)

      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);

//--- reset the error value

   ResetLastError();

//--- move a horizontal line

   if(!ObjectMove(chart_ID,name,0,0,price))

     {

      Print(__FUNCTION__,

            ": failed to move the horizontal line! Error code = ",GetLastError());

      return(false);

     }

//--- successful execution

   return(true);

  }

//+------------------------------------------------------------------+