Pdfma

ÿþ//------------------------------------------------------------------

#property copyright   "© mladen, 2016, MetaQuotes Software Corp."

#property link        "www.forex-tsd.com, www.mql5.com"

//------------------------------------------------------------------

#property indicator_chart_window

#property indicator_buffers 6

#property indicator_plots   3

#property indicator_label1  "pdfma zone"

#property indicator_type1   DRAW_FILLING

#property indicator_color1  clrGainsboro

#property indicator_label2  "pdfma middle"

#property indicator_type2   DRAW_LINE

#property indicator_style2  STYLE_DOT

#property indicator_color2  clrGray

#property indicator_label3  "pdfma"

#property indicator_type3   DRAW_COLOR_LINE

#property indicator_color3  clrDarkGray,clrLimeGreen,clrDarkOrange

#property indicator_width3  3



//

//

//

//

//



enum enPrices

{

   pr_close,      // Close

   pr_open,       // Open

   pr_high,       // High

   pr_low,        // Low

   pr_median,     // Median

   pr_typical,    // Typical

   pr_weighted,   // Weighted

   pr_average,    // Average (high+low+open+close)/4

   pr_medianb,    // Average median body (open+close)/2

   pr_tbiased,    // Trend biased price

   pr_tbiased2,   // Trend biased (extreme) price

   pr_haclose,    // Heiken ashi close

   pr_haopen ,    // Heiken ashi open

   pr_hahigh,     // Heiken ashi high

   pr_halow,      // Heiken ashi low

   pr_hamedian,   // Heiken ashi median

   pr_hatypical,  // Heiken ashi typical

   pr_haweighted, // Heiken ashi weighted

   pr_haaverage,  // Heiken ashi average

   pr_hamedianb,  // Heiken ashi median body

   pr_hatbiased,  // Heiken ashi trend biased price

   pr_hatbiased2  // Heiken ashi trend biased (extreme) price

};

enum chgColor

{

   cc_onSlope,  // Change color on slope change

   cc_onLevel,  // Change color on outer levels cross

   cc_onMiddle  // Change color on middle level cross

};

enum enLevelType

{

   lvl_floa,  // Floating levels

   lvl_quan,  // Quantile levels

   lvl_fixed  // No levels

};



input ENUM_TIMEFRAMES TimeFrame       = PERIOD_CURRENT; // Time frame

input int             MaPeriod        = 25;             // PDFMA period

input double          MaVariance      =  1;             // PDFMA variance

input double          MaMean          =  0;             // PDFMA mean

input enPrices        MaPrice         = pr_close;       // Price

input chgColor        ColorOn         = cc_onLevel;     // Color change on :

input enLevelType     LevelType       = lvl_floa;       // Level type

input int             LevelPeriod     = 25;             // Levels period

input double          LevelUp         = 90;             // Upper level %

input double          LevelDown       = 10;             // Lower level %

input bool            AlertsOn        = false;          // Turn alerts on?

input bool            AlertsOnCurrent = true;           // Alert on current bar?

input bool            AlertsMessage   = true;           // Display messageas on alerts?

input bool            AlertsSound     = false;          // Play sound on alerts?

input bool            AlertsEmail     = false;          // Send email on alerts?

input bool            AlertsNotify    = false;          // Send push notification on alerts?

input bool            Interpolate     = true;           // Interpolate when in multi time frame mode?



double val[],valc[],mid[],fup[],fdn[],count[];

int     _mtfHandle = INVALID_HANDLE; ENUM_TIMEFRAMES timeFrame;

#define _mtfCall iCustom(_Symbol,timeFrame,getIndicatorName(),PERIOD_CURRENT,MaPeriod,MaVariance,MaMean,MaPrice,ColorOn,LevelType,LevelPeriod,LevelUp,LevelDown,AlertsOn,AlertsOnCurrent,AlertsMessage,AlertsSound,AlertsEmail,AlertsNotify)



//------------------------------------------------------------------

//

//------------------------------------------------------------------

//

//

//

//

//



int OnInit()

