new_fractals_lines

//+------------------------------------------------------------------+
//|                                           New_Fractals_Lines.mq4 |
//|                                       Copyright © 2007, olyakish |
//|                                           plutonia-dmb#yandex.ru |
//+------------------------------------------------------------------+
//--- àâòîðñòâî èíäèêàòîðà
#property copyright "Copyright © 2007, olyakish"
//--- ññûëêà íà ñàéò àâòîðà
#property link      "plutonia-dmb#yandex.ru"
//--- íîìåð âåðñèè èíäèêàòîðà
#property version   "1.00"
//--- îòðèñîâêà èíäèêàòîðà â ãëàâíîì îêíå
#property indicator_chart_window 
//--- äëÿ ðàñ÷¸òà è îòðèñîâêè èíäèêàòîðà èñïîëüçîâàíî äâà áóôåðà
#property indicator_buffers 2
//--- èñïîëüçîâàíî âñåãî äâà ãðàôè÷åñêèõ ïîñòðîåíèÿ
#property indicator_plots   2
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè âåðõíåãî èíäèêàòîðà      |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà 1 â âèäå ñèìâîëà
#property indicator_type1   DRAW_ARROW
//--- â êà÷åñòâå öâåòà èíäèêàòîðà èñïîëüçîâàí Crimson öâåò
#property indicator_color1  clrCrimson
//--- òîëùèíà ëèíèè èíäèêàòîðà 1 ðàâíà 1
#property indicator_width1  1
//--- îòîáðàæåíèå áû÷åé ìåòêè èíäèêàòîðà
#property indicator_label1  "Down Fractal"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè íèæíåãî èíäèêàòîðà       |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà 2 â âèäå ñèìâîëà
#property indicator_type2   DRAW_ARROW
//--- â êà÷åñòâå öâåòà èíäèêàòîðà èñïîëüçîâàí LimeGreen öâåò
#property indicator_color2  clrLimeGreen
//--- òîëùèíà ëèíèè èíäèêàòîðà 2 ðàâíà 1
#property indicator_width2  1
//--- îòîáðàæåíèå ìåäâåæüåé ìåòêè èíäèêàòîðà
#property indicator_label2 "Up Fractal"
//+----------------------------------------------+
//| îáúÿâëåíèå êîíñòàíò                          |
//+----------------------------------------------+
#define RESET 0 // Êîíñòàíòà äëÿ âîçâðàòà òåðìèíàëó êîìàíäû íà ïåðåñ÷¸ò èíäèêàòîðà
//+----------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà                 |
//+----------------------------------------------+
input ENUM_APPLIED_VOLUME VolumeType=VOLUME_TICK;  // Îáú¸ì 
input int  UpLabel=164;                            // Ìåòêà âåðõíåãî ôðàêòàëà
input int  DnLabel=164;                            // Ìåòêà íèæíåãî ôðàêòàëà
//+----------------------------------------------+
//--- îáúÿâëåíèå äèíàìè÷åñêèõ ìàññèâîâ, êîòîðûå â äàëüíåéøåì
//--- áóäóò èñïîëüçîâàíû â êà÷åñòâå èíäèêàòîðíûõ áóôåðîâ
double DnBuffer[];
double UpBuffer[];
//---
int min_rates_total;
int FRA_Handle;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- èíèöèàëèçàöèÿ ãëîáàëüíûõ ïåðåìåííûõ 
   min_rates_total=3;
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà iFractals
   FRA_Handle=iFractals(Symbol(),PERIOD_CURRENT);
   if(FRA_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iFractals");
      return(INIT_FAILED);
     }
//--- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(0,DnBuffer,INDICATOR_DATA);
//--- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷¸òà îòðèñîâêè èíäèêàòîðà 1
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
//--- ñèìâîë äëÿ èíäèêàòîðà
   PlotIndexSetInteger(0,PLOT_ARROW,UpLabel);
//--- èíäåêñàöèÿ ýëåìåíòîâ â áóôåðå êàê â òàéìñåðèè
   ArraySetAsSeries(DnBuffer,true);
//--- çàïðåò íà îòðèñîâêó èíäèêàòîðîì ïóñòûõ çíà÷åíèé
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);
//--- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(1,UpBuffer,INDICATOR_DATA);
//--- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷¸òà îòðèñîâêè èíäèêàòîðà 2
   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
//--- ñèìâîë äëÿ èíäèêàòîðà
   PlotIndexSetInteger(1,PLOT_ARROW,DnLabel);
//--- èíäåêñàöèÿ ýëåìåíòîâ â áóôåðå êàê â òàéìñåðèè
   ArraySetAsSeries(UpBuffer,true);
//--- çàïðåò íà îòðèñîâêó èíäèêàòîðîì ïóñòûõ çíà÷åíèé
   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);
