qqecandle

//+------------------------------------------------------------------+
//|                                                    QQECandle.mq5 |
//|                               Copyright © 2015, Nikolay Kositsin | 
//|                              Khabarovsk,   farria@mail.redcom.ru | 
//+------------------------------------------------------------------+
#property copyright "Copyright © 2015, Nikolay Kositsin"
#property link "farria@mail.redcom.ru"
#property description "QQECandle"
//--- íîìåð âåðñèè èíäèêàòîðà
#property version   "1.00"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà               |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà â îòäåëüíîì îêíå
#property indicator_separate_window
//--- äëÿ ðàñ÷åòà è îòðèñîâêè èíäèêàòîðà èñïîëüçîâàíî ïÿòü áóôåðîâ
#property indicator_buffers 5
//--- èñïîëüçîâàíî âñåãî îäíî ãðàôè÷åñêîå ïîñòðîåíèå
#property indicator_plots   1
//--- â êà÷åñòâå èíäèêàòîðà èñïîëüçîâàíû öâåòíûå ñâå÷è
#property indicator_type1   DRAW_COLOR_CANDLES
#property indicator_color1   clrDeepPink,clrGray,clrBlueViolet
//--- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label1  "QQECandle Open;QQECandle High;QQECandle Low;QQECandle Close"
//+----------------------------------------------+
//| îáúÿâëåíèå êîíñòàíò                          |
//+----------------------------------------------+
#define RESET  0 // Êîíñòàíòà äëÿ âîçâðàòà òåðìèíàëó êîìàíäû íà ïåðåñ÷åò èíäèêàòîðà
//+----------------------------------------------+
//| Îïèñàíèå êëàññà CXMA                         |
//+----------------------------------------------+
#include <SmoothAlgorithms.mqh> 
//+----------------------------------------------+
//| îáúÿâëåíèå ïåðå÷èñëåíèé                      |
//+----------------------------------------------+
/*enum Smooth_Method - ïåðå÷èñëåíèå îáúÿâëåíî â ôàéëå SmoothAlgorithms.mqh
  {
   MODE_SMA_,  //SMA
   MODE_EMA_,  //EMA
   MODE_SMMA_, //SMMA
   MODE_LWMA_, //LWMA
   MODE_JJMA,  //JJMA
   MODE_JurX,  //JurX
   MODE_ParMA, //ParMA
   MODE_T3,    //T3
   MODE_VIDYA, //VIDYA
   MODE_AMA,   //AMA
  }; */
//+----------------------------------------------+
//| îáúÿâëåíèå ïåðå÷èñëåíèé                      |
//+----------------------------------------------+
enum mode
  {
   MODE_MAIN,  //ðàñ÷åò ïî îñíîâíîé ëèíèè
   MODE_SIGN,  //ðàñ÷åò ïî ñèãíàëüíîé ëèíèè
   MODE_DIFF   //ðàñ÷åò ïî ðàçíîñòè ëèíèé
  };
//+----------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà                 |
//+----------------------------------------------+
input mode Mode=MODE_DIFF;                // Âàðèàíò àëãîðèòìà
input uint RSI_Period=123;
input uint SF=41;
input double DARFACTOR=4.236;
input Smooth_Method XMA_Method=MODE_SMA;  // Ìåòîä óñðåäíåíèÿ
input int XPhase=15; // Ïàðàìåòð ñãëàæèâàíèÿ
//--- XPhase: äëÿ JJMA èçìåíÿåòñÿ â ïðåäåëàõ -100 ... +100, âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà;
//--- XPhase: äëÿ VIDIA ýòî ïåðèîä CMO, äëÿ AMA ýòî ïåðèîä ìåäëåííîé ñêîëüçÿùåé
input int Shift=0;                        // Ñäâèã èíäèêàòîðà ïî ãîðèçîíòàëè â áàðàõ
//+----------------------------------------------+
//--- îáúÿâëåíèå äèíàìè÷åñêèõ ìàññèâîâ, êîòîðûå â äàëüíåéøåì
//--- áóäóò èñïîëüçîâàíû â êà÷åñòâå èíäèêàòîðíûõ áóôåðîâ
double ExtOpenBuffer[];
double ExtHighBuffer[];
double ExtLowBuffer[];
double ExtCloseBuffer[];
double ExtColorBuffer[];
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ íà÷àëà îòñ÷åòà äàííûõ
int min_rates_total;
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ äëÿ õåíäëîâ èíäèêàòîðîâ
int Ind_Handle[4];
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- èíèöèàëèçàöèÿ ãëîáàëüíûõ ïåðåìåííûõ 
   int Wilders_Period=int(RSI_Period*2-1);
   min_rates_total=int(RSI_Period+1);
   min_rates_total+=GetStartBars(XMA_Method,SF,XPhase)+1;
   min_rates_total+=GetStartBars(XMA_Method,Wilders_Period,XPhase);
   min_rates_total+=GetStartBars(XMA_Method,Wilders_Period,XPhase);