{

   SetIndexBuffer(0,fup ,INDICATOR_DATA);

   SetIndexBuffer(1,fdn ,INDICATOR_DATA);

   SetIndexBuffer(2,mid ,INDICATOR_DATA);

   SetIndexBuffer(3,val ,INDICATOR_DATA);

   SetIndexBuffer(4,valc,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(5,count,INDICATOR_CALCULATIONS);

         timeFrame = MathMax(_Period,TimeFrame);

   IndicatorSetString(INDICATOR_SHORTNAME,timeFrameToString(timeFrame)+" PDF ma ("+(string)MaPeriod+","+(string)MaVariance+","+(string)MaMean+")");

   return(0);

}



//------------------------------------------------------------------

//

//------------------------------------------------------------------

//

//

//

//

//



int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime& time[],

                const double& open[],

                const double& high[],

                const double& low[],

                const double& close[],

                const long& tick_volume[],

                const long& volume[],

                const int& spread[])

{ 

   if (Bars(_Symbol,_Period)<rates_total) return(-1);

   

      //

      //

      //

      //

      //

      

      if (timeFrame!=_Period)

      {

         double result[]; datetime currTime[],nextTime[]; 

            if (!timeFrameCheck(timeFrame,time))         return(0);

            if (_mtfHandle==INVALID_HANDLE) _mtfHandle = _mtfCall;

            if (_mtfHandle==INVALID_HANDLE)              return(0);

            if (CopyBuffer(_mtfHandle,5,0,1,result)==-1) return(0); 

      

                //

                //

                //

                //

                //

              

                #define _mtfRatio PeriodSeconds(timeFrame)/PeriodSeconds(_Period)

                int k,n,i = MathMin(MathMax(prev_calculated-1,0),MathMax(rates_total-(int)result[0]*_mtfRatio-1,0));

                for (; i<rates_total && !_StopFlag; i++ )

                {

                  #define _mtfCopy(_buff,_buffNo) if (CopyBuffer(_mtfHandle,_buffNo,time[i],1,result)==-1) break; _buff[i] = result[0]

                          _mtfCopy(fup ,0);

                          _mtfCopy(fdn ,1);

                          _mtfCopy(mid ,2);

                          _mtfCopy(val ,3);

                          _mtfCopy(valc,4);

                   

                          //

                          //

                          //

                          //

                          //

                   

                          #define _mtfInterpolate(_buff) _buff[i-k] = _buff[i]+(_buff[i-n]-_buff[i])*k/n

                          if (!Interpolate) continue;  CopyTime(_Symbol,timeFrame,time[i  ],1,currTime); 

                              if (i<(rates_total-1)) { CopyTime(_Symbol,timeFrame,time[i+1],1,nextTime); if (currTime[0]==nextTime[0]) continue; }

                              for(n=1; (i-n)> 0 && time[i-n] >= currTime[0]; n++) continue;	

                              for(k=1; (i-k)>=0 && k<n; k++)

                              {

                                  _mtfInterpolate(fup);

                                  _mtfInterpolate(fdn);

                                  _mtfInterpolate(mid);

                                  _mtfInterpolate(val);

                              }                                 

                }

                return(i);

      }

         

   //

   //

   //

   //

   //

   

   int    levelType  = (LevelPeriod>1) ? LevelType : lvl_fixed; 

   int    colorOn    = (levelType!=lvl_fixed) ? ColorOn : cc_onSlope; 

   double maVariance = MathMax(MaVariance,0.01);

   double maMean     = MathMax(MathMin(MaMean,1.0),-1.0);   

   int i=(int)MathMax(prev_calculated-1,0); for (; i<rates_total && !_StopFlag; i++)

   {

      double price = getPrice(MaPrice,open,close,high,low,i,rates_total);

             val[i] = iPdfma(price,MaPeriod,maVariance,maMean,i,rates_total);

         

         //

         //

         //

         //

         //



            switch (levelType)

            {

               case lvl_fixed : 

                     fup[i] = val[i];

                     fdn[i] = val[i];

                     mid[i] = val[i];

                     break;

               case lvl_floa :                     

                     {               

                        int    start = MathMax(i-LevelPeriod+1,0);

                        double min   = val[ArrayMinimum(val,start,LevelPeriod)];

                        double max   = val[ArrayMaximum(val,start,LevelPeriod)];

                        double range = max-min;

                           fup[i] = min+LevelUp  *range/100.0;

                           fdn[i] = min+LevelDown*range/100.0;

                           mid[i] = (fup[i]+fdn[i])*0.5;

                           break;

                     }

               default :                                                

                     fup[i] = iQuantile(val[i],LevelPeriod, LevelUp               ,i,rates_total);

                     fdn[i] = iQuantile(val[i],LevelPeriod, LevelDown             ,i,rates_total);

                     mid[i] = iQuantile(val[i],LevelPeriod,(LevelUp+LevelDown)*0.5,i,rates_total);

                     break;

            }               

            switch(colorOn)

            {

               case cc_onLevel:  valc[i] = (val[i]>fup[i])  ? 1 : (val[i]<fdn[i])  ? 2 : (val[i]>fdn[i] && val[i]<fup[i]) ? 0 : (i>0) ? valc[i-1] : 0; break;

               case cc_onMiddle: valc[i] = (val[i]>mid[i])  ? 1 : (val[i]<mid[i])  ? 2 : 0; break;

               default :         valc[i] = (i>0) ? (val[i]>val[i-1]) ? 1 : (val[i]<val[i-1]) ? 2 : valc[i-1] : 0;

            }                  

   }

   count[rates_total-1] = MathMax(rates_total-prev_calculated+1,1);

   manageAlerts(time,valc,rates_total);

   return(rates_total);

}



