Multi pair RSI+EMA mtf

//+------------------------------------------------------------------+
//|                                               Multi pair RSI.mq4 |
//|                                                           mladen |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"

#property indicator_separate_window
#property  indicator_buffers 4
#property  indicator_color1  DodgerBlue
#property  indicator_color2  Lime
#property  indicator_color3  DimGray
#property  indicator_color4  DimGray
#property indicator_minimum  0
#property indicator_maximum  100
#property  indicator_width1  2
#property  indicator_style3  STYLE_DOT
#property  indicator_style4  STYLE_DOT

//
//
//
//
//

extern string    _              = "Parameters";
extern int       RSIPeriod      = 14;
extern int       RSIPrice       = PRICE_CLOSE;
extern int       MAPeriod       = 50;
extern int       MAType         = MODE_EMA;
extern string    TimeFrame      = "Current time frame";
extern int       barsPerPair    = 70;
extern string    pairs          = "EURUSD;GBPUSD;USDCAD";
extern int       levelUp        = 70;
extern int       levelDown      = 30;
extern string    text           = "color";
extern color     textColor      = Silver;
extern color     backColor      = C'48,48,48';
extern int       separatorWidth = 6;

//
//
//
//
//

double   ind_buffer1[];
double   ind_buffer2[];
double   ind_buffer3[];
double   ind_buffer4[];

//
//
//
//
//

string   aPairs[];
string   shortName;
string   indicatorFileName;
int      timeFrame;
int      window;  



//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   SetIndexBuffer(0,ind_buffer1);
   SetIndexBuffer(1,ind_buffer2);
   SetIndexBuffer(2,ind_buffer3);
   SetIndexBuffer(3,ind_buffer4);
      
   //
   //
   //
   //
   //

      if (_=="calculating") return(0);
         SetIndexLabel(0,"RSI");
         SetIndexLabel(1,"EMA");
         SetIndexLabel(2,NULL);
         SetIndexLabel(3,NULL);

   //
   //
   //
   //
   //

      pairs = StringUpperCase(StringTrimLeft(StringTrimRight(pairs)));
      if (StringSubstr(pairs,StringLen(pairs),1) != ";")
                       pairs = StringConcatenate(pairs,";");

         //
         //
         //
         //
         //                                   
            
         int s =  0;
         int i =  StringFind(pairs,";",s);
         string current;
         string temp;
            while (i > 0)
            {
               if (IsMini())
                     current = StringSubstr(pairs,s,i-s)+"m";
               else  current = StringSubstr(pairs,s,i-s);
               if (iClose(current,0,0) > 0)
                  {
                     ArrayResize(aPairs,ArraySize(aPairs)+1);
                                 aPairs[ArraySize(aPairs)-1] = current;
                                 if (current == Symbol())
                                 {
                                       temp      = aPairs[0];
                                       aPairs[0] = current;
                                       aPairs[ArraySize(aPairs)-1] = temp;
                                 }                                       
                  }
                  s = i + 1;
                  i = StringFind(pairs,";",s);
            }

      //
      //
      //
      //
      //
 
      separatorWidth = MathMax(separatorWidth,4);
      shortName = MakeUniqueName("Multi RSI "," ("+RSIPeriod+")");
      timeFrame = stringToTimeFrame(TimeFrame);
      indicatorFileName = WindowExpertName();
      IndicatorShortName(shortName);
 
   //
   //
   //
   //
   //
   
   return(0);
}

int deinit()
{
   for (int i = 0; i < ArraySize(aPairs); i++) { 
         ObjectDelete(shortName+i);
         ObjectDelete(shortName+i+i);
      }         
   return(0);
}


//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int counted_bars = IndicatorCounted();
   int i,k,limit;
   
   //
   //
   //
   //
   //
   
      if (_=="calculating")
      {
         if(counted_bars<0) return(-1);
         if(counted_bars>0) counted_bars--;
           limit=MathMin(Bars-counted_bars,Bars-1);

            //
            //
            //
            //
            //
               
            for(i=limit; i>=0; i--) ind_buffer1[i]=iRSI(NULL,0,RSIPeriod,RSIPrice,i);
            for(i=limit; i>=0; i--) ind_buffer2[i]=iMAOnArray(ind_buffer1,0,MAPeriod,0,MAType,i);
         return(0);
      }            

   //
   //
   //
   //
   //

   limit  = ArraySize(aPairs);
   window = WindowFind(shortName);  
            for(i=0,k=0; i<limit; i++) calculateRSI(aPairs[i],barsPerPair,k,i);

   //
   //
   //
   //
   //

   for (i=0;i<indicator_buffers;i++) SetIndexDrawBegin(i,Bars-k);
   return(0);
}


//+------------------------------------------------------------------+
//+                                                                  +
//+------------------------------------------------------------------+
//
//
//
//
//

