Multi-symbol Two iMA Simple

Author: Copyright 2021, MetaQuotes Software Corp.
Price Data Components
Series array that contains tick volumes of each bar
Indicators Used
Moving average indicator
Miscellaneous
It issuies visual alerts to the screen
0 Views
0 Downloads
0 Favorites
Multi-symbol Two iMA Simple 
ÿþ//+------------------------------------------------------------------+

//|                                              TradingEngine31.mqh |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "3.151"

//---

#include <Trade\PositionInfo.mqh>

#include <Trade\Trade.mqh>

#include <Trade\SymbolInfo.mqh>

#include <Trade\AccountInfo.mqh>

#include <Trade\DealInfo.mqh>

//+------------------------------------------------------------------+

//| Structure Positions                                              |

//+------------------------------------------------------------------+

struct STRUCT_POSITION

  {

   ENUM_POSITION_TYPE pos_type;              // position type

   bool              waiting_transaction;    // waiting transaction, "true" -> it's forbidden to trade, we expect a transaction

   ulong             waiting_order_ticket;   // waiting order ticket, ticket of the expected order

   bool              transaction_confirmed;  // transaction confirmed, "true" -> transaction confirmed

   //--- Constructor

                     STRUCT_POSITION()

     {

      pos_type                   = WRONG_VALUE;

      waiting_transaction        = false;

      waiting_order_ticket       = 0;

      transaction_confirmed      = false;

     }

  };

//+------------------------------------------------------------------+

//| Class CTradingEngine31                                           |

//| Appointment: Class Expert Advisor.                               |

//|              Derives from class CObject.                         |

//+------------------------------------------------------------------+

class CTradingEngine31 : public CObject

  {

protected:

   //---

   CPositionInfo     m_position;                   // object of CPositionInfo class

   CTrade            m_trade;                      // object of CTrade class

   CSymbolInfo       m_symbol;                     // object of CSymbolInfo class

   CAccountInfo      m_account;                    // object of CAccountInfo class

   CDealInfo         m_deal;                       // object of CDealInfo class

   //---

   ENUM_TIMEFRAMES   m_working_period;             // Working timeframe

   int               m_lots;                       // Number of minimum lots

   ulong             m_deviation;                  // Deviation

   //---

   uchar             m_freeze_coefficient;         // Coefficient (if Freeze==0 Or StopsLevels==0)

   bool              m_print_log;                  // Print log

   ulong             m_magic;                      // Magic number

   //---

   int               handle_iMA_Fast;              // variable for storing the handle of the iMA indicator

   int               handle_iMA_Slow;              // variable for storing the handle of the iMA indicator

   bool              m_need_close_all;             // close all positions

   datetime          m_prev_bars;                  // "0" -> D'1970.01.01 00:00';

   datetime          m_last_deal_in;               // "0" -> D'1970.01.01 00:00';

   int               m_bar_current;

   bool              m_init_error;                 // error on InInit

   //---

   STRUCT_POSITION   SPosition[];



private:



public:

                     CTradingEngine31();

                    ~CTradingEngine31();

   //--- Expert initialization function

   int               OnInit(string                 _TradeSymbol,

                            ENUM_TIMEFRAMES        _InpWorkingPeriod,            // Working timeframe

                            int                    _InpLots,                     // Number of minimum lots

                            int                    _Inp_MA_Fast_ma_period,       // MA Fast: averaging period

                            int                    _Inp_MA_Fast_ma_shift,        // MA Fast: horizontal shift

                            ENUM_MA_METHOD         _Inp_MA_Fast_ma_method,       // MA Fast: smoothing type

                            ENUM_APPLIED_PRICE     _Inp_MA_Fast_applied_price,   // MA Fast: type of price

                            int                    _Inp_MA_Slow_ma_period,       // MA Slow: averaging period

                            int                    _Inp_MA_Slow_ma_shift,        // MA Slow: horizontal shift

                            ENUM_MA_METHOD         _Inp_MA_Slow_ma_method,       // MA Slow: smoothing type

                            ENUM_APPLIED_PRICE     _Inp_MA_Slow_applied_price,   // MA Slow: type of price

                            bool                   _InpPrintLog,                 // Print log

                            uchar                  _InpFreezeCoefficient,        // Coefficient (if Freeze==0 Or StopsLevels==0)

                            ulong                  _InpDeviation,                // Deviation

                            ulong                  _InpMagic                     // Magic number

                           );

   //--- Expert deinitialization function

   void              OnDeinit(const int reason);

   //--- Expert tick function

   void              OnTick();

   //--- TradeTransaction function

   void              OnTradeTransaction(const MqlTradeTransaction &trans,

                                        const MqlTradeRequest &request,

                                        const MqlTradeResult &result);



protected:

   //--- Refreshes the symbol quotes data

   bool              RefreshRates(void);

   //--- Check the correctness of the position volume

   bool              CheckVolumeValue(double volume,string &error_description);

   //--- Check Freeze and Stops levels

   void              FreezeStopsLevels(double &freeze,double &stops);

   //--- Open position

   void              OpenPosition(const int index);

   //--- Open Buy position

   void              OpenBuy(const int index);

   //--- Open Sell position

   void              OpenSell(const int index);

   //--- Print CTrade result

   void              PrintResultTrade(CTrade &trade,CSymbolInfo &symbol);

   //--- Get value of buffers

   bool              iGetArray(const int handle,const int buffer,const int start_pos,

                               const int count,double &arr_buffer[]);

   //--- Calculate all positions

   void              CalculateAllPositions(int &count_buys,double &volume_buys,double &volume_biggest_buys,

                                           int &count_sells,double &volume_sells,double &volume_biggest_sells,

                                           bool lots_limit=false);

   //--- Search trading signals

   bool              SearchTradingSignals(void);

   //--- Is position exists

   bool              IsPositionExists(void);

   //--- Close all positions

   void              CloseAllPositions(void);



  };

