squeeze_ra_v1

//+---------------------------------------------------------------------+
//|                                                   Squeeze_RA_V1.mq5 | 
//|                                  Copyright © 2015, Ravish Anandaram | 
//|                                     mailto: aravishstocks@gmail.com | 
//+---------------------------------------------------------------------+ 
// ===========================================================================================================
// This indicator is based on a strategy mentioned in John Carter's book, Mastering the Trade. 
// It is also a fully improvised version of Squeeze_Break indicator by DesO'Regan.
// You can find that implementation here: 
// https://www.mql5.com/en/code/8840?utm_campaign=MetaTrader+4+Terminal&utm_medium=special&utm_source=mt4terminal+codebase
// The main improvements include plotting squeeze values (some BB/KC calculation changes) on the zero-line and then to smoothen the momentum values as rising/falling positive/negative histograms
// to match the ones sold on commercial websites. This is easy on the eye.
// Uses some of the Linear Regression code from Victor Nicolaev aka Vinin's V_LRMA.mq4 for smoothening the histograms
// This version DOES NOT have any alerts functionality and also does not have inputs to change.
// The reason is - this is V1 and generally no body changes the BB and KC values. Feel free to enhance on your own.
// And if you like this indicator pa$$ :-) on to -->  Ravish Anandaram (aravishstocks@gmail.com)
// ===========================================================================================================
#property copyright "Copyright © 2015, Ravish Anandaram"
#property link      "aravishstocks@gmail.com"
//---- íîìåð âåðñèè èíäèêàòîðà
#property version   "1.00"
//---- îòðèñîâêà èíäèêàòîðà â îòäåëüíîì îêíå
#property indicator_separate_window 
//---- êîëè÷åñòâî èíäèêàòîðíûõ áóôåðîâ 6
#property indicator_buffers 6 
//---- èñïîëüçîâàíî âñåãî øåñòü ãðàôè÷åñêèõ ïîñòðîåíèé
#property indicator_plots   6
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 1             |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå ãèñòîãðàììû
#property indicator_type1   DRAW_HISTOGRAM
//---- â êà÷åñòâå öâåòà ëèíèè èíäèêàòîðà èñïîëüçîâàí MediumBlue öâåò
#property indicator_color1 clrMediumBlue
//---- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style1  STYLE_SOLID
//---- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 3
#property indicator_width1  3
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label1  "SqzFiredLong"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 2             |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå ãèñòîãðàììû
#property indicator_type2   DRAW_HISTOGRAM
//---- â êà÷åñòâå öâåòà ëèíèè èíäèêàòîðà èñïîëüçîâàí Tomato öâåò
#property indicator_color2 clrTomato
//---- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style2  STYLE_SOLID
//---- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 3
#property indicator_width2 3
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label2 "SqzFiredShort"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 3             |
//+----------------------------------------------+
#property indicator_type3   DRAW_HISTOGRAM
//---- â êà÷åñòâå öâåòà ëèíèè èíäèêàòîðà èñïîëüçîâàí DodgerBlue öâåò
#property indicator_color3  clrDodgerBlue
//---- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style3  STYLE_SOLID
//---- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 3
#property indicator_width3 3
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label3 "SqzFiredLong_Weak"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 4             |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå ãèñòîãðàììû
#property indicator_type4   DRAW_HISTOGRAM
//---- â êà÷åñòâå öâåòà ëèíèè èíäèêàòîðà èñïîëüçîâàí Orange öâåò
#property indicator_color4  clrOrange
//---- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style4  STYLE_SOLID
//---- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 3
#property indicator_width4 3
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label4 "SqzFiredShort_Weak"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 5             |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå çíà÷êîâ
#property indicator_type5   DRAW_ARROW
//---- â êà÷åñòâå öâåòà ëèíèè èíäèêàòîðà èñïîëüçîâàí Lime öâåò
#property indicator_color5  clrLime
//---- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style5  STYLE_SOLID
//---- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 3
#property indicator_width5 3
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label5 "Squeeze_Off"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 6             |
//+----------------------------------------------+
//---- îòðèñîâêà èíäèêàòîðà â âèäå çíà÷êîâ
#property indicator_type6   DRAW_ARROW
//---- â êà÷åñòâå öâåòà ëèíèè èíäèêàòîðà èñïîëüçîâàí Magenta öâåò
#property indicator_color6  clrMagenta
//---- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style6  STYLE_SOLID
//---- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 3
#property indicator_width6 3
//---- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label6 "Squeeze_On"
//+----------------------------------------------+
//|  îáúÿâëåíèå êîíñòàíò                         |
//+----------------------------------------------+
#define RESET 0                        // Êîíñòàíòà äëÿ âîçâðàòà òåðìèíàëó êîìàíäû íà ïåðåñ÷¸ò èíäèêàòîðà
//+----------------------------------------------+
//| Internal Global Variables                    |
//+----------------------------------------------+
int       Bollinger_Period=20;
double    Bollinger_Deviation=2.0;
int       Keltner_Period=20;
double    Keltner_ATR=1.5;
ENUM_MA_METHOD Bollinger_MaMode=MODE_SMA;
ENUM_MA_METHOD Keltner_MaMode=MODE_SMA;
int       BarsToGoBack=1000;
double      LSmoothX=1.0;
double      LSmoothY=1.0;
double      LSmoothFactor_1=3.0;
double      LSmoothFactor_2=3.0;
int Shift=0; // ñäâèã èíäèêàòîðà ïî ãîðèçîíòàëè â áàðàõ
//+----------------------------------------------+
//---- îáúÿâëåíèå äèíàìè÷åñêèõ ìàññèâîâ, êîòîðûå áóäóò â 
//---- äàëüíåéøåì èñïîëüçîâàíû â êà÷åñòâå èíäèêàòîðíûõ áóôåðîâ
double Squeeze_Off[];           // Green Dots on the zero line
double Squeeze_On[];            // Red Dots on the zero line
double SqzFiredLong_Strong[];   // Rising Positive Histograms 
double SqzFiredShort_Strong[];  // Falling Negative Histograms 
double SqzFiredLong_Weak[];     // Falling Positive Histograms 
double SqzFiredShort_Weak[];    // Rising Negative Histograms
//---- Îáúÿâëåíèå öåëûõ ïåðåìåííûõ íà÷àëà îòñ÷¸òà äàííûõ
int min_rates_total,Smooth_Factor;
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ äëÿ õåíäëîâ èíäèêàòîðîâ
int ATR_Handle,Std_Handle,Ma1_Handle,Ma2_Handle,Ma3_Handle,Ma4_Handle;
//+------------------------------------------------------------------+
//| Custom indicator function                                        |
//+------------------------------------------------------------------+    
void IndInit(int number,double &Array[],int shift,int draw_begin,double empty_value)
  {
//---- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(number,Array,INDICATOR_DATA);
//---- îñóùåñòâëåíèå ñäâèãà èíäèêàòîðà ïî ãîðèçîíòàëè
   PlotIndexSetInteger(number,PLOT_SHIFT,shift);
//---- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷¸òà îòðèñîâêè èíäèêàòîðà
   PlotIndexSetInteger(number,PLOT_DRAW_BEGIN,draw_begin);
//---- óñòàíîâêà çíà÷åíèé èíäèêàòîðà, êîòîðûå íå áóäóò âèäèìû íà ãðàôèêå
   PlotIndexSetDouble(number,PLOT_EMPTY_VALUE,empty_value);
//---- èíäåêñàöèÿ ýëåìåíòîâ â áóôåðàõ êàê â òàéìñåðèÿõ   
   ArraySetAsSeries(Array,true);
//----
  }
