ROC_with_Signal_MA

ÿþ//+------------------------------------------------------------------+

//|                                           ROC_with_Signal_MA.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property description "Rate of Change with signal Moving Average indicator"

#property indicator_separate_window

#property indicator_buffers 2

#property indicator_plots   2

//--- plot ROC

#property indicator_label1  "Rate of Change"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrSeaGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot Signal

#property indicator_label2  "Signal"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrRed

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- input parameters

input uint           InpPeriodROC   =  8;          // ROC period

input uint           InpPeriodSig   =  8;          // Signal MA period

input ENUM_MA_METHOD InpMethod      =  MODE_EMA;   // Signal MA method

//--- indicator buffers

double         BufferROC[];

double         BufferSignal[];

//--- global variables

int            period_roc;

int            period_sig;

int            period_max;

int            weight_sum;

//--- includes

#include <MovingAverages.mqh>

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- set global variables

   period_roc=int(InpPeriodROC<1 ? 1 : InpPeriodROC);

   period_sig=int(InpPeriodSig<2 ? 2 : InpPeriodSig);

   period_max=fmax(period_roc,period_sig);

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferROC,INDICATOR_DATA);

   SetIndexBuffer(1,BufferSignal,INDICATOR_DATA);

//--- setting indicator parameters

   IndicatorSetString(INDICATOR_SHORTNAME,"ROC with signal ("+(string)period_roc+","+(string)period_sig+")");

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferROC,true);

   ArraySetAsSeries(BufferSignal,true);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- #AB0=>2:0 <0AA82>2 1CD5@>2 :0: B09<A5@89

   ArraySetAsSeries(close,true);

//--- @>25@:0 :>;8G5AB20 4>ABC?=KE 10@>2

   if(rates_total<fmax(period_max,4)) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-period_roc-1;

      ArrayInitialize(BufferROC,0);

      ArrayInitialize(BufferSignal,0);

     }



//---  0AGQB 8=48:0B>@0

   for(int i=limit; i>=0 && !IsStopped(); i--)

      BufferROC[i]=(close[i+period_roc]!=0 ? 100.0*(close[i]-close[i+period_roc])/close[i+period_roc] : 0);

   switch(InpMethod)

     {

      case MODE_EMA  :  return ExponentialMAOnBuffer(rates_total,prev_calculated,0,period_sig,BufferROC,BufferSignal);

      case MODE_SMMA :  return SmoothedMAOnBuffer(rates_total,prev_calculated,0,period_sig,BufferROC,BufferSignal);

      case MODE_LWMA :  return LinearWeightedMAOnBuffer(rates_total,prev_calculated,0,period_sig,BufferROC,BufferSignal,weight_sum);

      //---MODE_SMA

      default        :  return SimpleMAOnBuffer(rates_total,prev_calculated,0,period_sig,BufferROC,BufferSignal);

     }



//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+