//--- ïîëó÷åíèå õåíäëîâ èíäèêàòîðà iQQE
   Ind_Handle[0]=iCustom(NULL,0,"QQECloudX",RSI_Period,SF,DARFACTOR,XMA_Method,XPhase,PRICE_OPEN,0);
   if(Ind_Handle[0]==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iQQE["+string(0)+"]!");
      return(INIT_FAILED);
     }
//---   
   Ind_Handle[1]=iCustom(NULL,0,"QQECloudX",RSI_Period,SF,DARFACTOR,XMA_Method,XPhase,PRICE_HIGH,0);
   if(Ind_Handle[1]==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iQQE["+string(1)+"]!");
      return(INIT_FAILED);
     }
//---
   Ind_Handle[2]=iCustom(NULL,0,"QQECloudX",RSI_Period,SF,DARFACTOR,XMA_Method,XPhase,PRICE_LOW,0);
   if(Ind_Handle[2]==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iQQE["+string(2)+"]!");
      return(INIT_FAILED);
     }
//---
   Ind_Handle[3]=iCustom(NULL,0,"QQECloudX",RSI_Period,SF,DARFACTOR,XMA_Method,XPhase,PRICE_CLOSE,0);
   if(Ind_Handle[3]==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iQQE["+string(3)+"]!");
      return(INIT_FAILED);
     }
//--- ïðåâðàùåíèå äèíàìè÷åñêèõ ìàññèâîâ â èíäèêàòîðíûå áóôåðû
   SetIndexBuffer(0,ExtOpenBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,ExtHighBuffer,INDICATOR_DATA);
   SetIndexBuffer(2,ExtLowBuffer,INDICATOR_DATA);
   SetIndexBuffer(3,ExtCloseBuffer,INDICATOR_DATA);
//--- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â öâåòîâîé, èíäåêñíûé áóôåð   
   SetIndexBuffer(4,ExtColorBuffer,INDICATOR_COLOR_INDEX);
//--- èíäåêñàöèÿ ýëåìåíòîâ â áóôåðàõ êàê â òàéìñåðèÿõ
   ArraySetAsSeries(ExtOpenBuffer,true);
   ArraySetAsSeries(ExtHighBuffer,true);
   ArraySetAsSeries(ExtLowBuffer,true);
   ArraySetAsSeries(ExtCloseBuffer,true);
   ArraySetAsSeries(ExtColorBuffer,true);
//--- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷åòà îòðèñîâêè èíäèêàòîðà 1
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
//--- çàïðåò íà îòðèñîâêó èíäèêàòîðîì ïóñòûõ çíà÷åíèé
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);
//--- óñòàíîâêà ôîðìàòà òî÷íîñòè îòîáðàæåíèÿ èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,2);
//--- èìÿ äëÿ îêîí äàííûõ è ìåòêà äëÿ ñóáúîêîí 
   string short_name="QQECandle";
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- çàâåðøåíèå èíèöèàëèçàöèè
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷åòà
   if(BarsCalculated(Ind_Handle[0])<rates_total
      || BarsCalculated(Ind_Handle[1])<rates_total
      || BarsCalculated(Ind_Handle[2])<rates_total
      || BarsCalculated(Ind_Handle[3])<rates_total
      || rates_total<min_rates_total)
      return(RESET);
//--- îáúÿâëåíèÿ ëîêàëüíûõ ïåðåìåííûõ 
   int to_copy,limit,bar;