//--- óñòàíîâêà ôîðìàòà òî÷íîñòè îòîáðàæåíèÿ èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//--- èìÿ äëÿ îêîí äàííûõ è ìåòêà äëÿ ïîäîêîí 
   string short_name="New_Fractals_Lines";
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- çàâåðøåíèå èíèöèàëèçàöèè
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷¸òà
   if(BarsCalculated(FRA_Handle)<rates_total || rates_total<min_rates_total) return(RESET);
//--- îáúÿâëåíèÿ ëîêàëüíûõ ïåðåìåííûõ 
   int to_copy,limit;
   double AllHLUp,AllMFIUp,AllHLDown,AllMFIDown,UpFractal[],DnFractal[];
   long AllVolDown,AllVolUp;
   bool Up,Down;
   static int OldFractal;
//--- ðàñ÷¸òû íåîáõîäèìîãî êîëè÷åñòâà êîïèðóåìûõ äàííûõ
//--- è ñòàðòîâîãî íîìåðà limit äëÿ öèêëà ïåðåñ÷¸òà áàðîâ
   if(prev_calculated>rates_total || prev_calculated<=0)// ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷¸òà èíäèêàòîðà
     {
      limit=rates_total-min_rates_total-1; // ñòàðòîâûé íîìåð äëÿ ðàñ÷¸òà âñåõ áàðîâ
      OldFractal=0;
     }
   else
     {
      limit=rates_total-prev_calculated+min_rates_total; // ñòàðòîâûé íîìåð äëÿ ðàñ÷¸òà íîâûõ áàðîâ
     }
   to_copy=limit+1+min_rates_total;
//--- êîïèðóåì âíîâü ïîÿâèâøèåñÿ äàííûå â ìàññèâû UpFractal è DnFractal
   if(CopyBuffer(FRA_Handle,0,0,to_copy,UpFractal)<=0) return(RESET);
   if(CopyBuffer(FRA_Handle,1,0,to_copy,DnFractal)<=0) return(RESET);
//--- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ êàê â òàéìñåðèÿõ  
   ArraySetAsSeries(high,true);
   ArraySetAsSeries(low,true);
   ArraySetAsSeries(UpFractal,true);
   ArraySetAsSeries(DnFractal,true);
   if(VolumeType==VOLUME_TICK) ArraySetAsSeries(tick_volume,true);
   else ArraySetAsSeries(volume,true);
//--- îñíîâíîé öèêë ðàñ÷¸òà èíäèêàòîðà
   for(int bar=2; bar<=limit && !IsStopped(); bar++)
     {
      UpBuffer[bar]=EMPTY_VALUE;
      DnBuffer[bar]=EMPTY_VALUE;
      //---
      if(UpFractal[bar] && UpFractal[bar]!=EMPTY_VALUE)
        {
         Up=true;
         Down=false;
        }
      if(DnFractal[bar] && DnFractal[bar]!=EMPTY_VALUE)
        {
         Up=false;
         Down=true;
        }
      //--- äâà ôðàêòàëà ñðàçó - èãíîðèðóåì
      if(UpFractal[bar] && UpFractal[bar]!=EMPTY_VALUE && DnFractal[bar] && DnFractal[bar]!=EMPTY_VALUE)
        {
         Up=false;
         Down=false;
        }
      //---
      if(!Up && Down)
        {
         AllHLDown=high[bar+2]-low[bar+2]+high[bar+1]-low[bar+1]+high[bar]-low[bar]+high[bar-1]-low[bar-1]+high[bar-2]-low[bar-2];
         AllVolDown=VolSum(VolumeType,tick_volume,volume,bar);
         AllMFIDown=AllHLDown/AllVolDown;
         if(OldFractal==1 && AllMFIDown<AllMFIUp && AllVolDown>AllVolUp) DnBuffer[bar]=DnFractal[bar];
         OldFractal=0;
        }
      //---
      if(Up && !Down)
        {
         AllHLUp=high[bar+2]-low[bar+2]+high[bar+1]-low[bar+1]+high[bar]-low[bar]+high[bar-1]-low[bar-1]+high[bar-2]-low[bar-2];
         AllVolUp=VolSum(VolumeType,tick_volume,volume,bar);
         AllMFIUp=AllHLUp/AllVolUp;
         if(OldFractal==0 && AllMFIUp<AllMFIDown && AllVolUp>AllVolDown) UpBuffer[bar]=UpFractal[bar];
         OldFractal=1;
        }
     }
//---     
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| VolSum()                                                         |
//+------------------------------------------------------------------+    
long VolSum(ENUM_APPLIED_VOLUME VolType,
            const long &Tick_Volume[],
            const long &Volume[],
            int index)
  {
//---
   long Vol;
   if(VolType==VOLUME_REAL) Vol=Volume[index+2]+Volume[index+1]+Volume[index]+Volume[index-1]+Volume[index-2];
   else Vol=Tick_Volume[index+2]+Tick_Volume[index+1]+Tick_Volume[index]+Tick_Volume[index-1]+Tick_Volume[index-2];
//---
   return(Vol);
  }
//+------------------------------------------------------------------+