//------------------------------------------------------------------

//                                                                  

//------------------------------------------------------------------

//

//

//

//

//



#define _pdfmaInstances 1

double  _pdfmaWork[][_pdfmaInstances];

double  _pdfmaCoeffs[][_pdfmaInstances];

double iPdfma(double value, int period, double variance, double mean, int i, int bars, int instanceNo=0)

{

   if (ArrayRange(_pdfmaWork,0)  != bars)   ArrayResize(_pdfmaWork,bars);

   if (ArrayRange(_pdfmaCoeffs,0)<period+1) ArrayResize(_pdfmaCoeffs,period+1);

   if (_pdfmaCoeffs[period][instanceNo]!=period)

   {

      double step = M_PI/(period-1); for(int k=0; k<period; k++) _pdfmaCoeffs[k][instanceNo] = iPdf(k*step,variance,mean*M_PI);   

                                                                 _pdfmaCoeffs[period][instanceNo]=period;

   }                                                                     

   

   //

   //

   //

   //

   //

   

   _pdfmaWork[i][instanceNo] = value;

      double sumw = _pdfmaCoeffs[0][instanceNo];

      double sum  = _pdfmaCoeffs[0][instanceNo]*value;



      for(int k=1; k<period && (i-k)>=0; k++)

      {

         double weight = _pdfmaCoeffs[k][instanceNo]*value;

                sumw  += weight;

                sum   += weight*_pdfmaWork[i-k][instanceNo];  

      }             

      return(sum/sumw);

}

double iPdf(double x, double variance=1.0, double mean=0) { return((1.0/MathSqrt(2*M_PI*MathPow(variance,2))*MathExp(-MathPow(x-mean,2)/(2*MathPow(variance,2))))); }



//-------------------------------------------------------------------

//                                                                  

//-------------------------------------------------------------------

//

//

//

//

//



#define _quantileInstances 1

double _sortQuant[];

double _workQuant[][_quantileInstances];



double iQuantile(double value, int period, double qp, int i, int bars, int instanceNo=0)