//+------------------------------------------------------------------+

//| Constructor                                                      |

//+------------------------------------------------------------------+

CTradingEngine31::CTradingEngine31() :

   m_working_period(PERIOD_CURRENT),

   m_lots(1),

   m_deviation(10),

   m_freeze_coefficient(1),

   m_print_log(false),

   m_magic(200),

   handle_iMA_Fast(INVALID_HANDLE),

   handle_iMA_Slow(INVALID_HANDLE),

   m_need_close_all(false),

   m_prev_bars(0),

   m_last_deal_in(0),

   m_bar_current(1),

   m_init_error(false)

  {

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

CTradingEngine31::~CTradingEngine31()

  {

  }

//+------------------------------------------------------------------+

//| Expert initialization function                                   |

//+------------------------------------------------------------------+

int CTradingEngine31::OnInit(string                   _TradeSymbol,

                             ENUM_TIMEFRAMES          _InpWorkingPeriod,            // Working timeframe

                             int                      _InpLots,                     // Number of minimum lots

                             int                      _Inp_MA_Fast_ma_period,       // MA Fast: averaging period

                             int                      _Inp_MA_Fast_ma_shift,        // MA Fast: horizontal shift

                             ENUM_MA_METHOD           _Inp_MA_Fast_ma_method,       // MA Fast: smoothing type

                             ENUM_APPLIED_PRICE       _Inp_MA_Fast_applied_price,   // MA Fast: type of price

                             int                      _Inp_MA_Slow_ma_period,       // MA Slow: averaging period

                             int                      _Inp_MA_Slow_ma_shift,        // MA Slow: horizontal shift

                             ENUM_MA_METHOD           _Inp_MA_Slow_ma_method,       // MA Slow: smoothing type

                             ENUM_APPLIED_PRICE       _Inp_MA_Slow_applied_price,   // MA Slow: type of price

                             bool                     _InpPrintLog,                 // Print log

                             uchar                    _InpFreezeCoefficient,        // Coefficient (if Freeze==0 Or StopsLevels==0)

                             ulong                    _InpDeviation,                // Deviation

                             ulong                    _InpMagic                     // Magic number

                            )

  {

   ResetLastError();

   if(!m_symbol.Name(_TradeSymbol)) // sets symbol name

      return(INIT_FAILED);

   RefreshRates();

//---

   m_working_period           = _InpWorkingPeriod;

   m_lots                     = _InpLots;

   m_freeze_coefficient       = (_InpFreezeCoefficient>0)?_InpFreezeCoefficient:1;

   m_print_log                = _InpPrintLog;

   m_deviation                = _InpDeviation;

   m_magic                    = _InpMagic;

//---

   m_trade.SetExpertMagicNumber(m_magic);

   m_trade.SetMarginMode();

   m_trade.SetTypeFillingBySymbol(m_symbol.Name());

   m_trade.SetDeviationInPoints(m_deviation);

//--- check the input parameter "Lots"

   string err_text="";

   if(!CheckVolumeValue(m_symbol.LotsMin()*(double)m_lots,err_text))

     {

      if(MQLInfoInteger(MQL_TESTER)) // when testing, we will only output to the log about incorrect input parameters

         Print(__FILE__," ",__FUNCTION__,", ERROR: ",err_text);

      else // if the Expert Advisor is run on the chart, tell the user about the error

         Alert(__FILE__," ",__FUNCTION__,", ERROR: ",err_text);

      //---

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator iMA

   handle_iMA_Fast=iMA(m_symbol.Name(),_InpWorkingPeriod,_Inp_MA_Fast_ma_period,_Inp_MA_Fast_ma_shift,

                       _Inp_MA_Fast_ma_method,_Inp_MA_Fast_applied_price);

//--- if the handle is not created

   if(handle_iMA_Fast==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA ('Fast') indicator for the symbol %s/%s, error code %d",

                  m_symbol.Name(),

                  EnumToString(_InpWorkingPeriod),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//--- create handle of the indicator iMA

   handle_iMA_Slow=iMA(m_symbol.Name(),_InpWorkingPeriod,_Inp_MA_Slow_ma_period,_Inp_MA_Slow_ma_shift,

                       _Inp_MA_Slow_ma_method,_Inp_MA_Slow_applied_price);

//--- if the handle is not created

   if(handle_iMA_Slow==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iMA ('Slow') indicator for the symbol %s/%s, error code %d",

                  m_symbol.Name(),

                  EnumToString(_InpWorkingPeriod),

                  GetLastError());

      //--- the indicator is stopped early

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   m_bar_current=1;

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Expert deinitialization function                                 |

//+------------------------------------------------------------------+

void CTradingEngine31::OnDeinit(const int reason)

  {

//---

  }

//+------------------------------------------------------------------+

//| Expert tick function                                             |

//+------------------------------------------------------------------+

void CTradingEngine31::OnTick(void)

  {

   if(m_init_error)

      return;

//---

   if(m_need_close_all)

     {

      if(IsPositionExists())

        {

         CloseAllPositions();

         return;

        }

      else

        {

         m_need_close_all=false;

        }

     }

//---

   int size_need_position=ArraySize(SPosition);

   if(size_need_position>0)

     {

      for(int i=size_need_position-1; i>=0; i--)

        {

         if(SPosition[i].waiting_transaction)

           {

            if(!SPosition[i].transaction_confirmed)

              {

               if(m_print_log)

                  Print(__FILE__," ",__FUNCTION__,", OK: ","transaction_confirmed: ",SPosition[i].transaction_confirmed);

               return;

              }

            else

               if(SPosition[i].transaction_confirmed)

                 {

                  ArrayRemove(SPosition,i,1);

                  return;

                 }

           }

         if(SPosition[i].pos_type==POSITION_TYPE_BUY)

           {

            SPosition[i].waiting_transaction=true;

            OpenPosition(i);

            return;

           }

         if(SPosition[i].pos_type==POSITION_TYPE_SELL)

           {

            SPosition[i].waiting_transaction=true;

            OpenPosition(i);

            return;

           }

        }

     }

//--- we work only at the time of the birth of new bar

   datetime time_0=iTime(m_symbol.Name(),m_working_period,0);

   if(time_0==m_prev_bars)

      return;

   m_prev_bars=time_0;

//--- search for trading signals only at the time of the birth of new bar

   if(!RefreshRates())

     {

      m_prev_bars=0;

      return;

     }

//--- search for trading signals

   if(!SearchTradingSignals())

     {

      m_prev_bars=0;

      return;

     }

//---

  }

//+------------------------------------------------------------------+

//| TradeTransaction function                                        |

//+------------------------------------------------------------------+

void CTradingEngine31::OnTradeTransaction(const MqlTradeTransaction &trans,

      const MqlTradeRequest &request,

      const MqlTradeResult &result)

  {

//--- get transaction type as enumeration value

   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;

//--- if transaction is result of addition of the transaction in history

   if(type==TRADE_TRANSACTION_DEAL_ADD)

     {

      if(HistoryDealSelect(trans.deal))

         m_deal.Ticket(trans.deal);

      else

        {

         Print(__FILE__," ",__FUNCTION__,", ERROR: ","HistoryDealSelect(",trans.deal,") error: ",GetLastError());

         return;

        }

      if(m_deal.Symbol()==m_symbol.Name() && m_deal.Magic()==m_magic)

        {

         if(m_deal.DealType()==DEAL_TYPE_BUY || m_deal.DealType()==DEAL_TYPE_SELL)

           {

            if(m_deal.Entry()==DEAL_ENTRY_IN || m_deal.Entry()==DEAL_ENTRY_INOUT)

               m_last_deal_in=iTime(m_symbol.Name(),m_working_period,0);

            int size_need_position=ArraySize(SPosition);

            if(size_need_position>0)

              {

               for(int i=0; i<size_need_position; i++)

                 {

                  if(SPosition[i].waiting_transaction)

                     if(SPosition[i].waiting_order_ticket==m_deal.Order())

                       {

                        Print(__FUNCTION__," Transaction confirmed");

                        SPosition[i].transaction_confirmed=true;

                        break;

                       }

                 }

              }

           }

        }

     }

  }

//+------------------------------------------------------------------+

//| Refreshes the symbol quotes data                                 |

//+------------------------------------------------------------------+

bool CTradingEngine31::RefreshRates(void)

  {

//--- refresh rates

   if(!m_symbol.RefreshRates())

     {

      Print(__FILE__," ",__FUNCTION__,", ERROR: ","RefreshRates error");

      return(false);

     }

//--- protection against the return value of "zero"

   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)

     {

      Print(__FILE__," ",__FUNCTION__,", ERROR: ","Ask == 0.0 OR Bid == 0.0");

      return(false);

     }

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Check the correctness of the position volume                     |

//+------------------------------------------------------------------+

bool CTradingEngine31::CheckVolumeValue(double volume,string &error_description)

  {

//--- minimal allowed volume for trade operations

   double min_volume=m_symbol.LotsMin();

   if(volume<min_volume)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< <5=LH5 <8=8<0;L=> 4>?CAB8<>3> SYMBOL_VOLUME_MIN=%.2f",min_volume);

      else

         error_description=StringFormat("Volume is less than the minimal allowed SYMBOL_VOLUME_MIN=%.2f",min_volume);

      return(false);

     }

//--- maximal allowed volume of trade operations

   double max_volume=m_symbol.LotsMax();

   if(volume>max_volume)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< 1>;LH5 <0:A8<0;L=> 4>?CAB8<>3> SYMBOL_VOLUME_MAX=%.2f",max_volume);

      else

         error_description=StringFormat("Volume is greater than the maximal allowed SYMBOL_VOLUME_MAX=%.2f",max_volume);

      return(false);

     }

//--- get minimal step of volume changing

   double volume_step=m_symbol.LotsStep();

   int ratio=(int)MathRound(volume/volume_step);

   if(MathAbs(ratio*volume_step-volume)>0.0000001)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< =5 :@0B5= <8=8<0;L=><C H03C SYMBOL_VOLUME_STEP=%.2f, 1;8609H89 ?@028;L=K9 >1J5< %.2f",

                                        volume_step,ratio*volume_step);

      else

         error_description=StringFormat("Volume is not a multiple of the minimal step SYMBOL_VOLUME_STEP=%.2f, the closest correct volume is %.2f",

                                        volume_step,ratio*volume_step);

      return(false);

     }

   error_description="Correct volume value";

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Check Freeze and Stops levels                                    |

//+------------------------------------------------------------------+

void CTradingEngine31::FreezeStopsLevels(double &freeze,double &stops)

  {

//--- check Freeze and Stops levels

   /*

   SYMBOL_TRADE_FREEZE_LEVEL shows the distance of freezing the trade operations

      for pending orders and open positions in points

   ------------------------|--------------------|--------------------------------------------

   Type of order/position  |  Activation price  |  Check

   ------------------------|--------------------|--------------------------------------------

   Buy Limit order         |  Ask               |  Ask-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy Stop order          |  Ask               |  OpenPrice-Ask  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Limit order        |  Bid               |  OpenPrice-Bid  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Stop order         |  Bid               |  Bid-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy position            |  Bid               |  TakeProfit-Bid >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  Bid-StopLoss   >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell position           |  Ask               |  Ask-TakeProfit >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  StopLoss-Ask   >= SYMBOL_TRADE_FREEZE_LEVEL

   ------------------------------------------------------------------------------------------



   SYMBOL_TRADE_STOPS_LEVEL determines the number of points for minimum indentation of the

      StopLoss and TakeProfit levels from the current closing price of the open position

   ------------------------------------------------|------------------------------------------

   Buying is done at the Ask price                 |  Selling is done at the Bid price

   ------------------------------------------------|------------------------------------------

   TakeProfit        >= Bid                        |  TakeProfit        <= Ask

   StopLoss          <= Bid                        |  StopLoss          >= Ask

   TakeProfit - Bid  >= SYMBOL_TRADE_STOPS_LEVEL   |  Ask - TakeProfit  >= SYMBOL_TRADE_STOPS_LEVEL

   Bid - StopLoss    >= SYMBOL_TRADE_STOPS_LEVEL   |  StopLoss - Ask    >= SYMBOL_TRADE_STOPS_LEVEL

   ------------------------------------------------------------------------------------------

   */

   double coeff=(double)m_freeze_coefficient;

   if(!RefreshRates() || !m_symbol.Refresh())

      return;

//--- FreezeLevel -> for pending order and modification

   double freeze_level=m_symbol.FreezeLevel()*m_symbol.Point();

   if(freeze_level==0.0)

      if(m_freeze_coefficient>0)

         freeze_level=(m_symbol.Ask()-m_symbol.Bid())*coeff;

//--- StopsLevel -> for TakeProfit and StopLoss

   double stop_level=m_symbol.StopsLevel()*m_symbol.Point();

   if(stop_level==0.0)

      if(m_freeze_coefficient>0)

         stop_level=(m_symbol.Ask()-m_symbol.Bid())*coeff;

//---

   freeze=freeze_level;

   stops=stop_level;

//---

   return;

  }

//+------------------------------------------------------------------+

//| Open position                                                    |

//|   double stop_loss                                               |

//|      -> pips * m_adjusted_point (if "0.0" -> the m_stop_loss)    |

//|   double take_profit                                             |

//|      -> pips * m_adjusted_point (if "0.0" -> the m_take_profit)  |

//+------------------------------------------------------------------+

void CTradingEngine31::OpenPosition(const int index)

  {

   double freeze=0.0,stops=0.0;

   FreezeStopsLevels(freeze,stops);

   /*

   SYMBOL_TRADE_STOPS_LEVEL determines the number of points for minimum indentation of the

      StopLoss and TakeProfit levels from the current closing price of the open position

   ------------------------------------------------|------------------------------------------

   Buying is done at the Ask price                 |  Selling is done at the Bid price

   ------------------------------------------------|------------------------------------------

   TakeProfit        >= Bid                        |  TakeProfit        <= Ask

   StopLoss          <= Bid                        |  StopLoss          >= Ask

   TakeProfit - Bid  >= SYMBOL_TRADE_STOPS_LEVEL   |  Ask - TakeProfit  >= SYMBOL_TRADE_STOPS_LEVEL

   Bid - StopLoss    >= SYMBOL_TRADE_STOPS_LEVEL   |  StopLoss - Ask    >= SYMBOL_TRADE_STOPS_LEVEL

   ------------------------------------------------------------------------------------------

   */

//--- buy

   if(SPosition[index].pos_type==POSITION_TYPE_BUY)

     {

      OpenBuy(index);

      return;

     }

//--- sell

   if(SPosition[index].pos_type==POSITION_TYPE_SELL)

     {

      OpenSell(index);

      return;

     }

  }

//+------------------------------------------------------------------+

//| Open Buy position                                                |

//+------------------------------------------------------------------+

void CTradingEngine31::OpenBuy(const int index)

  {

   double sl=0.0;

   double tp=0.0;

   double long_lot=m_symbol.LotsMin()*(double)m_lots;

//---

   if(m_symbol.LotsLimit()>0.0)

     {

      int      count_buys           = 0;

      double   volume_buys          = 0.0;

      double   volume_biggest_buys  = 0.0;

      int      count_sells          = 0;

      double   volume_sells         = 0.0;

      double   volume_biggest_sells = 0.0;

      CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                            count_sells,volume_sells,volume_biggest_sells,

                            true);

      if(volume_buys+volume_sells+long_lot>m_symbol.LotsLimit())

        {

         ArrayRemove(SPosition,index,1);

         if(m_print_log)

            Print(__FILE__," ",__FUNCTION__,", ERROR: ","#0 Buy, Volume Buy (",DoubleToString(volume_buys,2),

                  ") + Volume Sell (",DoubleToString(volume_sells,2),

                  ") + Volume long (",DoubleToString(long_lot,2),

                  ") > Lots Limit (",DoubleToString(m_symbol.LotsLimit(),2),")");

         return;

        }

     }

//--- check volume before OrderSend to avoid "not enough money" error (CTrade)

   double free_margin_check=m_account.FreeMarginCheck(m_symbol.Name(),

                            ORDER_TYPE_BUY,

                            long_lot,

                            m_symbol.Ask());

   double margin_check=m_account.MarginCheck(m_symbol.Name(),

                       ORDER_TYPE_BUY,

                       long_lot,

                       m_symbol.Ask());

   if(free_margin_check>margin_check)

     {

      if(m_trade.Buy(long_lot,m_symbol.Name(),

                     m_symbol.Ask(),sl,tp)) // CTrade::Buy -> "true"

        {

         if(m_trade.ResultDeal()==0)

           {

            if(m_trade.ResultRetcode()==10009) // trade order went to the exchange

              {

               SPosition[index].waiting_transaction=true;

               SPosition[index].waiting_order_ticket=m_trade.ResultOrder();

              }

            else

              {

               SPosition[index].waiting_transaction=false;

               if(m_print_log)

                  Print(__FILE__," ",__FUNCTION__,", ERROR: ","#1 Buy -> false. Result Retcode: ",m_trade.ResultRetcode(),

                        ", description of result: ",m_trade.ResultRetcodeDescription());

              }

            if(m_print_log)

               PrintResultTrade(m_trade,m_symbol);

           }

         else

           {

            if(m_trade.ResultRetcode()==10009)

              {

               SPosition[index].waiting_transaction=true;

               SPosition[index].waiting_order_ticket=m_trade.ResultOrder();

              }

            else

              {

               SPosition[index].waiting_transaction=false;

               if(m_print_log)

                  Print(__FILE__," ",__FUNCTION__,", OK: ","#2 Buy -> true. Result Retcode: ",m_trade.ResultRetcode(),

                        ", description of result: ",m_trade.ResultRetcodeDescription());

              }

            if(m_print_log)

               PrintResultTrade(m_trade,m_symbol);

           }

        }

      else

        {

         SPosition[index].waiting_transaction=false;

         if(m_print_log)

            Print(__FILE__," ",__FUNCTION__,", ERROR: ","#3 Buy -> false. Result Retcode: ",m_trade.ResultRetcode(),

                  ", description of result: ",m_trade.ResultRetcodeDescription());

         if(m_print_log)

            PrintResultTrade(m_trade,m_symbol);

        }

     }

   else

     {

      ArrayRemove(SPosition,index,1);

      if(m_print_log)

         Print(__FILE__," ",__FUNCTION__,", ERROR: ","CAccountInfo.FreeMarginCheck returned the value ",DoubleToString(free_margin_check,2));

      return;

     }

//---

  }

