TCI_MTF

ÿþ//+------------------------------------------------------------------+

//|                                                      TCI_MTF.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property description "Multi timeframe Trend Confirmation Indicator"

#property indicator_separate_window

#property indicator_buffers 12

#property indicator_plots   3

//--- plot TCI1

#property indicator_label1  "TCI 1"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrLimeGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot TCI2

#property indicator_label2  "TCI 2"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrDodgerBlue

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- plot TCI3

#property indicator_label3  "TCI 3"

#property indicator_type3   DRAW_LINE

#property indicator_color3  clrOrangeRed

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- enums

enum ENUM_DRAW_MODE

  {

   DRAW_MODE_STEPS,     // Steps

   DRAW_MODE_SLOPE      // Slope

  };

//--- input parameters

input uint                 InpPeriodFast  =  5;                // Fast MA period

input ENUM_MA_METHOD       InpMethodFast  =  MODE_EMA;         // Fast MA method

input ENUM_APPLIED_PRICE   InpPriceFast   =  PRICE_CLOSE;      // Fast MA applied price

input uint                 InpPeriodSlow  =  10;               // Slow MA period

input ENUM_MA_METHOD       InpMethodSlow  =  MODE_EMA;         // Slow MA method

input ENUM_APPLIED_PRICE   InpPriceSlow   =  PRICE_CLOSE;      // Slow MA applied price

input ENUM_TIMEFRAMES      InpTimeframe1  =  PERIOD_H1;        // First TCI timeframe

input ENUM_TIMEFRAMES      InpTimeframe2  =  PERIOD_H4;        // Second TCI timeframe

input ENUM_TIMEFRAMES      InpTimeframe3  =  PERIOD_D1;        // Third TCI timeframe

input ENUM_DRAW_MODE       InpDrawMode    =  DRAW_MODE_STEPS;  // Drawing mode

//--- indicator buffers

double            BufferTCI1[];

double            BufferTCI2[];

double            BufferTCI3[];

double            BufferTCI1tmp[];

double            BufferTCI2tmp[];

double            BufferTCI3tmp[];

double            BufferFMA1[];

double            BufferSMA1[];

double            BufferFMA2[];

double            BufferSMA2[];

double            BufferFMA3[];

double            BufferSMA3[];

//--- global variables

ENUM_TIMEFRAMES   timeframe1;

ENUM_TIMEFRAMES   timeframe2;

ENUM_TIMEFRAMES   timeframe3;

int               period_fast;

int               period_slow;

int               handle_fma1;

int               handle_fma2;

int               handle_fma3;

int               handle_sma1;

int               handle_sma2;

int               handle_sma3;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- timer

   EventSetTimer(90);

//--- set global variables

   period_fast=int(InpPeriodFast<1 ? 1 : InpPeriodFast);

   period_slow=int(InpPeriodSlow<1 ? 1 : InpPeriodSlow);

   timeframe1=(InpTimeframe1>Period() ? InpTimeframe1 : Period());

   timeframe2=(InpTimeframe2>Period() ? InpTimeframe2 : Period());

   timeframe3=(InpTimeframe3>Period() ? InpTimeframe3 : Period());

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferTCI1,INDICATOR_DATA);

   SetIndexBuffer(1,BufferTCI2,INDICATOR_DATA);

   SetIndexBuffer(2,BufferTCI3,INDICATOR_DATA);

   SetIndexBuffer(3,BufferTCI1tmp,INDICATOR_CALCULATIONS);

   SetIndexBuffer(4,BufferTCI2tmp,INDICATOR_CALCULATIONS);

   SetIndexBuffer(5,BufferTCI3tmp,INDICATOR_CALCULATIONS);

   SetIndexBuffer(6,BufferFMA1,INDICATOR_CALCULATIONS);

   SetIndexBuffer(7,BufferFMA2,INDICATOR_CALCULATIONS);

   SetIndexBuffer(8,BufferFMA3,INDICATOR_CALCULATIONS);

   SetIndexBuffer(9,BufferSMA1,INDICATOR_CALCULATIONS);

   SetIndexBuffer(10,BufferSMA2,INDICATOR_CALCULATIONS);

   SetIndexBuffer(11,BufferSMA3,INDICATOR_CALCULATIONS);