{

   if (ArrayRange(_workQuant,0)!=bars) ArrayResize(_workQuant,bars);   _workQuant[i][instanceNo]=value; if (period<1) return(value);

   if (ArraySize(_sortQuant)!=period)  ArrayResize(_sortQuant,period); 

            int k=0; for (; k<period && (i-k)>=0; k++) _sortQuant[k] = _workQuant[i-k][instanceNo];

                     for (; k<period            ; k++) _sortQuant[k] = 0;

                     ArraySort(_sortQuant);



   //

   //

   //

   //

   //

   

   double index = (period-1.0)*qp/100.00;

   int    ind   = (int)index;

   double delta = index - ind;

   if (ind == NormalizeDouble(index,5))

         return(            _sortQuant[ind]);

   else  return((1.0-delta)*_sortQuant[ind]+delta*_sortQuant[ind+1]);

}   



//------------------------------------------------------------------

//

//------------------------------------------------------------------

//

//

//

//

//

//



#define _pricesInstances 1

#define _pricesSize      4

double workHa[][_pricesInstances*_pricesSize];

double getPrice(int tprice, const double& open[], const double& close[], const double& high[], const double& low[], int i,int _bars, int instanceNo=0)

{

  if (tprice>=pr_haclose)

   {

      if (ArrayRange(workHa,0)!= _bars) ArrayResize(workHa,_bars); instanceNo*=_pricesSize;

         

         //

         //

         //

         //

         //

         

         double haOpen;

         if (i>0)

                haOpen  = (workHa[i-1][instanceNo+2] + workHa[i-1][instanceNo+3])/2.0;

         else   haOpen  = (open[i]+close[i])/2;

         double haClose = (open[i] + high[i] + low[i] + close[i]) / 4.0;

         double haHigh  = MathMax(high[i], MathMax(haOpen,haClose));

         double haLow   = MathMin(low[i] , MathMin(haOpen,haClose));



         if(haOpen  <haClose) { workHa[i][instanceNo+0] = haLow;  workHa[i][instanceNo+1] = haHigh; } 

         else                 { workHa[i][instanceNo+0] = haHigh; workHa[i][instanceNo+1] = haLow;  } 

                                workHa[i][instanceNo+2] = haOpen;

                                workHa[i][instanceNo+3] = haClose;

         //

         //

         //

         //

         //

         

         switch (tprice)

         {

            case pr_haclose:     return(haClose);

            case pr_haopen:      return(haOpen);

            case pr_hahigh:      return(haHigh);

            case pr_halow:       return(haLow);

            case pr_hamedian:    return((haHigh+haLow)/2.0);

            case pr_hamedianb:   return((haOpen+haClose)/2.0);

            case pr_hatypical:   return((haHigh+haLow+haClose)/3.0);

            case pr_haweighted:  return((haHigh+haLow+haClose+haClose)/4.0);

            case pr_haaverage:   return((haHigh+haLow+haClose+haOpen)/4.0);

            case pr_hatbiased:

               if (haClose>haOpen)

                     return((haHigh+haClose)/2.0);

               else  return((haLow+haClose)/2.0);        

            case pr_hatbiased2:

               if (haClose>haOpen)  return(haHigh);

               if (haClose<haOpen)  return(haLow);

                                    return(haClose);        

         }

   }

   

   //

   //

   //

   //

   //

   

   switch (tprice)

   {

      case pr_close:     return(close[i]);

      case pr_open:      return(open[i]);

      case pr_high:      return(high[i]);

      case pr_low:       return(low[i]);

      case pr_median:    return((high[i]+low[i])/2.0);

      case pr_medianb:   return((open[i]+close[i])/2.0);

      case pr_typical:   return((high[i]+low[i]+close[i])/3.0);

      case pr_weighted:  return((high[i]+low[i]+close[i]+close[i])/4.0);

      case pr_average:   return((high[i]+low[i]+close[i]+open[i])/4.0);

      case pr_tbiased:   

               if (close[i]>open[i])

                     return((high[i]+close[i])/2.0);

               else  return((low[i]+close[i])/2.0);        

      case pr_tbiased2:   

               if (close[i]>open[i]) return(high[i]);

               if (close[i]<open[i]) return(low[i]);

                                     return(close[i]);        

   }

   return(0);

}





