Top_And_Bottom

ÿþ//+------------------------------------------------------------------+

//|                                               Top_And_Bottom.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property description "Top and Bottom indicator"

#property indicator_chart_window

#property indicator_buffers 2

#property indicator_plots   2

//--- plot Top

#property indicator_label1  "Top"

#property indicator_type1   DRAW_ARROW

#property indicator_color1  clrRed

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot Bottom

#property indicator_label2  "Bottom"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrGreen

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- enums

enum ENUM_INPUT_YES_NO

  {

   INPUT_YES   =  1, // Yes

   INPUT_NO    =  0  // No

  };

//--- input parameters

input uint              InpFrames   =  2;          // Frames

input ENUM_INPUT_YES_NO InpUseAlert =  INPUT_YES;  // Show alerts

input ENUM_INPUT_YES_NO InpSendMail =  INPUT_NO;   // Send mails

input ENUM_INPUT_YES_NO InpSendPush =  INPUT_YES;  // Send push-notifications

//--- indicator buffers

double         BufferTop[];

double         BufferBottom[];

//--- global variables

int            frames;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- set global variables

   frames=int(InpFrames<1 ? 1 : InpFrames);

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferTop,INDICATOR_DATA);

   SetIndexBuffer(1,BufferBottom,INDICATOR_DATA);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,159);

   PlotIndexSetInteger(1,PLOT_ARROW,159);

//--- setting indicator parameters

   IndicatorSetString(INDICATOR_SHORTNAME,"Top and Bottom ("+(string)frames+")");

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferTop,true);

   ArraySetAsSeries(BufferBottom,true);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- #AB0=>2:0 <0AA82>2 1CD5@>2 :0: B09<A5@89

   ArraySetAsSeries(high,true);

   ArraySetAsSeries(low,true);

   ArraySetAsSeries(time,true);

//--- @>25@:0 :>;8G5AB20 4>ABC?=KE 10@>2

   if(rates_total<fmax(frames*2,4)) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-frames-2;

      ArrayInitialize(BufferTop,EMPTY_VALUE);

      ArrayInitialize(BufferBottom,EMPTY_VALUE);

     }



//---  0AGQB 8=48:0B>@0

   static datetime last_time=0;

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      BufferBottom[i]=BufferTop[i]=EMPTY_VALUE;

      int start_bar=i+frames+1;



      if(IsTop(rates_total,start_bar,frames,high))

        {

         BufferTop[start_bar]=high[start_bar];

         if(i==0 && time[0]>last_time)

           {

            string message=Symbol()+", "+TimeframeToString(Period())+": Top is found.";

            if(InpUseAlert) Alert(message);

            if(InpSendMail  && TerminalInfoInteger(TERMINAL_EMAIL_ENABLED)) SendMail("Top and Bottom indicator Signal",message);

            if(InpSendPush && TerminalInfoInteger(TERMINAL_NOTIFICATIONS_ENABLED)) SendNotification(message);

            last_time=TimeCurrent();

           }

        }

      else

         BufferTop[start_bar]=EMPTY_VALUE;



      if(IsBottom(rates_total,start_bar,frames,low))

        {

         BufferBottom[start_bar]=low[start_bar];

         if(i==0 && time[0]>last_time)

           {

            string message=Symbol()+", "+TimeframeToString(Period())+": Bottom is found.";

            if(InpUseAlert) Alert(message);

            if(InpSendMail  && TerminalInfoInteger(TERMINAL_EMAIL_ENABLED)) SendMail("Top and Bottom indicator Signal",message);

            if(InpSendPush && TerminalInfoInteger(TERMINAL_NOTIFICATIONS_ENABLED)) SendNotification(message);

            last_time=TimeCurrent();

           }

        }

      else

         BufferBottom[start_bar]=EMPTY_VALUE;

     }



//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

bool IsTop(const int rates_total,const int shift,const int count,const double &high[])

  {

   if(shift+count>rates_total-1)

      return false;

   bool res=true;

   for(int i=1;i<=count;i++)

      if(high[shift-i+1]<=high[shift-i] || high[shift+i-1]<=high[shift+i])

         res=false;

   return res;

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

bool IsBottom(const int rates_total,const int shift,const int count,const double &low[])

  {

   if(shift+count>rates_total-1)

      return false;

   bool res=true;

   for(int i=1;i<=count;i++)

      if(low[shift-i+1]>=low[shift-i] || low[shift+i-1]>=low[shift+i])

         res=false;

   return res;

  }

//+------------------------------------------------------------------+

//| Timeframe to string                                              |

//+------------------------------------------------------------------+

string TimeframeToString(const ENUM_TIMEFRAMES timeframe)

  {

   return StringSubstr(EnumToString(timeframe),7);

  }

//+------------------------------------------------------------------+