Time_Segmented_Volume

ÿþ//+------------------------------------------------------------------+

//|                                        Time_Segmented_Volume.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property description "Time Segmented Volume indicator (TSV)"

#property indicator_separate_window

#property indicator_buffers 4

#property indicator_plots   1

//--- plot SV

#property indicator_label1  "TSV"

#property indicator_type1   DRAW_COLOR_HISTOGRAM

#property indicator_color1  clrGreen,clrRed,clrDarkGray

#property indicator_style1  STYLE_SOLID

#property indicator_width1  8

//--- input parameters

input uint     InpPeriod   =  14;   // Period

//--- indicator buffers

double         BufferTSV[];

double         BufferColors[];

double         BufferTMP[];

double         BufferRAW[];

//--- global variables

int            period_sv;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- set global variables

   period_sv=int(InpPeriod<1 ? 1 : InpPeriod);

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferTSV,INDICATOR_DATA);

   SetIndexBuffer(1,BufferColors,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,BufferTMP,INDICATOR_CALCULATIONS);

   SetIndexBuffer(3,BufferRAW,INDICATOR_CALCULATIONS);

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferTSV,true);

   ArraySetAsSeries(BufferColors,true);

   ArraySetAsSeries(BufferTMP,true);

   ArraySetAsSeries(BufferRAW,true);

//--- setting indicator parameters

   IndicatorSetString(INDICATOR_SHORTNAME,"Time Segmented Volume("+(string)period_sv+")");

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- #AB0=>2:0 <0AA82>2 1CD5@>2 :0: B09<A5@89

   ArraySetAsSeries(open,true);

   ArraySetAsSeries(high,true);

   ArraySetAsSeries(low,true);

   ArraySetAsSeries(close,true);

   ArraySetAsSeries(tick_volume,true);

//--- @>25@:0 :>;8G5AB20 4>ABC?=KE 10@>2

   if(rates_total<fmax(period_sv,4)) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-2;

      ArrayInitialize(BufferTSV,EMPTY_VALUE);

      ArrayInitialize(BufferColors,2);

      ArrayInitialize(BufferTMP,0);

      ArrayInitialize(BufferRAW,0);

     }

//---  0AGQB 8=48:0B>@0

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      BufferTMP[i]=(close[i]>close[i+1] ? tick_volume[i]*(close[i]-close[i+1]) : close[i]<close[i+1] ? -1*tick_volume[i]*(close[i+1]-close[i]) : 0);

      BufferTSV[i]=SMA(rates_total,BufferTMP,period_sv,i)*period_sv;

      BufferColors[i]=(BufferTSV[i]>BufferTSV[i+1] ? 0 : BufferTSV[i]<BufferTSV[i+1] ? 1 : 2);

     }

   

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Simple Moving Average                                            |

//+------------------------------------------------------------------+

double SMA(const int rates_total,const double &array_src[],const int period,const int shift)

  {

   if(period<1 || shift>rates_total-period-1)

      return array_src[shift];

   double sum=0;

   for(int i=0; i<period; i++)

      sum+=array_src[shift+i];

   return(sum/period);

  }

//+------------------------------------------------------------------+