//--- setting indicator parameters

   string label=TimeframeToString(timeframe1)+","+TimeframeToString(timeframe2)+","+TimeframeToString(timeframe3)+" TCI ("+(string)period_fast+","+(string)period_slow+")";

   IndicatorSetString(INDICATOR_SHORTNAME,label);

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- setting plot buffer parameters

   PlotIndexSetString(0,PLOT_LABEL,TimeframeToString(timeframe1)+" TCI ("+(string)period_fast+","+(string)period_slow+")");

   PlotIndexSetString(1,PLOT_LABEL,TimeframeToString(timeframe2)+" TCI ("+(string)period_fast+","+(string)period_slow+")");

   PlotIndexSetString(2,PLOT_LABEL,TimeframeToString(timeframe3)+" TCI ("+(string)period_fast+","+(string)period_slow+")");

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferTCI1,true);

   ArraySetAsSeries(BufferTCI2,true);

   ArraySetAsSeries(BufferTCI3,true);

   ArraySetAsSeries(BufferTCI1tmp,true);

   ArraySetAsSeries(BufferTCI2tmp,true);

   ArraySetAsSeries(BufferTCI3tmp,true);

   ArraySetAsSeries(BufferFMA1,true);

   ArraySetAsSeries(BufferFMA2,true);

   ArraySetAsSeries(BufferFMA3,true);

   ArraySetAsSeries(BufferSMA1,true);

   ArraySetAsSeries(BufferSMA2,true);

   ArraySetAsSeries(BufferSMA3,true);

