qrma

ÿþ//------------------------------------------------------------------

#property copyright   "© mladen, 2018"

#property link        "mladenfx@gmail.com"

#property description "QRMA"

//------------------------------------------------------------------

#property indicator_chart_window

#property indicator_buffers 2

#property indicator_plots   1

#property indicator_label1  "QRMA"

#property indicator_type1   DRAW_COLOR_LINE

#property indicator_style1  STYLE_SOLID

#property indicator_color1  clrDarkGray,clrDodgerBlue,clrSandyBrown

#property indicator_width1  2

//

//---

//

input int                inpPeriod = 20;          // Period

input ENUM_APPLIED_PRICE inpPrice  = PRICE_CLOSE; // Price

//--- indicator buffers

double val[],valc[];

//+------------------------------------------------------------------+ 

//| Custom indicator initialization function                         | 

//+------------------------------------------------------------------+ 

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,val,INDICATOR_DATA);

   SetIndexBuffer(1,valc,INDICATOR_COLOR_INDEX);

   IndicatorSetString(INDICATOR_SHORTNAME,"QRMA ("+(string)inpPeriod+")");

//---

   return (INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator de-initialization function                      |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,const int prev_calculated,const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   if(Bars(_Symbol,_Period)<rates_total) return(prev_calculated);

   int i=(int)MathMax(prev_calculated-1,0); for(; i<rates_total && !_StopFlag; i++)

     {

      val[i]   = iQrma(getPrice(inpPrice,open,close,high,low,i,rates_total),inpPeriod,i,rates_total);

      valc[i]  = (i>0) ? (val[i]>val[i-1]) ?  1 : (val[i]<val[i-1]) ? 2 : valc[i-1] : 0;

     }

   return(i);

  }

//+------------------------------------------------------------------+

//| Custom functions                                                 |

//+------------------------------------------------------------------+

double workQrma[][1];

//

//---

//

double iQrma(double price, int period, int r, int bars, int instanceNo=0)

{

   if (ArrayRange(workQrma,0)!= bars) ArrayResize(workQrma,bars);



   //

   //

   //

   //

   //

   

      period = MathMax(period,1);

      double qwmaCoeff = (10.0-15.0/(period+2.0));

      double lwmaCoeff = (12.0-15.0/(period+2.0));

      double qwmwCoeff = 6.0/(period*(period+1.0)*(2.0*period+1.0));

      workQrma[r][instanceNo] = price;

      if (r<period) return(price);

         double lwmw = period; double lwma = lwmw*price; 

         double sma  = price;

         double sump = price*period*period;

         for(int k=1; k<period && (r-k)>=0; k++)

         {

            double weight = period-k;

                   lwmw  += weight;

                   lwma  += weight*workQrma[r-k][instanceNo];  

                   sma   +=        workQrma[r-k][instanceNo];

                   sump  +=        workQrma[r-k][instanceNo]*(period-k)*(period-k);

         }             

   return(3.0*sma/period+sump*qwmaCoeff*qwmwCoeff-lwmaCoeff*lwma/lwmw);

}

//

//---

//

double getPrice(ENUM_APPLIED_PRICE tprice,const double &open[],const double &close[],const double &high[],const double &low[],int i,int _bars)

  {

   if(i>=0)

      switch(tprice)

        {

         case PRICE_CLOSE:     return(close[i]);

         case PRICE_OPEN:      return(open[i]);

         case PRICE_HIGH:      return(high[i]);

         case PRICE_LOW:       return(low[i]);

         case PRICE_MEDIAN:    return((high[i]+low[i])/2.0);

         case PRICE_TYPICAL:   return((high[i]+low[i]+close[i])/3.0);

         case PRICE_WEIGHTED:  return((high[i]+low[i]+close[i]+close[i])/4.0);

        }

   return(0);

  }

//+------------------------------------------------------------------+