Spring

ÿþ//+------------------------------------------------------------------+

//|                                                       Spring.mq5 |

//|                              Copyright © 2021, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

#property indicator_chart_window

#property indicator_buffers 2

#property indicator_plots   2

//--- plot BearishHarami

#property indicator_label1  "Sell Signal"

#property indicator_type1   DRAW_ARROW

#property indicator_color1  clrRed

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot BullishHarami

#property indicator_label2  "Buy Signal"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrBlue

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- input parameters

input uchar    InputSellCode  = 248;         // Arrow code for Sell Signal (font Wingdings)

input uchar    InputBuyCode   = 246;         // Arrow code for Buy Signal (font Wingdings)

input char     InpShift       = 5;           // Vertical shift of arrows in pixels

//--- indicator buffers

double   SellSignalBuffer[];

double   BuySignalBuffer[];

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,SellSignalBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,BuySignalBuffer,INDICATOR_DATA);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(0,PLOT_ARROW,InputSellCode);

   PlotIndexSetInteger(1,PLOT_ARROW,InputBuyCode);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,-InpShift);

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,InpShift);

//--- set as an empty value 0

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//---

   if(rates_total<9)

      return(0);

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      SellSignalBuffer[0]=0.0;

      BuySignalBuffer[0]=0.0;

      SellSignalBuffer[1]=0.0;

      BuySignalBuffer[1]=0.0;

      limit=2;

     }

   for(int i=limit; i<rates_total; i++)

     {

      //SellSignalBuffer[i-1]=0.0;

      //BuySignalBuffer[i-1]=0.0;

      SellSignalBuffer[i]=0.0;

      BuySignalBuffer[i]=0.0;

      if(open[i-2]<close[i-2] && open[i-1]<close[i-1] && open[i]<close[i]) // three bullish candles !!!

         if(high[i-2]<high[i-1] && high[i-1]<high[i]) // each maximum is higher than the previous one

            if((close[i-2]-open[i-2])>(close[i-1]-open[i-1]) && (close[i-1]-open[i-1])>(close[i]-open[i])) // each body is larger than the previous one

               SellSignalBuffer[i]=high[i];

      if(open[i-2]>close[i-2] && open[i-1]>close[i-1] && open[i]>close[i]) // three bearish candles

         if(low[i-2]>low[i-1] && low[i-1]>low[i]) // each minimum is lower than the previous one

            if((open[i-2]-close[i-2])>(open[i-1]-close[i-1]) && (open[i-1]-close[i-1])>(open[i]-close[i])) // each body is smaller than the previous one

               BuySignalBuffer[i]=low[i];

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+