TSI_Overlay

ÿþ//+------------------------------------------------------------------+

//|                                                  TSI_Overlay.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property description "True Strength Index Overlay indicator"

#property description "TSI: https://www.mql5.com/ru/code/22783"

#property indicator_chart_window

#property indicator_buffers 12

#property indicator_plots   1

//--- plot Label1

#property indicator_label1  "Open;High;Low;Close"

#property indicator_type1   DRAW_COLOR_CANDLES

#property indicator_color1  clrLimeGreen,clrDarkOrange,clrGreen,clrCrimson,clrOrangeRed,clrDarkSeaGreen,clrRed,clrBurlyWood

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- enums

enum ENUM_STATUS_TSI

  {

   STATUS_NULL,

   STATUS_POS_UP,

   STATUS_POS_DN,

   STATUS_OB_UP,

   STATUS_OB_DN,

   STATUS_NEG_DN,

   STATUS_NEG_UP,

   STATUS_OS_DN,

   STATUS_OS_UP,

  };

//--- input parameters

input uint     InpPeriodSm1   =  7;    // TSI First smoothing period

input uint     InpPeriodSm2   =  14;   // TSI Second smoothing period

input double   InpOverbought  =  25.0; // TSI Overbought

input double   InpOversold    = -25.0; // TSI Oversold

//--- indicator buffers

double         BufferCandleO[];

double         BufferCandleH[];

double         BufferCandleL[];

double         BufferCandleC[];

double         BufferColors[];

double         BufferTSI[];

double         BufferUDM[];

double         BufferADM[];

double         BufferUDM1[];

double         BufferUDM2[];

double         BufferADM1[];

double         BufferADM2[];

//--- global variables

double         overbought;

double         oversold;

int            period_sm1;

int            period_sm2;

//--- includes

#include <MovingAverages.mqh>

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- set global variables

   period_sm1=int(InpPeriodSm1<2 ? 2 : InpPeriodSm1);

   period_sm2=int(InpPeriodSm2<2 ? 2 : InpPeriodSm2);

   overbought=(fabs(InpOverbought)<0.1 ? 0.1 : InpOverbought>100.0 ? 100.0 : fabs(InpOverbought));

   oversold=(-fabs(InpOversold)>-0.1 ? -0.1 : -fabs(InpOversold)<-100.0 ? -100.0 : -fabs(InpOversold));

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferCandleO,INDICATOR_DATA);

   SetIndexBuffer(1,BufferCandleH,INDICATOR_DATA);

   SetIndexBuffer(2,BufferCandleL,INDICATOR_DATA);

   SetIndexBuffer(3,BufferCandleC,INDICATOR_DATA);

   SetIndexBuffer(4,BufferColors,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(5,BufferTSI,INDICATOR_CALCULATIONS);

   SetIndexBuffer(6,BufferUDM,INDICATOR_CALCULATIONS);

   SetIndexBuffer(7,BufferUDM1,INDICATOR_CALCULATIONS);

   SetIndexBuffer(8,BufferUDM2,INDICATOR_CALCULATIONS);

   SetIndexBuffer(9,BufferADM,INDICATOR_CALCULATIONS);

   SetIndexBuffer(10,BufferADM1,INDICATOR_CALCULATIONS);

   SetIndexBuffer(11,BufferADM2,INDICATOR_CALCULATIONS);

//--- setting indicator parameters

   IndicatorSetString(INDICATOR_SHORTNAME,"True Strength Index Overlay ("+(string)period_sm1+","+(string)period_sm2+")");

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferCandleO,true);

   ArraySetAsSeries(BufferCandleH,true);

   ArraySetAsSeries(BufferCandleL,true);

   ArraySetAsSeries(BufferCandleC,true);

   ArraySetAsSeries(BufferColors,true);

   ArraySetAsSeries(BufferTSI,true);

   ArraySetAsSeries(BufferUDM,true);

   ArraySetAsSeries(BufferUDM1,true);

   ArraySetAsSeries(BufferUDM2,true);

   ArraySetAsSeries(BufferADM,true);

   ArraySetAsSeries(BufferADM1,true);

   ArraySetAsSeries(BufferADM2,true);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- #AB0=>2:0 <0AA82>2 1CD5@>2 :0: B09<A5@89

   ArraySetAsSeries(open,true);

   ArraySetAsSeries(high,true);

   ArraySetAsSeries(low,true);

   ArraySetAsSeries(close,true);