//+------------------------------------------------------------------+
//| Custom indicator function                                        |
//+------------------------------------------------------------------+    
int GetSmoothFactor(ENUM_TIMEFRAMES period)
  {
//----
   switch(period)
     {
      case PERIOD_M1:  return(300);
      case PERIOD_M2:  return(230);
      case PERIOD_M4:  return(150);
      case PERIOD_M5:  return(100);
      case PERIOD_M6:  return(80);
      case PERIOD_M10: return(65);
      case PERIOD_M15: return(50);
      case PERIOD_M20: return(50);
      case PERIOD_M30: return(50);
      case PERIOD_H1:  return(30);
      case PERIOD_H2:  return(20);
      case PERIOD_H3:  return(12);
      case PERIOD_H4:  return(8);
      case PERIOD_H6:  return(7);
      case PERIOD_H8:  return(6);
      case PERIOD_H12: return(5);
      case PERIOD_D1:  return(6);
      case PERIOD_W1:  return(4);
      case PERIOD_MN1: return(4);
     }
//----
   return(300);
  }
//+------------------------------------------------------------------+   
//| Custom indicator initialization function                         | 
//+------------------------------------------------------------------+ 
int OnInit()
  {
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà ATR
   ATR_Handle=iATR(NULL,0,Keltner_Period);
   if(ATR_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà ATR");
      return(INIT_FAILED);
     }
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà iStdDev
   Std_Handle=iStdDev(NULL,0,Bollinger_Period,0,Bollinger_MaMode,PRICE_CLOSE);
   if(Std_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iStdDev");
      return(INIT_FAILED);
     }
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà iMA1
   Ma1_Handle=iMA(NULL,0,Keltner_Period,0,MODE_SMA,PRICE_CLOSE);
   if(Ma1_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iMA1");
      return(INIT_FAILED);
     }
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà iMA2
   Ma2_Handle=iMA(NULL,0,Keltner_Period,0,MODE_LWMA,PRICE_CLOSE);
   if(Ma2_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iMA2");
      return(INIT_FAILED);
     }
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà iMA3
   Ma3_Handle=iMA(NULL,0,Keltner_Period,0,Keltner_MaMode,PRICE_CLOSE);
   if(Ma3_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iMA3");
      return(INIT_FAILED);
     }
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà iMA4
   Ma4_Handle=iMA(NULL,0,Bollinger_Period,0,Bollinger_MaMode,PRICE_CLOSE);
   if(Ma4_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iMA4");
      return(INIT_FAILED);
     }
//---- 
   min_rates_total=Keltner_Period+Bollinger_Period;
   Smooth_Factor=GetSmoothFactor(Period());
//---- ïðåâðàùåíèå äèíàìè÷åñêèõ ìàññèâîâ â èíäèêàòîðíûå áóôåðû
   IndInit(0,SqzFiredLong_Strong,Shift,min_rates_total,EMPTY_VALUE);
   IndInit(1,SqzFiredShort_Strong,Shift,min_rates_total,EMPTY_VALUE);
   IndInit(2,SqzFiredLong_Weak,Shift,min_rates_total,EMPTY_VALUE);
   IndInit(3,SqzFiredShort_Weak,Shift,min_rates_total,EMPTY_VALUE);
   IndInit(4,Squeeze_Off,Shift,min_rates_total,EMPTY_VALUE);
   IndInit(5,Squeeze_On,Shift,min_rates_total,EMPTY_VALUE);
//--- ñîçäàíèå èìåíè äëÿ îòîáðàæåíèÿ â îòäåëüíîì ïîäîêíå è âî âñïëûâàþùåé ïîäñêàçêå
   IndicatorSetString(INDICATOR_SHORTNAME,"Squeeze_RA_V1");
//--- îïðåäåëåíèå òî÷íîñòè îòîáðàæåíèÿ çíà÷åíèé èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//--- çàâåðøåíèå èíèöèàëèçàöèè
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+ 
//| Custom indicator iteration function                              | 
//+------------------------------------------------------------------+ 
int OnCalculate(
                const int rates_total,    // êîëè÷åñòâî èñòîðèè â áàðàõ íà òåêóùåì òèêå
                const int prev_calculated,// êîëè÷åñòâî èñòîðèè â áàðàõ íà ïðåäûäóùåì òèêå
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[]
                )
  {
//--- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷åòà
   if(BarsCalculated(ATR_Handle)<rates_total
      || BarsCalculated(Std_Handle)<rates_total
      || BarsCalculated(Ma1_Handle)<rates_total
      || BarsCalculated(Ma2_Handle)<rates_total
      || BarsCalculated(Ma3_Handle)<rates_total
      || BarsCalculated(Ma4_Handle)<rates_total
      || rates_total<min_rates_total) return(RESET);

//--- îáúÿâëåíèÿ ëîêàëüíûõ ïåðåìåííûõ 
   int to_copy,limit,bar;
   double Std[],ATR[],MA1[],MA2[],MA3[],MA4[];

//--- ðàñ÷åòû íåîáõîäèìîãî êîëè÷åñòâà êîïèðóåìûõ äàííûõ è
//ñòàðòîâîãî íîìåðà limit äëÿ öèêëà ïåðåñ÷åòà áàðîâ
   if(prev_calculated>rates_total || prev_calculated<=0)// ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷åòà èíäèêàòîðà
     {
      limit=rates_total-min_rates_total; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà âñåõ áàðîâ
     }
   else
     {
      limit=rates_total-prev_calculated; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà íîâûõ áàðîâ
     }
   to_copy=limit+1;
//--- êîïèðóåì âíîâü ïîÿâèâøèåñÿ äàííûå â ìàññèâû
   if(CopyBuffer(Std_Handle,0,0,to_copy,Std)<=0) return(RESET);
   if(CopyBuffer(ATR_Handle,0,0,to_copy,ATR)<=0) return(RESET);
   if(CopyBuffer(Ma1_Handle,0,0,to_copy,MA1)<=0) return(RESET);
   if(CopyBuffer(Ma2_Handle,0,0,to_copy,MA2)<=0) return(RESET);
   if(CopyBuffer(Ma3_Handle,0,0,to_copy,MA3)<=0) return(RESET);
   if(CopyBuffer(Ma4_Handle,0,0,to_copy,MA4)<=0) return(RESET);
//--- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ êàê â òàéìñåðèÿõ  
   ArraySetAsSeries(Std,true);
   ArraySetAsSeries(ATR,true);
   ArraySetAsSeries(MA1,true);
   ArraySetAsSeries(MA2,true);
   ArraySetAsSeries(MA3,true);
   ArraySetAsSeries(MA4,true);

//--- îñíîâíîé öèêë ðàñ÷åòà èíäèêàòîðà
   for(bar=limit; bar>=0 && !IsStopped(); bar--)
     {
      double Kelt_Mid_Band=MA3[bar];
      double Kelt_Upper_Band=Kelt_Mid_Band+ATR[bar]*Keltner_ATR;
      double Kelt_Lower_Band=Kelt_Mid_Band-ATR[bar]*Keltner_ATR;
      //---
      double StdDev=Std[bar];
      double Ma=MA4[bar];
      double Boll_Upper_Band=Ma+StdDev*Bollinger_Deviation;
      double Boll_Lower_Band=Ma-StdDev*Bollinger_Deviation;
      //---
      double LSmooth1,LSmooth2,LSmoothVal,dLSmoothVal;
      LSmooth1=LSmoothX*MA1[bar];
      LSmooth2=MA2[bar]/LSmoothY;
      LSmoothVal=LSmoothFactor_1*LSmooth2-LSmoothFactor_2*LSmooth1;
      dLSmoothVal=LSmoothVal*Smooth_Factor;
      if(dLSmoothVal>0)
        {
         if((SqzFiredLong_Strong[bar+1] && dLSmoothVal>SqzFiredLong_Strong[bar+1]) || (SqzFiredLong_Weak[bar+1] && dLSmoothVal>SqzFiredLong_Weak[bar+1]))
           {
            SqzFiredLong_Strong[bar]=dLSmoothVal; 
            SqzFiredLong_Weak[bar]=0;
           }
         else
           {
            SqzFiredLong_Weak[bar]=dLSmoothVal;
            SqzFiredLong_Strong[bar]=0;
           }
         SqzFiredShort_Strong[bar]=0;
         SqzFiredShort_Weak[bar]=0;
        }
      else
        {
         if((SqzFiredShort_Strong[bar+1] && dLSmoothVal<SqzFiredShort_Strong[bar+1]) || (SqzFiredShort_Weak[bar+1] && dLSmoothVal<SqzFiredShort_Weak[bar+1]))
           {
            SqzFiredShort_Strong[bar]=dLSmoothVal;
            SqzFiredShort_Weak[bar]=0;
           }
         else
           {
            SqzFiredShort_Weak[bar]=dLSmoothVal;
            SqzFiredShort_Strong[bar]=0;
           }
         SqzFiredLong_Strong[bar]=0;
         SqzFiredLong_Weak[bar]=0;
        }
      //---
      if(Boll_Upper_Band<Kelt_Upper_Band && Boll_Lower_Band>Kelt_Lower_Band)
        {
         Squeeze_On[bar]=0.00;
         Squeeze_Off[bar]=EMPTY_VALUE;
        }
      else
        {
         Squeeze_Off[bar]=0.00;
         Squeeze_On[bar]=EMPTY_VALUE;
        }
     }
//---     
   return(rates_total);
  }
//+------------------------------------------------------------------+