//--- create MA's handle

   ResetLastError();

   handle_fma1=iMA(NULL,timeframe1,period_fast,0,InpMethodFast,InpPriceFast);

   if(handle_fma1==INVALID_HANDLE)

     {

      Print(__LINE__,": The iMA(",TimeframeToString(timeframe1),",",(string)period_fast,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

   handle_fma2=iMA(NULL,timeframe2,period_fast,0,InpMethodFast,InpPriceFast);

   if(handle_fma2==INVALID_HANDLE)

     {

      Print(__LINE__,": The iMA(",TimeframeToString(timeframe2),",",(string)period_fast,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

   handle_fma3=iMA(NULL,timeframe3,period_fast,0,InpMethodFast,InpPriceFast);

   if(handle_fma3==INVALID_HANDLE)

     {

      Print(__LINE__,": The iMA(",TimeframeToString(timeframe3),",",(string)period_fast,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

   handle_sma1=iMA(NULL,timeframe1,period_slow,0,InpMethodSlow,InpPriceSlow);

   if(handle_sma1==INVALID_HANDLE)

     {

      Print(__LINE__,": The iMA(",TimeframeToString(timeframe1),",",(string)period_slow,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

   handle_sma2=iMA(NULL,timeframe2,period_slow,0,InpMethodSlow,InpPriceSlow);

   if(handle_sma2==INVALID_HANDLE)

     {

      Print(__LINE__,": The iMA(",TimeframeToString(timeframe2),",",(string)period_slow,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

   handle_sma3=iMA(NULL,timeframe3,period_slow,0,InpMethodSlow,InpPriceSlow);

   if(handle_sma3==INVALID_HANDLE)

     {

      Print(__LINE__,": The iMA(",TimeframeToString(timeframe3),",",(string)period_slow,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

//--- get timeframe

   Time(NULL,timeframe1,1);

   Time(NULL,timeframe2,1);

   Time(NULL,timeframe3,1);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- @>25@:0 :>;8G5AB20 4>ABC?=KE 10@>2

   if(rates_total<4) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-1;

      ArrayInitialize(BufferTCI1,EMPTY_VALUE);

      ArrayInitialize(BufferTCI2,EMPTY_VALUE);

      ArrayInitialize(BufferTCI3,EMPTY_VALUE);

      ArrayInitialize(BufferTCI1tmp,0);

      ArrayInitialize(BufferTCI2tmp,0);

      ArrayInitialize(BufferTCI3tmp,0);

      ArrayInitialize(BufferFMA1,0);

      ArrayInitialize(BufferFMA2,0);

      ArrayInitialize(BufferFMA3,0);

      ArrayInitialize(BufferSMA1,0);

      ArrayInitialize(BufferSMA2,0);

      ArrayInitialize(BufferSMA3,0);

     }

//--- >43>B>2:0 40==KE

   if(Time(NULL,timeframe1,1)==0 || Time(NULL,timeframe2,1)==0 || Time(NULL,timeframe3,1)==0)

      return 0;

   int bars1=(timeframe1==Period() ? rates_total : Bars(NULL,timeframe1));

   int bars2=(timeframe2==Period() ? rates_total : Bars(NULL,timeframe2));

   int bars3=(timeframe3==Period() ? rates_total : Bars(NULL,timeframe3));

   

   int count1=(limit>1 ? fmin(bars1,rates_total) : 1),copied=0;

   copied=CopyBuffer(handle_fma1,0,0,count1,BufferFMA1);

   if(copied!=count1) return 0;

   copied=CopyBuffer(handle_sma1,0,0,count1,BufferSMA1);

   if(copied!=count1) return 0;

   

   int count2=(limit>1 ? fmin(bars2,rates_total) : 1);

   copied=CopyBuffer(handle_fma2,0,0,count2,BufferFMA2);

   if(copied!=count2) return 0;

   copied=CopyBuffer(handle_sma2,0,0,count2,BufferSMA2);

   if(copied!=count2) return 0;

   

   int count3=(limit>1 ? fmin(bars3,rates_total) : 1);

   copied=CopyBuffer(handle_fma3,0,0,count3,BufferFMA3);

   if(copied!=count3) return 0;

   copied=CopyBuffer(handle_sma3,0,0,count3,BufferSMA3);

   if(copied!=count3) return 0;

   

   for(int i=limit; i>=0; i--)

     {

      BufferTCI1tmp[i]=(BufferSMA1[i]!=0 ? (BufferFMA1[i]/BufferSMA1[i]-1)*100.0 : 0);

      BufferTCI2tmp[i]=(BufferSMA2[i]!=0 ? (BufferFMA2[i]/BufferSMA2[i]-1)*100.0 : 0);

      BufferTCI3tmp[i]=(BufferSMA3[i]!=0 ? (BufferFMA3[i]/BufferSMA3[i]-1)*100.0 : 0);

     }



//---  0AGQB 8=48:0B>@0

   for(int i=limit; i>=0; i--)

     {

      DataConversion(rates_total,NULL,timeframe1,i,BufferTCI1tmp,BufferTCI1,InpDrawMode);

      DataConversion(rates_total,NULL,timeframe2,i,BufferTCI2tmp,BufferTCI2,InpDrawMode);

      DataConversion(rates_total,NULL,timeframe3,i,BufferTCI3tmp,BufferTCI3,InpDrawMode);

     }

   

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Custom indicator timer function                                  |

//+------------------------------------------------------------------+

void OnTimer()

  {

   Time(NULL,timeframe1,1);

   Time(NULL,timeframe2,1);

   Time(NULL,timeframe3,1);

  }  

//+------------------------------------------------------------------+

//| Transfering data from the source timeframe to current timeframe  |

//+------------------------------------------------------------------+

void DataConversion(const int rates_total,

                    const string symbol_name,

                    const ENUM_TIMEFRAMES timeframe_src,

                    const int shift,

                    const double &buffer_src[],

                    double &buffer_dest[],

                    ENUM_DRAW_MODE mode=DRAW_MODE_STEPS

                   )

  {

   if(Time(symbol_name,timeframe_src,shift)==0)

      return;

   if(timeframe_src==Period())

     {

      buffer_dest[shift]=buffer_src[shift];

      return;

     }

   int bar_curr=BarToCurrent(symbol_name,timeframe_src,shift);

   if(bar_curr>rates_total-1)

      return;

   int bar_prev=BarToCurrent(symbol_name,timeframe_src,shift+1);

   int bar_next=(shift>0 ? BarToCurrent(symbol_name,timeframe_src,shift-1) : 0);

   if(bar_prev==WRONG_VALUE || bar_curr==WRONG_VALUE || bar_next==WRONG_VALUE)

      return;

   buffer_dest[bar_curr]=buffer_src[shift];

   if(mode==DRAW_MODE_STEPS)

      for(int j=bar_curr; j>=bar_next; j--)

         buffer_dest[j]=buffer_dest[bar_curr];

   else

     {

      if(bar_prev>rates_total-1) return;

      for(int j=bar_prev; j>=bar_curr; j--)

         buffer_dest[j]=EquationDirect(bar_prev,buffer_dest[bar_prev],bar_curr,buffer_dest[bar_curr],j);

      if(shift==0)

         for(int j=bar_curr; j>=0; j--)

            buffer_dest[j]=buffer_dest[bar_curr];

     }

  }

//+------------------------------------------------------------------+

//| >72@0I05B 10@ 7040==>3> B09<D@59<0 :0: 10@ B5:CI53> B09<D@59<0  |

//+------------------------------------------------------------------+

int BarToCurrent(const string symbol_name,const ENUM_TIMEFRAMES timeframe_src,const int shift,bool exact=false)

  {

   datetime time=Time(symbol_name,timeframe_src,shift);

   return(time!=0 ? BarShift(symbol_name,Period(),time,exact) : WRONG_VALUE);

  }  

//+------------------------------------------------------------------+

//| >72@0I05B A<5I5=85 10@0 ?> 2@5<5=8                              |

//| https://www.mql5.com/ru/forum/743/page11#comment_7010041         |

//+------------------------------------------------------------------+

int BarShift(const string symbol_name,const ENUM_TIMEFRAMES timeframe,const datetime time,bool exact=false)

  {

   int res=Bars(symbol_name,timeframe,time+1,UINT_MAX);

   if(exact) if((timeframe!=PERIOD_MN1 || time>TimeCurrent()) && res==Bars(symbol_name,timeframe,time-PeriodSeconds(timeframe)+1,UINT_MAX)) return(WRONG_VALUE);

   return res;

  }

//+------------------------------------------------------------------+

//| >72@0I05B Time                                                  |

//+------------------------------------------------------------------+

datetime Time(const string symbol_name,const ENUM_TIMEFRAMES timeframe,const int shift)

  {

   datetime array[];

   ArraySetAsSeries(array,true);

   return(CopyTime(symbol_name,timeframe,shift,1,array)==1 ? array[0] : 0);

  }

//+------------------------------------------------------------------+

//| #@02=5=85 ?@O<>9                                                 |

//+------------------------------------------------------------------+

double EquationDirect(const int left_bar,const double left_price,const int right_bar,const double right_price,const int bar_to_search) 

  {

   return(right_bar==left_bar ? left_price : (right_price-left_price)/(right_bar-left_bar)*(bar_to_search-left_bar)+left_price);

  }

//+------------------------------------------------------------------+

//| Timeframe to string                                              |

//+------------------------------------------------------------------+

string TimeframeToString(const ENUM_TIMEFRAMES timeframe)

  {

   return StringSubstr(EnumToString(timeframe),7);

  }

//+------------------------------------------------------------------+