int calculateRSI(string symbol,int limit,int& shift,int element)
{
   int i;
 
   //
   //
   //
   //
   //
   
   for(i=0;i<limit;i++)
   {
      int y=iBarShift(symbol,timeFrame,Time[i]);
      ind_buffer1[shift+i]=iCustom(symbol,timeFrame,indicatorFileName,"calculating",RSIPeriod,RSIPrice,MAPeriod,MAType,0,y);
      ind_buffer2[shift+i]=iCustom(symbol,timeFrame,indicatorFileName,"calculating",RSIPeriod,RSIPrice,MAPeriod,MAType,1,y);
      ind_buffer3[shift+i]=levelUp;
      ind_buffer4[shift+i]=levelDown;
   }
   
   //
   //
   //
   //
   //

   for (i=0;i<separatorWidth;i++) {
         ind_buffer1[shift+limit+i] = EMPTY_VALUE;                     
         ind_buffer2[shift+limit+i] = EMPTY_VALUE;                     
         ind_buffer3[shift+limit+i] = EMPTY_VALUE;                     
         ind_buffer4[shift+limit+i] = EMPTY_VALUE;                     
      }         

   //
   //
   //
   //
   //
   
   createLabel(symbol,element,shift+limit+separatorWidth-2,isSignalCrossing(shift));
   shift += limit+separatorWidth-1;
}

//
//
//
//
//

bool isSignalCrossing(int shift)
{
   double res = (ind_buffer1[shift]   - ind_buffer3[shift])*
                (ind_buffer1[shift+1] - ind_buffer3[shift+1]); 
   if (res>0)
          res = (ind_buffer1[shift]   - ind_buffer4[shift])*
                (ind_buffer1[shift+1] - ind_buffer4[shift+1]);  
   return(res<=0);
}


//+------------------------------------------------------------------+
//+                                                                  +
//+------------------------------------------------------------------+
//
//
//
//
//

void createLabel(string symbol,int element, int shift, bool signalCrossing)
{
   string name   = shortName+element;
   double price1 = 100;
   double price2 =   0;
   
   //
   //
   //
   //
   //
   
   if (ObjectFind(name) == -1)
      {
         ObjectCreate(name,OBJ_TEXT,window,0,0);
         ObjectSet(name,OBJPROP_ANGLE,90);
         ObjectSetText(name,symbol);
      }
      ObjectSet(name,OBJPROP_TIME1 ,Time[shift]);
      ObjectSet(name,OBJPROP_PRICE1,(price1+price2)/2);
      if (signalCrossing)
           ObjectSet(name,OBJPROP_COLOR,Gold);
      else ObjectSet(name,OBJPROP_COLOR,textColor);

   //
   //
   //
   //
   //

 
   name = shortName+element+element;
   if (ObjectFind(name) == -1)
      {
         ObjectCreate(name,OBJ_RECTANGLE,window,0,0,0,0);
         ObjectSet(name,OBJPROP_COLOR,backColor);
      }         
      ObjectSet(name,OBJPROP_TIME1,Time[shift]);
      ObjectSet(name,OBJPROP_PRICE1,price1);
      ObjectSet(name,OBJPROP_TIME2,Time[shift-(separatorWidth-2)]);
      ObjectSet(name,OBJPROP_PRICE2,price2);
}

//+------------------------------------------------------------------+
//+                                                                  +
//+------------------------------------------------------------------+
//
//
//
//
//

string StringUpperCase(string str)
{
   string   s = str;
   int      lenght = StringLen(str) - 1;
   int      char;
   
   while(lenght >= 0)
      {
         char = StringGetChar(s, lenght);
         
         //
         //
         //
         //
         //
         
         if((char > 96 && char < 123) || (char > 223 && char < 256))
                  s = StringSetChar(s, lenght, char - 32);
          else 
              if(char > -33 && char < 0)
                  s = StringSetChar(s, lenght, char + 224);
                  
         //
         //
         //
         //
         //
                                 
         lenght--;
   }
   
   //
   //
   //
   //
   //
   
   return(s);
}

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   for(int l = StringLen(tfs)-1; l >= 0; l--)
   {
      int char = StringGetChar(tfs,l);
          if((char > 96 && char < 123) || (char > 223 && char < 256))
               tfs = StringSetChar(tfs, l, char - 32);
          else 
              if(char > -33 && char < 0)
                  tfs = StringSetChar(tfs, l, char + 224);
   }

   //
   //
   //
   //
   //
   
   int tf=0;
         if (tfs=="M1" || tfs=="1")     tf=PERIOD_M1;
         if (tfs=="M5" || tfs=="5")     tf=PERIOD_M5;
         if (tfs=="M15"|| tfs=="15")    tf=PERIOD_M15;
         if (tfs=="M30"|| tfs=="30")    tf=PERIOD_M30;
         if (tfs=="H1" || tfs=="60")    tf=PERIOD_H1;
         if (tfs=="H4" || tfs=="240")   tf=PERIOD_H4;
         if (tfs=="D1" || tfs=="1440")  tf=PERIOD_D1;
         if (tfs=="W1" || tfs=="10080") tf=PERIOD_W1;
         if (tfs=="MN" || tfs=="43200") tf=PERIOD_MN1;
   return(tf);
}

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

string MakeUniqueName(string first, string rest)
{
   string result = first+(MathRand()%1001)+rest;

   while (WindowFind(result)> 0)
          result = first+(MathRand()%1001)+rest;
   return(result);
}
bool IsMini()
{
   if (StringFind(Symbol(),"m") > -1)
         return(true);
   else  return(false);    
}