//------------------------------------------------------------------

//

//------------------------------------------------------------------

//

//

//

//

//



void manageAlerts(const datetime& _time[], double& _trend[], int bars)

{

   if (AlertsOn)

   {

      int whichBar = bars-1; if (!AlertsOnCurrent) whichBar = bars-2; datetime time1 = _time[whichBar];

      if (_trend[whichBar] != _trend[whichBar-1])

      {

         string add = "slope changed to";

         switch (ColorOn)

         {

            case cc_onLevel  : add = "outer level crossed"; break;

            case cc_onMiddle : add = "middle level crossed";

         }                  

         if (_trend[whichBar] == 1) doAlert(time1,add+" up");

         if (_trend[whichBar] == 2) doAlert(time1,add+" down");

      }         

   }

}   



//

//

//

//

//



void doAlert(datetime forTime, string doWhat)

{

   static string   previousAlert="nothing";

   static datetime previousTime;

   

   if (previousAlert != doWhat || previousTime != forTime) 

   {

      previousAlert  = doWhat;

      previousTime   = forTime;



      //

      //

      //

      //

      //



      string message = TimeToString(TimeLocal(),TIME_SECONDS)+" "+_Symbol+" PDF ma state changed to "+doWhat;

         if (AlertsMessage) Alert(message);

         if (AlertsEmail)   SendMail(_Symbol+" PDF ma",message);

         if (AlertsNotify)  SendNotification(message);

         if (AlertsSound)   PlaySound("alert2.wav");

   }

}



//-------------------------------------------------------------------

//

//-------------------------------------------------------------------

//

//

//

//

//



string getIndicatorName()

{

   string path = MQL5InfoString(MQL5_PROGRAM_PATH);

   string data = TerminalInfoString(TERMINAL_DATA_PATH)+"\\MQL5\\Indicators\\";

   string name = StringSubstr(path,StringLen(data));

      return(name);

}



//

//

//

//

//



int    _tfsPer[]={PERIOD_M1,PERIOD_M2,PERIOD_M3,PERIOD_M4,PERIOD_M5,PERIOD_M6,PERIOD_M10,PERIOD_M12,PERIOD_M15,PERIOD_M20,PERIOD_M30,PERIOD_H1,PERIOD_H2,PERIOD_H3,PERIOD_H4,PERIOD_H6,PERIOD_H8,PERIOD_H12,PERIOD_D1,PERIOD_W1,PERIOD_MN1};

string _tfsStr[]={"1 minute","2 minutes","3 minutes","4 minutes","5 minutes","6 minutes","10 minutes","12 minutes","15 minutes","20 minutes","30 minutes","1 hour","2 hours","3 hours","4 hours","6 hours","8 hours","12 hours","daily","weekly","monthly"};

string timeFrameToString(int period)

{

   if (period==PERIOD_CURRENT) 

       period = _Period;   

         int i; for(i=0;i<ArraySize(_tfsPer);i++) if(period==_tfsPer[i]) break;

   return(_tfsStr[i]);   

}



//

//

//

//

//



bool timeFrameCheck(ENUM_TIMEFRAMES _timeFrame,const datetime& time[])

{

   static bool warned=false;

   if (time[0]<SeriesInfoInteger(_Symbol,_timeFrame,SERIES_FIRSTDATE))

   {

      datetime startTime,testTime[]; 

         if (SeriesInfoInteger(_Symbol,PERIOD_M1,SERIES_TERMINAL_FIRSTDATE,startTime))

         if (startTime>0)                       { CopyTime(_Symbol,_timeFrame,time[0],1,testTime); SeriesInfoInteger(_Symbol,_timeFrame,SERIES_FIRSTDATE,startTime); }

         if (startTime<=0 || startTime>time[0]) { Comment(MQL5InfoString(MQL5_PROGRAM_NAME)+"\nMissing data for "+timeFrameToString(_timeFrame)+" time frame\nRe-trying on next tick"); warned=true; return(false); }

   }

   if (warned) { Comment(""); warned=false; }

   return(true);

}