//--- @>25@:0 :>;8G5AB20 4>ABC?=KE 10@>2

   if(rates_total<2) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-2;

      ArrayInitialize(BufferCandleO,EMPTY_VALUE);

      ArrayInitialize(BufferCandleH,EMPTY_VALUE);

      ArrayInitialize(BufferCandleL,EMPTY_VALUE);

      ArrayInitialize(BufferCandleC,EMPTY_VALUE);

      ArrayInitialize(BufferColors,7);

      ArrayInitialize(BufferTSI,0);

      ArrayInitialize(BufferUDM,0);

      ArrayInitialize(BufferUDM1,0);

      ArrayInitialize(BufferUDM2,0);

      ArrayInitialize(BufferADM,0);

      ArrayInitialize(BufferADM1,0);

      ArrayInitialize(BufferADM2,0);

     }



//--- >43>B>2:0 40==KE

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      BufferUDM[i]=close[i]-close[i+1];

      BufferADM[i]=fabs(BufferUDM[i]);

     }

   if(ExponentialMAOnBuffer(rates_total,prev_calculated,0,period_sm1,BufferUDM,BufferUDM1)==0)

      return 0;

   if(ExponentialMAOnBuffer(rates_total,prev_calculated,0,period_sm1,BufferADM,BufferADM1)==0)

      return 0;

   if(ExponentialMAOnBuffer(rates_total,prev_calculated,period_sm1,period_sm2,BufferUDM1,BufferUDM2)==0)

      return 0;

   if(ExponentialMAOnBuffer(rates_total,prev_calculated,period_sm1,period_sm2,BufferADM1,BufferADM2)==0)

      return 0;

   for(int i=limit; i>=0 && !IsStopped(); i--)

      BufferTSI[i]=(BufferADM2[i]!=0 ? 100.0*BufferUDM2[i]/BufferADM2[i] : 0);

   

//---  0AGQB 8=48:0B>@0

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      BufferCandleO[i]=BufferCandleH[i]=BufferCandleL[i]=BufferCandleC[i]=EMPTY_VALUE;

      ENUM_STATUS_TSI status=StatusTSI(i);

      if(status==STATUS_POS_UP)

        {

         SetCandle(i,open,high,low,close);

         BufferColors[i]=0;

        }

      if(status==STATUS_POS_DN)

        {

         SetCandle(i,open,high,low,close);

         BufferColors[i]=1;

        }

      if(status==STATUS_OB_UP)

        {

         SetCandle(i,open,high,low,close);

         BufferColors[i]=2;

        }

      if(status==STATUS_OB_DN)

        {

         SetCandle(i,open,high,low,close);

         BufferColors[i]=3;

        }

      if(status==STATUS_NEG_DN)

        {

         SetCandle(i,open,high,low,close);

         BufferColors[i]=4;

        }

      if(status==STATUS_NEG_UP)

        {

         SetCandle(i,open,high,low,close);

         BufferColors[i]=5;

        }

      if(status==STATUS_OS_DN)

        {

         SetCandle(i,open,high,low,close);

         BufferColors[i]=6;

        }

      if(status==STATUS_OS_UP)

        {

         SetCandle(i,open,high,low,close);

         BufferColors[i]=7;

        }

     }

   

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| #AB0=02;8205B 1CD5@ A25G8                                        |

//+------------------------------------------------------------------+

void SetCandle(const int shift,const double &open[],const double &high[],const double &low[],const double &close[])

  {

   BufferCandleO[shift]=open[shift];

   BufferCandleH[shift]=high[shift];

   BufferCandleL[shift]=low[shift];

   BufferCandleC[shift]=close[shift];

  }

//+------------------------------------------------------------------+

//| >72@0I05B A>AB>O=85 TSI                                         |

//+------------------------------------------------------------------+

ENUM_STATUS_TSI StatusTSI(const int shift)

  {

   if(BufferTSI[shift]>overbought)

     {

      if(BufferTSI[shift]<BufferTSI[shift+1])

         return(STATUS_OB_DN);

      else

         return(STATUS_OB_UP);

     }

   else if(BufferTSI[shift]<oversold)

     {

      if(BufferTSI[shift]>BufferTSI[shift+1])

         return(STATUS_OS_UP);

      else

         return(STATUS_OS_DN);

     }

   else if(BufferTSI[shift]>0 && BufferTSI[shift]<=overbought)

     {

      if(BufferTSI[shift]>BufferTSI[shift+1])

         return(STATUS_POS_UP);

      else

         return(STATUS_POS_DN);

     }

   else if(BufferTSI[shift]<0 && BufferTSI[shift]>=oversold)

     {

      if(BufferTSI[shift]>BufferTSI[shift+1])

         return(STATUS_NEG_UP);

      else

         return(STATUS_NEG_DN);

     }

   return STATUS_NULL;

  }  

//+------------------------------------------------------------------+