//+------------------------------------------------------------------+

//| Open Sell position                                               |

//+------------------------------------------------------------------+

void CTradingEngine31::OpenSell(const int index)

  {

   double sl=0.0;

   double tp=0.0;

   double short_lot=m_symbol.LotsMin()*(double)m_lots;

//---

   if(m_symbol.LotsLimit()>0.0)

     {

      int      count_buys           = 0;

      double   volume_buys          = 0.0;

      double   volume_biggest_buys  = 0.0;

      int      count_sells          = 0;

      double   volume_sells         = 0.0;

      double   volume_biggest_sells = 0.0;

      CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                            count_sells,volume_sells,volume_biggest_sells,

                            true);

      if(volume_buys+volume_sells+short_lot>m_symbol.LotsLimit())

        {

         ArrayRemove(SPosition,index,1);

         if(m_print_log)

            Print(__FILE__," ",__FUNCTION__,", ERROR: ","#0 Buy, Volume Buy (",DoubleToString(volume_buys,2),

                  ") + Volume Sell (",DoubleToString(volume_sells,2),

                  ") + Volume short (",DoubleToString(short_lot,2),

                  ") > Lots Limit (",DoubleToString(m_symbol.LotsLimit(),2),")");

         return;

        }

     }

//--- check volume before OrderSend to avoid "not enough money" error (CTrade)

   double free_margin_check=m_account.FreeMarginCheck(m_symbol.Name(),

                            ORDER_TYPE_SELL,

                            short_lot,

                            m_symbol.Bid());

   double margin_check=m_account.MarginCheck(m_symbol.Name(),

                       ORDER_TYPE_SELL,

                       short_lot,

                       m_symbol.Bid());

   if(free_margin_check>margin_check)

     {

      if(m_trade.Sell(short_lot,m_symbol.Name(),

                      m_symbol.Bid(),sl,tp)) // CTrade::Sell -> "true"

        {

         if(m_trade.ResultDeal()==0)

           {

            if(m_trade.ResultRetcode()==10009) // trade order went to the exchange

              {

               SPosition[index].waiting_transaction=true;

               SPosition[index].waiting_order_ticket=m_trade.ResultOrder();

              }

            else

              {

               SPosition[index].waiting_transaction=false;

               if(m_print_log)

                  Print(__FILE__," ",__FUNCTION__,", ERROR: ","#1 Sell -> false. Result Retcode: ",m_trade.ResultRetcode(),

                        ", description of result: ",m_trade.ResultRetcodeDescription());

              }

            if(m_print_log)

               PrintResultTrade(m_trade,m_symbol);

           }

         else

           {

            if(m_trade.ResultRetcode()==10009)

              {

               SPosition[index].waiting_transaction=true;

               SPosition[index].waiting_order_ticket=m_trade.ResultOrder();

              }

            else

              {

               SPosition[index].waiting_transaction=false;

               if(m_print_log)

                  Print(__FILE__," ",__FUNCTION__,", OK: ","#2 Sell -> true. Result Retcode: ",m_trade.ResultRetcode(),

                        ", description of result: ",m_trade.ResultRetcodeDescription());

              }

            if(m_print_log)

               PrintResultTrade(m_trade,m_symbol);

           }

        }

      else

        {

         SPosition[index].waiting_transaction=false;

         if(m_print_log)

            Print(__FILE__," ",__FUNCTION__,", ERROR: ","#3 Sell -> false. Result Retcode: ",m_trade.ResultRetcode(),

                  ", description of result: ",m_trade.ResultRetcodeDescription());

         if(m_print_log)

            PrintResultTrade(m_trade,m_symbol);

        }

     }

   else

     {

      ArrayRemove(SPosition,index,1);

      if(m_print_log)

         Print(__FILE__," ",__FUNCTION__,", ERROR: ","CAccountInfo.FreeMarginCheck returned the value ",DoubleToString(free_margin_check,2));

      return;

     }