//--- ðàñ÷åòû íåîáõîäèìîãî êîëè÷åñòâà êîïèðóåìûõ äàííûõ è ñòàðòîâîãî íîìåðà limit äëÿ öèêëà ïåðåñ÷åòà áàðîâ
   if(prev_calculated>rates_total || prev_calculated<=0)// ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷åòà èíäèêàòîðà
     {
      limit=rates_total-1; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà âñåõ áàðîâ
     }
   else
     {
      limit=rates_total-prev_calculated; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà íîâûõ áàðîâ
     }
//---
   to_copy=limit+1;
//--- êîïèðóåì âíîâü ïîÿâèâøèåñÿ äàííûå â ìàññèâû
   switch(Mode)
     {
      case  MODE_MAIN:
         if(CopyBuffer(Ind_Handle[0],MAIN_LINE,0,to_copy,ExtOpenBuffer)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[1],MAIN_LINE,0,to_copy,ExtHighBuffer)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[2],MAIN_LINE,0,to_copy,ExtLowBuffer)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[3],MAIN_LINE,0,to_copy,ExtCloseBuffer)<=0) return(RESET);
         break;
         //---
      case  MODE_SIGN:
         if(CopyBuffer(Ind_Handle[0],SIGNAL_LINE,0,to_copy,ExtOpenBuffer)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[1],SIGNAL_LINE,0,to_copy,ExtHighBuffer)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[2],SIGNAL_LINE,0,to_copy,ExtLowBuffer)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[3],SIGNAL_LINE,0,to_copy,ExtCloseBuffer)<=0) return(RESET);
         break;
         //---
      case  MODE_DIFF:
        {
         double MOpen[],MHigh[],MLow[],MClose[],SOpen[],SHigh[],SLow[],SClose[];
         //--- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ, êàê â òàéìñåðèÿõ  
         ArraySetAsSeries(MOpen,true);
         ArraySetAsSeries(MHigh,true);
         ArraySetAsSeries(MLow,true);
         ArraySetAsSeries(MClose,true);
         ArraySetAsSeries(SOpen,true);
         ArraySetAsSeries(SHigh,true);
         ArraySetAsSeries(SLow,true);
         ArraySetAsSeries(SClose,true);
         //--- èíäåêñàöèÿ
         if(CopyBuffer(Ind_Handle[0],MAIN_LINE,0,to_copy,MOpen)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[1],MAIN_LINE,0,to_copy,MHigh)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[2],MAIN_LINE,0,to_copy,MLow)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[3],MAIN_LINE,0,to_copy,MClose)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[0],SIGNAL_LINE,0,to_copy,SOpen)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[1],SIGNAL_LINE,0,to_copy,SHigh)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[2],SIGNAL_LINE,0,to_copy,SLow)<=0) return(RESET);
         if(CopyBuffer(Ind_Handle[3],SIGNAL_LINE,0,to_copy,SClose)<=0) return(RESET);
         //---
         for(bar=limit; bar>=0 && !IsStopped(); bar--)
           {
            ExtOpenBuffer[bar]=MOpen[bar]-SOpen[bar];
            ExtCloseBuffer[bar]=MClose[bar]-SClose[bar];
            ExtLowBuffer[bar]=MLow[bar]-SLow[bar];
            ExtHighBuffer[bar]=MHigh[bar]-SHigh[bar];
           }
        }
     }
//--- îñíîâíîé öèêë èñïðàâëåíèÿ è îêðàøèâàíèÿ ñâå÷åé
   for(bar=limit; bar>=0 && !IsStopped(); bar--)
     {
      //--- èñïðàâëåíèå ïîðóáëåííûõ ñâå÷
      double max=MathMax(ExtOpenBuffer[bar],ExtCloseBuffer[bar]);
      if(ExtHighBuffer[bar]<max) ExtHighBuffer[bar]=max;
      double min=MathMin(ExtOpenBuffer[bar],ExtCloseBuffer[bar]);
      if(ExtLowBuffer[bar]>min) ExtLowBuffer[bar]=min;
      //---
      if(ExtOpenBuffer[bar]<ExtCloseBuffer[bar]) ExtColorBuffer[bar]=2.0;
      else if(ExtOpenBuffer[bar]>ExtCloseBuffer[bar]) ExtColorBuffer[bar]=0.0;
      else ExtColorBuffer[bar]=1.0;
     }
//---     
   return(rates_total);
  }
//+------------------------------------------------------------------+