T3 Stochastic Momentum Index

ÿþ//+------------------------------------------------------------------

#property copyright   "mladen"

#property link        "mladenfx@gmail.com"

#property link        "https://www.mql5.com"

#property description "T3 Stochastc Momentum Index"

//+------------------------------------------------------------------

#property indicator_separate_window

#property indicator_buffers 3

#property indicator_plots   2

#property indicator_label1  "Smi"

#property indicator_type1   DRAW_COLOR_LINE

#property indicator_color1  clrDarkGray,clrDeepSkyBlue,clrLightSalmon

#property indicator_width1  2

#property indicator_label2  "Smi signal"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrDarkGray

#property indicator_width2  1

#property indicator_level1  40

#property indicator_level2  -40



//--- input parameters

input int                inpLength     = 13;          // Length

input int                inpSmooth1    = 25;          // Smooth period 1

input int                inpSmooth2    =  2;          // Smooth period 2

input int                inpSignal     =  5;          // Signal period

input double             inpT3Hot      =  0.4;        // T3 hot

input bool               inpT3Original =  false;      // T3 original Tim Tillson calculation

input ENUM_APPLIED_PRICE inpPrice      = PRICE_CLOSE; // Price 

//--- buffers declarations

double val[],valc[],signal[];

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,val,INDICATOR_DATA);

   SetIndexBuffer(1,valc,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,signal,INDICATOR_DATA);

//---

   IndicatorSetString(INDICATOR_SHORTNAME,"T3 SMI ("+(string)inpLength+","+(string)inpSmooth1+","+(string)inpSmooth2+","+(string)inpSignal+")");

//---

   return (INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator de-initialization function                      |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,const int prev_calculated,const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(Bars(_Symbol,_Period)<rates_total) return(prev_calculated);



   int i=(int)MathMax(prev_calculated-1,1); for(; i<rates_total && !_StopFlag; i++)

     {

      int _start=(int)MathMax(i-inpLength+1,0);

      double hh = high[ArrayMaximum(high,_start,inpLength)];

      double ll = low [ArrayMinimum(low ,_start,inpLength)];

      double pr = getPrice(inpPrice,open,close,high,low,i,rates_total);



      double ema10 = pr - 0.5*(hh+ll);

      double ema11 = iT3(ema10,inpSmooth1,inpT3Hot,inpT3Original,i,rates_total,0);

      double ema12 = iT3(ema11,inpSmooth2,inpT3Hot,inpT3Original,i,rates_total,1);



      double ema20 =           hh-ll;

      double ema21 = iT3(ema20,inpSmooth1,inpT3Hot,inpT3Original,i,rates_total,2);

      double ema22 = iT3(ema21,inpSmooth2,inpT3Hot,inpT3Original,i,rates_total,3);



      val[i]    = (ema22!=0) ? 100.00 * ema12 / (0.5 * ema22) : 0;

      signal[i] = iT3(val[i],inpSignal,inpT3Hot,inpT3Original,i,rates_total,4);

      valc[i]=(val[i]>signal[i]) ? 1 :(val[i]<signal[i]) ? 2 :(i>0) ? valc[i-1]: 0;

     }

   return (i);

  }

//+------------------------------------------------------------------+

//| Custom functions                                                 |

//+------------------------------------------------------------------+

#define _t3Instances     5

#define _t3InstancesSize 6

double workT3[][_t3Instances*_t3InstancesSize];

double workT3Coeffs[][6];

#define _period 0

#define _c1     1

#define _c2     2

#define _c3     3

#define _c4     4

#define _alpha  5

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

double iT3(double price,double period,double hot,bool original,int r,int bars,int instanceNo=0)

  {

   if(ArrayRange(workT3,0)!=bars) ArrayResize(workT3,bars);

   if(ArrayRange(workT3Coeffs,0)<(instanceNo+1)) ArrayResize(workT3Coeffs,instanceNo+1);

   if(workT3Coeffs[instanceNo][_period]!=period)

     {

      workT3Coeffs[instanceNo][_period]=period;

      workT3Coeffs[instanceNo][_c1] = -hot*hot*hot;

      workT3Coeffs[instanceNo][_c2] = 3*hot*hot+3*hot*hot*hot;

      workT3Coeffs[instanceNo][_c3] = -6*hot*hot-3*hot-3*hot*hot*hot;

      workT3Coeffs[instanceNo][_c4] = 1+3*hot+hot*hot*hot+3*hot*hot;

      if(original)

         workT3Coeffs[instanceNo][_alpha]=2.0/(1.0+period);

      else workT3Coeffs[instanceNo][_alpha]=2.0/(2.0+(period-1.0)/2.0);

     }



   int buffer=instanceNo*_t3InstancesSize; for(int k=0; k<6; k++) workT3[r][k+buffer]=(r>0) ? workT3[r-1][k+buffer]: price;

   if(r>0 && period>1)

     {

      workT3[r][0+buffer] = workT3[r-1][0+buffer]+workT3Coeffs[instanceNo][_alpha]*(price              -workT3[r-1][0+buffer]);

      workT3[r][1+buffer] = workT3[r-1][1+buffer]+workT3Coeffs[instanceNo][_alpha]*(workT3[r][0+buffer]-workT3[r-1][1+buffer]);

      workT3[r][2+buffer] = workT3[r-1][2+buffer]+workT3Coeffs[instanceNo][_alpha]*(workT3[r][1+buffer]-workT3[r-1][2+buffer]);

      workT3[r][3+buffer] = workT3[r-1][3+buffer]+workT3Coeffs[instanceNo][_alpha]*(workT3[r][2+buffer]-workT3[r-1][3+buffer]);

      workT3[r][4+buffer] = workT3[r-1][4+buffer]+workT3Coeffs[instanceNo][_alpha]*(workT3[r][3+buffer]-workT3[r-1][4+buffer]);

      workT3[r][5+buffer] = workT3[r-1][5+buffer]+workT3Coeffs[instanceNo][_alpha]*(workT3[r][4+buffer]-workT3[r-1][5+buffer]);

     }

   return(workT3Coeffs[instanceNo][_c1]*workT3[r][5+buffer] +

          workT3Coeffs[instanceNo][_c2]*workT3[r][4+buffer]+

          workT3Coeffs[instanceNo][_c3]*workT3[r][3+buffer]+

          workT3Coeffs[instanceNo][_c4]*workT3[r][2+buffer]);

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

double getPrice(ENUM_APPLIED_PRICE tprice,const double &open[],const double &close[],const double &high[],const double &low[],int i,int _bars)

  {

   switch(tprice)

     {

      case PRICE_CLOSE:     return(close[i]);

      case PRICE_OPEN:      return(open[i]);

      case PRICE_HIGH:      return(high[i]);

      case PRICE_LOW:       return(low[i]);

      case PRICE_MEDIAN:    return((high[i]+low[i])/2.0);

      case PRICE_TYPICAL:   return((high[i]+low[i]+close[i])/3.0);

      case PRICE_WEIGHTED:  return((high[i]+low[i]+close[i]+close[i])/4.0);

     }

   return(0);

  }

//+------------------------------------------------------------------+