//---

  }

//+------------------------------------------------------------------+

//| Print CTrade result                                              |

//+------------------------------------------------------------------+

void CTradingEngine31::PrintResultTrade(CTrade &trade,CSymbolInfo &symbol)

  {

   Print(__FILE__," ",__FUNCTION__,", Symbol: ",symbol.Name()+", "+

         "Code of request result: "+IntegerToString(trade.ResultRetcode())+", "+

         "Code of request result as a string: "+trade.ResultRetcodeDescription(),

         "Trade execution mode: "+symbol.TradeExecutionDescription());

   Print("Deal ticket: "+IntegerToString(trade.ResultDeal())+", "+

         "Order ticket: "+IntegerToString(trade.ResultOrder())+", "+

         "Order retcode external: "+IntegerToString(trade.ResultRetcodeExternal())+", "+

         "Volume of deal or order: "+DoubleToString(trade.ResultVolume(),2));

   Print("Price, confirmed by broker: "+DoubleToString(trade.ResultPrice(),symbol.Digits())+", "+

         "Current bid price: "+DoubleToString(symbol.Bid(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultBid(),symbol.Digits())+", "+

         "Current ask price: "+DoubleToString(symbol.Ask(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultAsk(),symbol.Digits()));

   Print("Broker comment: "+trade.ResultComment());

  }

//+------------------------------------------------------------------+

//| Get value of buffers                                             |

//+------------------------------------------------------------------+

bool CTradingEngine31::iGetArray(const int handle,const int buffer,const int start_pos,

                                 const int count,double &arr_buffer[])

  {

   bool result=true;

   if(!ArrayIsDynamic(arr_buffer))

     {

      if(m_print_log)

         PrintFormat("ERROR! EA: %s, FUNCTION: %s, this a no dynamic array!",__FILE__,__FUNCTION__);

      return(false);

     }

   ArrayFree(arr_buffer);

//--- reset error code

   ResetLastError();

//--- fill a part of the iBands array with values from the indicator buffer

   int copied=CopyBuffer(handle,buffer,start_pos,count,arr_buffer);

   if(copied!=count)

     {

      //--- if the copying fails, tell the error code

      if(m_print_log)

         PrintFormat("ERROR! EA: %s, FUNCTION: %s, amount to copy: %d, copied: %d, error code %d",

                     __FILE__,__FUNCTION__,count,copied,GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

   return(result);

  }

//+------------------------------------------------------------------+

//| Calculate all positions                                          |

//|  'lots_limit=true' - only for 'if(m_symbol.LotsLimit()>0.0)'     |

//+------------------------------------------------------------------+

void CTradingEngine31::CalculateAllPositions(int &count_buys,double &volume_buys,double &volume_biggest_buys,

      int &count_sells,double &volume_sells,double &volume_biggest_sells,

      bool lots_limit=false)

  {

   count_buys  = 0;

   volume_buys   = 0.0;

   volume_biggest_buys  = 0.0;

   count_sells = 0;

   volume_sells  = 0.0;

   volume_biggest_sells = 0.0;

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==m_symbol.Name() && (lots_limit || (!lots_limit && m_position.Magic()==m_magic)))

           {

            if(m_position.PositionType()==POSITION_TYPE_BUY)

              {

               count_buys++;

               volume_buys+=m_position.Volume();

               if(m_position.Volume()>volume_biggest_buys)

                  volume_biggest_buys=m_position.Volume();

               continue;

              }

            else

               if(m_position.PositionType()==POSITION_TYPE_SELL)

                 {

                  count_sells++;

                  volume_sells+=m_position.Volume();

                  if(m_position.Volume()>volume_biggest_sells)

                     volume_biggest_sells=m_position.Volume();

                 }

           }

  }

//+------------------------------------------------------------------+

//| Search trading signals                                           |

//+------------------------------------------------------------------+

bool CTradingEngine31::SearchTradingSignals(void)

  {

   if(iTime(m_symbol.Name(),m_working_period,0)==m_last_deal_in) // on one bar - only one deal

      return(true);

   double fast[],slow[];

   ArraySetAsSeries(fast,true);

   ArraySetAsSeries(slow,true);

   int start_pos=0,count=6;

   if(!iGetArray(handle_iMA_Fast,0,start_pos,count,fast) || !iGetArray(handle_iMA_Slow,0,start_pos,count,slow))

      return(false);

//---

   int size_need_position=ArraySize(SPosition);

   if(size_need_position>0)

      return(true);

//--- BUY Signal

   if(fast[m_bar_current+1]<slow[m_bar_current+1] && fast[m_bar_current]>slow[m_bar_current])

     {

      if(m_prev_bars==m_last_deal_in) // on one bar - only one deal

         return(true);

      ArrayResize(SPosition,size_need_position+1);

      SPosition[size_need_position].pos_type=POSITION_TYPE_BUY;

      if(m_print_log)

         Print(__FILE__," ",__FUNCTION__,", OK: ","Signal BUY");

      m_need_close_all=true;

      return(true);

     }

//--- SELL Signal

   if(fast[m_bar_current+1]>slow[m_bar_current+1] && fast[m_bar_current]<slow[m_bar_current])

     {

      if(m_prev_bars==m_last_deal_in) // on one bar - only one deal

         return(true);

      ArrayResize(SPosition,size_need_position+1);

      SPosition[size_need_position].pos_type=POSITION_TYPE_SELL;

      if(m_print_log)

         Print(__FILE__," ",__FUNCTION__,", OK: ","Signal SELL");

      m_need_close_all=true;

      return(true);

     }

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Is position exists                                               |

//+------------------------------------------------------------------+

bool CTradingEngine31::IsPositionExists(void)

  {

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==m_magic)

            return(true);

//---

   return(false);

  }

//+------------------------------------------------------------------+

//| Close all positions                                              |

//+------------------------------------------------------------------+

void CTradingEngine31::CloseAllPositions(void)

  {

   double freeze=0.0,stops=0.0;

   FreezeStopsLevels(freeze,stops);

   /*

   SYMBOL_TRADE_FREEZE_LEVEL shows the distance of freezing the trade operations

      for pending orders and open positions in points

   ------------------------|--------------------|--------------------------------------------

   Type of order/position  |  Activation price  |  Check

   ------------------------|--------------------|--------------------------------------------

   Buy Limit order         |  Ask               |  Ask-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy Stop order          |  Ask               |  OpenPrice-Ask  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Limit order        |  Bid               |  OpenPrice-Bid  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Stop order         |  Bid               |  Bid-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy position            |  Bid               |  TakeProfit-Bid >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  Bid-StopLoss   >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell position           |  Ask               |  Ask-TakeProfit >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  StopLoss-Ask   >= SYMBOL_TRADE_FREEZE_LEVEL

   ------------------------------------------------------------------------------------------

   */

   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of current positions

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==m_magic)

           {

            if(m_position.PositionType()==POSITION_TYPE_BUY)

              {

               bool take_profit_level=(m_position.TakeProfit()!=0.0 && m_position.TakeProfit()-m_position.PriceCurrent()>=freeze) || m_position.TakeProfit()==0.0;

               bool stop_loss_level=(m_position.StopLoss()!=0.0 && m_position.PriceCurrent()-m_position.StopLoss()>=freeze) || m_position.StopLoss()==0.0;

               if(take_profit_level && stop_loss_level)

                  if(!m_trade.PositionClose(m_position.Ticket())) // close a position by the specified m_symbol

                     if(m_print_log)

                        Print(__FILE__," ",__FUNCTION__,", ERROR: ","BUY PositionClose ",m_position.Ticket(),", ",m_trade.ResultRetcodeDescription());

              }

            if(m_position.PositionType()==POSITION_TYPE_SELL)

              {

               bool take_profit_level=(m_position.TakeProfit()!=0.0 && m_position.PriceCurrent()-m_position.TakeProfit()>=freeze) || m_position.TakeProfit()==0.0;

               bool stop_loss_level=(m_position.StopLoss()!=0.0 && m_position.StopLoss()-m_position.PriceCurrent()>=freeze) || m_position.StopLoss()==0.0;

               if(take_profit_level && stop_loss_level)

                  if(!m_trade.PositionClose(m_position.Ticket())) // close a position by the specified m_symbol

                     if(m_print_log)

                        Print(__FILE__," ",__FUNCTION__,", ERROR: ","SELL PositionClose ",m_position.Ticket(),", ",m_trade.ResultRetcodeDescription());

              }

           }

  }

//+------------------------------------------------------------------+

//|                                  Multi-symbol Two iMA Simple.mq5 |

//|                        Copyright 2021, MetaQuotes Software Corp. |

//|                                             https://www.mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2021, MetaQuotes Software Corp."

#property link      "https://www.mql5.com"

#property version   "1.000"

//---

#include <Arrays\ArrayObj.mqh>

CArrayObj      m_array_obj;                  // CArrayObj object

//--- input parameters

input group             "Trading settings"

input ENUM_TIMEFRAMES      InpWorkingPeriod           = PERIOD_CURRENT;    // Working timeframe

input string               InpSymbol_0                = "EURUSD";          // Symbol 0

input string               InpSymbol_1                = "USDJPY";          // Symbol 1

input group             "Position size management (lot calculation)"

input int                  InpLots                    = 1;                 // Number of minimum lots

input group             "MA Fast"

input int                  Inp_MA_Fast_ma_period      = 5;                 // MA Fast: averaging period

input int                  Inp_MA_Fast_ma_shift       = 0;                 // MA Fast: horizontal shift

input ENUM_MA_METHOD       Inp_MA_Fast_ma_method      = MODE_EMA;          // MA Fast: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_Fast_applied_price  = PRICE_WEIGHTED;    // MA Fast: type of price

input group             "MA Slow"

input int                  Inp_MA_Slow_ma_period      = 25;                // MA Slow: averaging period

input int                  Inp_MA_Slow_ma_shift       = 0;                 // MA Slow: horizontal shift

input ENUM_MA_METHOD       Inp_MA_Slow_ma_method      = MODE_EMA;          // MA Slow: smoothing type

input ENUM_APPLIED_PRICE   Inp_MA_Slow_applied_price  = PRICE_WEIGHTED;    // MA Slow: type of price

input group             "Additional features"

input bool                 InpPrintLog                = false;             // Print log

input uchar                InpFreezeCoefficient       = 1;                 // Coefficient (if Freeze==0 Or StopsLevels==0)

input ulong                InpDeviation               = 10;                // Deviation

input ulong                InpMagic                   = 80112528;          // Magic number

//+------------------------------------------------------------------+

//| Expert initialization function                                   |

//+------------------------------------------------------------------+

int OnInit()

  {

//---

   CTradingEngine31 *multi_0=new CTradingEngine31;

   if(multi_0==NULL)

     {

      Print("Object CTradingEngine31 create error");

      return(INIT_FAILED);

     }

   m_array_obj.Add(multi_0);

   int init=multi_0.OnInit(InpSymbol_0,

                           InpWorkingPeriod,

                           InpLots,

                           Inp_MA_Fast_ma_period,

                           Inp_MA_Fast_ma_shift,

                           Inp_MA_Fast_ma_method,

                           Inp_MA_Fast_applied_price,

                           Inp_MA_Slow_ma_period,

                           Inp_MA_Slow_ma_shift,

                           Inp_MA_Slow_ma_method,

                           Inp_MA_Slow_applied_price,

                           InpPrintLog,

                           InpFreezeCoefficient,

                           InpDeviation,

                           InpMagic

                          );

   if(init!=INIT_SUCCEEDED)

      return(init);

//---

   CTradingEngine31 *multi_1=new CTradingEngine31;

   if(multi_1==NULL)

     {

      Print("Object CTradingEngine31 create error");

      return(INIT_FAILED);

     }

   m_array_obj.Add(multi_1);

   init=multi_1.OnInit(InpSymbol_1,

                       InpWorkingPeriod,

                       InpLots,

                       Inp_MA_Fast_ma_period,

                       Inp_MA_Fast_ma_shift,

                       Inp_MA_Fast_ma_method,

                       Inp_MA_Fast_applied_price,

                       Inp_MA_Slow_ma_period,

                       Inp_MA_Slow_ma_shift,

                       Inp_MA_Slow_ma_method,

                       Inp_MA_Slow_applied_price,

                       InpPrintLog,

                       InpFreezeCoefficient,

                       InpDeviation,

                       InpMagic

                      );

   if(init!=INIT_SUCCEEDED)

      return(init);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Expert deinitialization function                                 |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

//---

   for(int i=0; i<m_array_obj.Total(); i++)

     {

      CTradingEngine31 *multi=m_array_obj.At(i);

      if(multi==NULL)

        {

         //--- Error reading from array

         Print("Object CMultiGrid create error");

         return;

        }

      multi.OnDeinit(reason);

     }

  }

//+------------------------------------------------------------------+

//| Expert tick function                                             |

//+------------------------------------------------------------------+

void OnTick()

  {

//---

   for(int i=0; i<m_array_obj.Total(); i++)

     {

      CTradingEngine31 *multi=m_array_obj.At(i);

      if(multi==NULL)

        {

         //--- Error reading from array

         Print("Object CMultiGrid create error");

         return;

        }

      multi.OnTick();

     }

  }

//+------------------------------------------------------------------+

//| TradeTransaction function                                        |

//+------------------------------------------------------------------+

void OnTradeTransaction(const MqlTradeTransaction &trans,

                        const MqlTradeRequest &request,

                        const MqlTradeResult &result)

  {

//---

   for(int i=0; i<m_array_obj.Total(); i++)

     {

      CTradingEngine31 *multi=m_array_obj.At(i);

      if(multi==NULL)

        {

         //--- Error reading from array

         Print("Object CMultiiMATrend create error");

         return;

        }

      multi.OnTradeTransaction(trans,request,result);

     }

  }

//+------------------------------------------------------------------+

Comments

Markdown supported. Formatting help

Markdown Formatting Guide

Element Markdown Syntax
Heading # H1
## H2
### H3
Bold **bold text**
Italic *italicized text*
Link [title](https://www.example.com)
Image ![alt text](image.jpg)
Code `code`
Code Block ```
code block
```
Quote > blockquote
Unordered List - Item 1
- Item 2
Ordered List 1. First item
2. Second item
Horizontal Rule ---