Min Max for N Bars Martingale 2

ÿþ//+------------------------------------------------------------------+

//|                              Min Max for N Bars Martingale 2.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "3.150"

#property description "barabashkakvn Trading engine 3.150"

/*

   barabashkakvn Trading engine 3.150

*/

#include <Trade\PositionInfo.mqh>

#include <Trade\Trade.mqh>

#include <Trade\SymbolInfo.mqh>

#include <Trade\AccountInfo.mqh>

#include <Trade\DealInfo.mqh>

#include <Trade\OrderInfo.mqh>

#include <Expert\Money\MoneyFixedMargin.mqh>

//---

CPositionInfo  m_position;                   // object of CPositionInfo class

CTrade         m_trade;                      // object of CTrade class

CSymbolInfo    m_symbol;                     // object of CSymbolInfo class

CAccountInfo   m_account;                    // object of CAccountInfo class

CDealInfo      m_deal;                       // object of CDealInfo class

COrderInfo     m_order;                      // object of COrderInfo class

CMoneyFixedMargin *m_money;                  // object of CMoneyFixedMargin class

//+------------------------------------------------------------------+

//| Enum Lor or Risk                                                 |

//+------------------------------------------------------------------+

enum ENUM_LOT_OR_RISK

  {

   lots_min=0, // Lots Min

   lot=1,      // Constant lot

   risk=2,     // Risk in percent for a deal (range: from 1.00 to 100.00)

  };

//+------------------------------------------------------------------+

//| Enum Pending Type Max                                            |

//+------------------------------------------------------------------+

enum ENUM_PENDING_TYPE_MAX

  {

   sell_limit  = 1,  // Sell limit

   buy_stop    = 2,  // Buy stop

  };

//+------------------------------------------------------------------+

//| Enum Pending Type Min                                            |

//+------------------------------------------------------------------+

enum ENUM_PENDING_TYPE_MIN

  {

   buy_limit   = 0,  // Buy limit

   sell_stop   = 3,  // Sell stop

  };

//+------------------------------------------------------------------+

//| Enum Pips Or Points                                              |

//+------------------------------------------------------------------+

enum ENUM_PIPS_OR_POINTS

  {

   pips=0,     // Pips (1.00045-1.00055=1 pips)

   points=1,   // Points (1.00045-1.00055=10 points)

  };

//--- input parameters

input group             "Trading settings"

input ENUM_TIMEFRAMES      InpWorkingPeriod=PERIOD_CURRENT; // Working timeframe

input ENUM_PIPS_OR_POINTS  InpPipsOrPoints=pips;            // Pips Or Points:

input uint     InpStopLoss          = 15;          // Stop Loss

input uint     InpTakeProfit        = 46;          // Take Profit

input ushort   InpTrailingFrequency = 10;          // Trailing, in seconds (< "10" -> only on a new bar)

input ushort   InpSignalsFrequency  = 10;          // Search signals, in seconds (< "10" -> only on a new bar)

input uint     InpTrailingStop      = 25;          // Trailing Stop (min distance from price to Stop Loss)

input uint     InpTrailingStep      = 5;           // Trailing Step

input group             "Position size management (lot calculation)"

input ENUM_LOT_OR_RISK InpLotOrRisk = lots_min;    // Money management: Lot OR Risk

input double   InpVolumeLotOrRisk   = 3.0;         // The value for "Money management"

input group             "Martingale"

input double   InpMaxLoss           = -30;         // Maximum loss, in money

input double   InpTargetProfit      = 60;          // Target profit, in money

input double   InpCoefficient       = 2.0;         // Coefficient of the last lot DEAL IN (at losses)

input double   InpMaxLot            = 1.0;         // Maximum lot ('0' -> OFF)

input group             "Pending Order Parameters"

input ushort   InpPendingExpiration = 600;         // Pending: Expiration, in minutes ('0' -> OFF)

input uint     InpPendingIndent     = 15;          // Pending: Indent ('0' -> OFF)

input uint     InpPendingMaxSpread  = 12;          // Pending: Maximum spread ('0' -> OFF)

input uchar    InpPendingWindowWidth= 15;          // Pending: Window width, in bars (minimum 3)

input ENUM_PENDING_TYPE_MAX InpPendingTypeMax=buy_stop;// Pending: Type on Max

input ENUM_PENDING_TYPE_MIN InpPendingTypeMin=sell_stop;// Pending: Type on Min

input group             "Additional features"

input bool     InpPendingCloseOpposite=true;       // Pending: Close opposite positions

input bool     InpPrintLog          = false;       // Print log

input uchar    InpFreezeCoefficient = 1;           // Coefficient (if Freeze==0 Or StopsLevels==0)

input ulong    InpDeviation         = 10;          // Deviation

input ulong    InpMagic             = 415262008;   // Magic number

input group             "Rectangle"

input color                Inp_Rectangle_Color        = clrMediumPurple;   // Rectangle: Color

input ENUM_LINE_STYLE      Inp_Rectangle_Style        = STYLE_DASH;        // Rectangle: Style

input int                  Inp_Rectangle_Width        = 2;                 // Rectangle: Width

input bool                 Inp_Rectangle_Fill         = false;             // Rectangle: Filling  color

input bool                 Inp_Rectangle_Back         = false;             // Rectangle: Background

input bool                 Inp_Rectangle_Selection    = false;             // Rectangle: Highlight to move

input bool                 Inp_Rectangle_Hidden       = true;              // Rectangle: Hidden in the object list

input long                 Inp_Rectangle_ZOrder       = 0;                 // Rectangle: Priority for mouse click

//---

double   m_stop_loss                = 0.0;      // Stop Loss                  -> double

double   m_take_profit              = 0.0;      // Take Profit                -> double

double   m_trailing_stop            = 0.0;      // Trailing Stop              -> double

double   m_trailing_step            = 0.0;      // Trailing Step              -> double

double   m_pending_indent           = 0.0;      // Pending: Indent            -> double

double   m_pending_max_spread       = 0.0;      // Pending: Maximum spread    -> double



double   m_adjusted_point;                      // point value adjusted for 3 or 5 points

bool     m_need_close_all           = false;    // close all positions

bool     m_need_close_all_buy       = false;    // close all BUY positions

bool     m_need_close_all_sell      = false;    // close all SELL positions

datetime m_last_trailing            = 0;        // "0" -> D'1970.01.01 00:00';

datetime m_last_signal              = 0;        // "0" -> D'1970.01.01 00:00';

datetime m_prev_bars                = 0;        // "0" -> D'1970.01.01 00:00';

datetime m_last_deal_in             = 0;        // "0" -> D'1970.01.01 00:00';

int      m_bar_current              = 0;

bool     m_need_delete_all          = false;    // delete all pending orders

bool     m_waiting_pending_order    = false;    // waiting for a pending order

bool     m_init_error               = false;    // error on InInit

double   m_last_volume_in           = 0.0;

string   m_rectangles_name          = "Min Max";// Rectangle name

//--- the tactic is this: ***

//---    and pending orders (if the spread was verified)

//---    just shoot and zero out the arrays of structures

//+------------------------------------------------------------------+

//| Structurt Pending                                                |

//+------------------------------------------------------------------+

struct STRUCT_PENDING

  {

   ENUM_ORDER_TYPE   pending_type;           // pending order type

   double            volume;                 // pending order volume

   double            price;                  // pending order price

   double            stop_loss;              // pending order stop loss, in pips * m_adjusted_point (if "0.0" -> the m_stop_loss)

   double            take_profit;            // pending order take profit, in pips * m_adjusted_point (if "0.0" -> the m_take_profit)

   double            indent;                 // pending indent, in pips * m_adjusted_point

   long              expiration;             // expiration (extra time)

   //--- Constructor

                     STRUCT_PENDING()

     {

      pending_type               = WRONG_VALUE;

      volume                     = 0.0;

      price                      = 0.0;

      stop_loss                  = 0.0;

      take_profit                = 0.0;

      indent                     = 0.0;

      expiration                 = 0;

     }

  };

STRUCT_PENDING SPending[];

//+------------------------------------------------------------------+

//| Expert initialization function                                   |

//+------------------------------------------------------------------+

int OnInit()

  {

//---

   if(InpTrailingStop!=0 && InpTrailingStep==0)

     {

      string err_text=(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")?

                      ""@59;8=3 =52>7<>65=: ?0@0<5B@ \"Trailing Step\" @025= =C;N!":

                      "Trailing is not possible: parameter \"Trailing Step\" is zero!";

      if(MQLInfoInteger(MQL_TESTER)) // when testing, we will only output to the log about incorrect input parameters

         Print(__FILE__," ",__FUNCTION__,", ERROR: ",err_text);

      else // if the Expert Advisor is run on the chart, tell the user about the error

         Alert(__FILE__," ",__FUNCTION__,", ERROR: ",err_text);

      //---

      m_init_error=true;

      return(INIT_SUCCEEDED);

     }

//---

   ResetLastError();

   if(!m_symbol.Name(Symbol())) // sets symbol name

     {

      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");

      return(INIT_FAILED);

     }

   RefreshRates();

//---

   if(InpPendingExpiration>0)

     {

      int exp_type=(int)SYMBOL_EXPIRATION_SPECIFIED;

      int expiration=(int)m_symbol.TradeTimeFlags();

      if((expiration&exp_type)!=exp_type)

        {

         string err_text=(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")?

                         "0 A8<2>;5 "+m_symbol.Name()+" =5;L7O 7040BL !@>: 8AB5G5=8O 4;O >B;>65==>3> >@45@0!":

                         "On the symbol "+m_symbol.Name()+" you can not set the expiration date for a pending order!";

         if(MQLInfoInteger(MQL_TESTER)) // when testing, we will only output to the log about incorrect input parameters

            Print(__FILE__," ",__FUNCTION__,", ERROR: ",err_text);

         else // if the Expert Advisor is run on the chart, tell the user about the error

            Alert(__FILE__," ",__FUNCTION__,", ERROR: ",err_text);

         //---

         m_init_error=true;

         return(INIT_SUCCEEDED);

        }

     }

//---

   m_trade.SetExpertMagicNumber(InpMagic);

   m_trade.SetMarginMode();

   m_trade.SetTypeFillingBySymbol(m_symbol.Name());

   m_trade.SetDeviationInPoints(InpDeviation);

//--- tuning for 3 or 5 digits

   int digits_adjust=1;

   if(m_symbol.Digits()==3 || m_symbol.Digits()==5)

      digits_adjust=10;

   m_adjusted_point=m_symbol.Point()*digits_adjust;

   if(InpPipsOrPoints==pips) // Pips (1.00045-1.00055=1 pips)

     {

      m_stop_loss                = InpStopLoss                 * m_adjusted_point;

      m_take_profit              = InpTakeProfit               * m_adjusted_point;

      m_trailing_stop            = InpTrailingStop             * m_adjusted_point;

      m_trailing_step            = InpTrailingStep             * m_adjusted_point;

      m_pending_indent           = InpPendingIndent            * m_adjusted_point;

      m_pending_max_spread       = InpPendingMaxSpread         * m_adjusted_point;

     }

   else // Points (1.00045-1.00055=10 points)

     {

      m_stop_loss                = InpStopLoss                 * m_symbol.Point();

      m_take_profit              = InpTakeProfit               * m_symbol.Point();

      m_trailing_stop            = InpTrailingStop             * m_symbol.Point();

      m_trailing_step            = InpTrailingStep             * m_symbol.Point();

      m_pending_indent           = InpPendingIndent            * m_symbol.Point();

      m_pending_max_spread       = InpPendingMaxSpread         * m_symbol.Point();

     }

//--- check the input parameter "Lots"

   string err_text="";

   if(InpLotOrRisk==lot)

     {

      if(!CheckVolumeValue(InpVolumeLotOrRisk,err_text))

        {

         if(MQLInfoInteger(MQL_TESTER)) // when testing, we will only output to the log about incorrect input parameters

            Print(__FILE__," ",__FUNCTION__,", ERROR: ",err_text);

         else // if the Expert Advisor is run on the chart, tell the user about the error

            Alert(__FILE__," ",__FUNCTION__,", ERROR: ",err_text);

         //---

         m_init_error=true;

         return(INIT_SUCCEEDED);

        }

     }

   else

      if(InpLotOrRisk==risk)

        {

         if(m_money!=NULL)

            delete m_money;

         m_money=new CMoneyFixedMargin;

         if(m_money!=NULL)

           {

            if(InpVolumeLotOrRisk<1 || InpVolumeLotOrRisk>100)

              {

               Print(__FILE__," ",__FUNCTION__,", ERROR: ");

               Print("The value for \"Money management\" (",DoubleToString(InpVolumeLotOrRisk,2),") -> invalid parameters");

               Print("   parameter must be in the range: from 1.00 to 100.00");

               //---

               m_init_error=true;

               return(INIT_SUCCEEDED);

              }

            if(!m_money.Init(GetPointer(m_symbol),InpWorkingPeriod,m_symbol.Point()*digits_adjust))

              {

               Print(__FILE__," ",__FUNCTION__,", ERROR: CMoneyFixedMargin.Init");

               //---

               m_init_error=true;

               return(INIT_SUCCEEDED);

              }

            m_money.Percent(InpVolumeLotOrRisk);

           }

         else

           {

            Print(__FILE__," ",__FUNCTION__,", ERROR: Object CMoneyFixedMargin is NULL");

            return(INIT_FAILED);

           }

        }

//---

   m_bar_current=(InpSignalsFrequency<10)?1:0;

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Expert deinitialization function                                 |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

//---

   if(m_money!=NULL)

      delete m_money;

  }

//+------------------------------------------------------------------+

//| Expert tick function                                             |

//+------------------------------------------------------------------+

void OnTick()

  {

   if(m_init_error)

      return;

//---

   if(m_need_close_all)

     {

      if(IsPositionExists())

        {

         CloseAllPositions();

         return;

        }

      else

        {

         m_need_close_all=false;

         ArrayFree(SPending);

        }

     }

   if(m_need_close_all_buy || m_need_close_all_sell)

     {

      int      count_buys           = 0;

      double   volume_buys          = 0.0;

      double   volume_biggest_buys  = 0.0;

      int      count_sells          = 0;

      double   volume_sells         = 0.0;

      double   volume_biggest_sells = 0.0;

      CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                            count_sells,volume_sells,volume_biggest_sells,

                            false);

      if(m_need_close_all_buy)

        {

         if(count_buys>0)

           {

            ClosePositions(POSITION_TYPE_BUY);

            return;

           }

         else

            m_need_close_all_buy=false;

        }

      if(m_need_close_all_sell)

        {

         if(count_sells>0)

           {

            ClosePositions(POSITION_TYPE_SELL);

            return;

           }

         else

            m_need_close_all_sell=false;

         ArrayFree(SPending);

        }

     }

//---

   if(m_need_delete_all)

     {

      if(IsPendingOrdersExists())

        {

         DeleteAllPendingOrders();

         return;

        }

      else

         m_need_delete_all=false;

     }

//---

   double profit_all_positions=ProfitAllPositions();

   if(profit_all_positions<=InpMaxLoss || profit_all_positions>InpTargetProfit)

     {

      m_need_close_all=true;

      m_need_delete_all=true;

      m_last_volume_in=0.0;

      ArrayFree(SPending);

      return;

     }

//---

   int size_need_pending=ArraySize(SPending);

   if(size_need_pending>0)

     {

      if(!m_waiting_pending_order)

         for(int i=size_need_pending-1; i>=0; i--)

           {

            m_waiting_pending_order=true;

            PlaceOrders(i);

           }

      return;

     }

//---

   if(InpTrailingFrequency>=10) // trailing no more than once every 10 seconds

     {

      datetime time_current=TimeCurrent();

      if(time_current-m_last_trailing>InpTrailingFrequency)

        {

         Trailing();

         m_last_trailing=time_current;

        }

     }

   if(InpSignalsFrequency>=10) // search for trading signals no more than once every 10 seconds

     {

      datetime time_current=TimeCurrent();

      if(time_current-m_last_signal>InpSignalsFrequency)

        {

         //--- search for trading signals

         if(!RefreshRates())

            return;

         if(!SearchTradingSignals())

            return;

         m_last_signal=time_current;

        }

     }

//--- we work only at the time of the birth of new bar

   if(InpTrailingFrequency<10 || InpSignalsFrequency<10)

     {

      datetime time_0=iTime(m_symbol.Name(),InpWorkingPeriod,0);

      if(time_0==m_prev_bars)

         return;

      m_prev_bars=time_0;

      if(InpTrailingFrequency<10) // trailing only at the time of the birth of new bar

        {

         Trailing();

        }

      if(InpSignalsFrequency<10) // search for trading signals only at the time of the birth of new bar

        {

         if(!RefreshRates())

           {

            m_prev_bars=0;

            return;

           }

         //--- search for trading signals

         if(!SearchTradingSignals())

           {

            m_prev_bars=0;

            return;

           }

        }

     }

//---

  }

//+------------------------------------------------------------------+

//| TradeTransaction function                                        |

//+------------------------------------------------------------------+

void OnTradeTransaction(const MqlTradeTransaction &trans,

                        const MqlTradeRequest &request,

                        const MqlTradeResult &result)

  {

//--- get transaction type as enumeration value

   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;

//--- if transaction is result of addition of the transaction in history

   if(type==TRADE_TRANSACTION_DEAL_ADD)

     {

      ResetLastError();

      if(HistoryDealSelect(trans.deal))

         m_deal.Ticket(trans.deal);

      else

        {

         Print(__FILE__," ",__FUNCTION__,", ERROR: ","HistoryDealSelect(",trans.deal,") error: ",GetLastError());

         return;

        }

      if(m_deal.Symbol()==m_symbol.Name() && m_deal.Magic()==InpMagic)

        {

         if(m_deal.DealType()==DEAL_TYPE_BUY || m_deal.DealType()==DEAL_TYPE_SELL)

           {

            if(m_deal.Entry()==DEAL_ENTRY_IN || m_deal.Entry()==DEAL_ENTRY_INOUT)

              {

               m_need_delete_all=true;

               m_last_deal_in=iTime(m_symbol.Name(),InpWorkingPeriod,0);

               m_last_volume_in=m_deal.Volume();

               if(InpPendingCloseOpposite)

                 {

                  if(m_deal.DealType()==DEAL_TYPE_BUY)

                     m_need_close_all_sell=true;

                  if(m_deal.DealType()==DEAL_TYPE_SELL)

                     m_need_close_all_buy=true;

                 }

              }

            if(m_deal.Entry()==DEAL_ENTRY_OUT)

               m_last_volume_in=0.0;

           }

        }

     }

  }

//+------------------------------------------------------------------+

//| Refreshes the symbol quotes data                                 |

//+------------------------------------------------------------------+

bool RefreshRates()

  {

//--- refresh rates

   if(!m_symbol.RefreshRates())

     {

      Print(__FILE__," ",__FUNCTION__,", ERROR: ","RefreshRates error");

      return(false);

     }

//--- protection against the return value of "zero"

   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)

     {

      Print(__FILE__," ",__FUNCTION__,", ERROR: ","Ask == 0.0 OR Bid == 0.0");

      return(false);

     }

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Check the correctness of the position volume                     |

//+------------------------------------------------------------------+

bool CheckVolumeValue(double volume,string &error_description)

  {

//--- minimal allowed volume for trade operations

   double min_volume=m_symbol.LotsMin();

   if(volume<min_volume)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< <5=LH5 <8=8<0;L=> 4>?CAB8<>3> SYMBOL_VOLUME_MIN=%.2f",min_volume);

      else

         error_description=StringFormat("Volume is less than the minimal allowed SYMBOL_VOLUME_MIN=%.2f",min_volume);

      return(false);

     }

//--- maximal allowed volume of trade operations

   double max_volume=m_symbol.LotsMax();

   if(volume>max_volume)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< 1>;LH5 <0:A8<0;L=> 4>?CAB8<>3> SYMBOL_VOLUME_MAX=%.2f",max_volume);

      else

         error_description=StringFormat("Volume is greater than the maximal allowed SYMBOL_VOLUME_MAX=%.2f",max_volume);

      return(false);

     }

//--- get minimal step of volume changing

   double volume_step=m_symbol.LotsStep();

   int ratio=(int)MathRound(volume/volume_step);

   if(MathAbs(ratio*volume_step-volume)>0.0000001)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< =5 :@0B5= <8=8<0;L=><C H03C SYMBOL_VOLUME_STEP=%.2f, 1;8609H89 ?@028;L=K9 >1J5< %.2f",

                                        volume_step,ratio*volume_step);

      else

         error_description=StringFormat("Volume is not a multiple of the minimal step SYMBOL_VOLUME_STEP=%.2f, the closest correct volume is %.2f",

                                        volume_step,ratio*volume_step);

      return(false);

     }

   error_description="Correct volume value";

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Lot Check                                                        |

//+------------------------------------------------------------------+

double LotCheck(double lots,CSymbolInfo &symbol)

  {

//--- calculate maximum volume

   double volume=NormalizeDouble(lots,2);

   double stepvol=symbol.LotsStep();

   if(stepvol>0.0)

      volume=stepvol*MathFloor(volume/stepvol);

//---

   double minvol=symbol.LotsMin();

   if(volume<minvol)

      volume=0.0;

//---

   double maxvol=symbol.LotsMax();

   if(volume>maxvol)

      volume=maxvol;

//---

   return(volume);

  }

//+------------------------------------------------------------------+

//| Check Freeze and Stops levels                                    |

//+------------------------------------------------------------------+

void FreezeStopsLevels(double &freeze,double &stops)

  {

//--- check Freeze and Stops levels

   /*

   SYMBOL_TRADE_FREEZE_LEVEL shows the distance of freezing the trade operations

      for pending orders and open positions in points

   ------------------------|--------------------|--------------------------------------------

   Type of order/position  |  Activation price  |  Check

   ------------------------|--------------------|--------------------------------------------

   Buy Limit order         |  Ask               |  Ask-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy Stop order          |  Ask               |  OpenPrice-Ask  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Limit order        |  Bid               |  OpenPrice-Bid  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Stop order         |  Bid               |  Bid-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy position            |  Bid               |  TakeProfit-Bid >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  Bid-StopLoss   >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell position           |  Ask               |  Ask-TakeProfit >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  StopLoss-Ask   >= SYMBOL_TRADE_FREEZE_LEVEL

   ------------------------------------------------------------------------------------------



   SYMBOL_TRADE_STOPS_LEVEL determines the number of points for minimum indentation of the

      StopLoss and TakeProfit levels from the current closing price of the open position

   ------------------------------------------------|------------------------------------------

   Buying is done at the Ask price                 |  Selling is done at the Bid price

   ------------------------------------------------|------------------------------------------

   TakeProfit        >= Bid                        |  TakeProfit        <= Ask

   StopLoss          <= Bid                        |  StopLoss          >= Ask

   TakeProfit - Bid  >= SYMBOL_TRADE_STOPS_LEVEL   |  Ask - TakeProfit  >= SYMBOL_TRADE_STOPS_LEVEL

   Bid - StopLoss    >= SYMBOL_TRADE_STOPS_LEVEL   |  StopLoss - Ask    >= SYMBOL_TRADE_STOPS_LEVEL

   ------------------------------------------------------------------------------------------

   */

   double coeff=(double)InpFreezeCoefficient;

   if(!RefreshRates() || !m_symbol.Refresh())

      return;

//--- FreezeLevel -> for pending order and modification

   double freeze_level=m_symbol.FreezeLevel()*m_symbol.Point();

   if(freeze_level==0.0)

      if(InpFreezeCoefficient>0)

         freeze_level=(m_symbol.Ask()-m_symbol.Bid())*coeff;

//--- StopsLevel -> for TakeProfit and StopLoss

   double stop_level=m_symbol.StopsLevel()*m_symbol.Point();

   if(stop_level==0.0)

      if(InpFreezeCoefficient>0)

         stop_level=(m_symbol.Ask()-m_symbol.Bid())*coeff;

//---

   freeze=freeze_level;

   stops=stop_level;

//---

   return;

  }

//+------------------------------------------------------------------+

//| Print CTrade result                                              |

//+------------------------------------------------------------------+

void PrintResultTrade(CTrade &trade,CSymbolInfo &symbol)

  {

   Print(__FILE__," ",__FUNCTION__,", Symbol: ",symbol.Name()+", "+

         "Code of request result: "+IntegerToString(trade.ResultRetcode())+", "+

         "Code of request result as a string: "+trade.ResultRetcodeDescription(),

         "Trade execution mode: "+symbol.TradeExecutionDescription());

   Print("Deal ticket: "+IntegerToString(trade.ResultDeal())+", "+

         "Order ticket: "+IntegerToString(trade.ResultOrder())+", "+

         "Order retcode external: "+IntegerToString(trade.ResultRetcodeExternal())+", "+

         "Volume of deal or order: "+DoubleToString(trade.ResultVolume(),2));

   Print("Price, confirmed by broker: "+DoubleToString(trade.ResultPrice(),symbol.Digits())+", "+

         "Current bid price: "+DoubleToString(symbol.Bid(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultBid(),symbol.Digits())+", "+

         "Current ask price: "+DoubleToString(symbol.Ask(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultAsk(),symbol.Digits()));

   Print("Broker comment: "+trade.ResultComment());

  }

//+------------------------------------------------------------------+

//| Trailing                                                         |

//|   InpTrailingStop: min distance from price to Stop Loss          |

//+------------------------------------------------------------------+

void Trailing()

  {

   if(InpTrailingStop==0)

      return;

   double freeze=0.0,stops=0.0;

   FreezeStopsLevels(freeze,stops);

   /*

   SYMBOL_TRADE_FREEZE_LEVEL shows the distance of freezing the trade operations

      for pending orders and open positions in points

   ------------------------|--------------------|--------------------------------------------

   Type of order/position  |  Activation price  |  Check

   ------------------------|--------------------|--------------------------------------------

   Buy Limit order         |  Ask               |  Ask-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy Stop order          |  Ask               |  OpenPrice-Ask  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Limit order        |  Bid               |  OpenPrice-Bid  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Stop order         |  Bid               |  Bid-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy position            |  Bid               |  TakeProfit-Bid >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  Bid-StopLoss   >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell position           |  Ask               |  Ask-TakeProfit >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  StopLoss-Ask   >= SYMBOL_TRADE_FREEZE_LEVEL

   ------------------------------------------------------------------------------------------

   */

   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of open positions

      if(m_position.SelectByIndex(i))

         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)

           {

            double price_current = m_position.PriceCurrent();

            double price_open    = m_position.PriceOpen();

            double stop_loss     = m_position.StopLoss();

            double take_profit   = m_position.TakeProfit();

            double ask           = m_symbol.Ask();

            double bid           = m_symbol.Bid();

            //---

            if(m_position.PositionType()==POSITION_TYPE_BUY)

              {

               if(price_current-price_open>m_trailing_stop+m_trailing_step)

                  if(stop_loss<price_current-(m_trailing_stop+m_trailing_step))

                     if(m_trailing_stop>=freeze && (take_profit-bid>=freeze || take_profit==0.0))

                       {

                        if(!m_trade.PositionModify(m_position.Ticket(),

                                                   m_symbol.NormalizePrice(price_current-m_trailing_stop),

                                                   take_profit))

                           if(InpPrintLog)

                              Print(__FILE__," ",__FUNCTION__,", ERROR: ","Modify BUY ",m_position.Ticket(),

                                    " Position -> false. Result Retcode: ",m_trade.ResultRetcode(),

                                    ", description of result: ",m_trade.ResultRetcodeDescription());

                        if(InpPrintLog)

                          {

                           RefreshRates();

                           m_position.SelectByIndex(i);

                           PrintResultModify(m_trade,m_symbol,m_position);

                          }

                        continue;

                       }

              }

            else

              {

               if(price_open-price_current>m_trailing_stop+m_trailing_step)

                  if((stop_loss>(price_current+(m_trailing_stop+m_trailing_step))) || (stop_loss==0))

                     if(m_trailing_stop>=freeze && ask-take_profit>=freeze)

                       {

                        if(!m_trade.PositionModify(m_position.Ticket(),

                                                   m_symbol.NormalizePrice(price_current+m_trailing_stop),

                                                   take_profit))

                           if(InpPrintLog)

                              Print(__FILE__," ",__FUNCTION__,", ERROR: ","Modify SELL ",m_position.Ticket(),

                                    " Position -> false. Result Retcode: ",m_trade.ResultRetcode(),

                                    ", description of result: ",m_trade.ResultRetcodeDescription());

                        if(InpPrintLog)

                          {

                           RefreshRates();

                           m_position.SelectByIndex(i);

                           PrintResultModify(m_trade,m_symbol,m_position);

                          }

                       }

              }

           }

  }

//+------------------------------------------------------------------+

//| Print CTrade result                                              |

//+------------------------------------------------------------------+

void PrintResultModify(CTrade &trade,CSymbolInfo &symbol,CPositionInfo &position)

  {

   Print("File: ",__FILE__,", symbol: ",symbol.Name());

   Print("Code of request result: "+IntegerToString(trade.ResultRetcode()));

   Print("code of request result as a string: "+trade.ResultRetcodeDescription());

   Print("Deal ticket: "+IntegerToString(trade.ResultDeal()));

   Print("Order ticket: "+IntegerToString(trade.ResultOrder()));

   Print("Volume of deal or order: "+DoubleToString(trade.ResultVolume(),2));

   Print("Price, confirmed by broker: "+DoubleToString(trade.ResultPrice(),symbol.Digits()));

   Print("Current bid price: "+DoubleToString(symbol.Bid(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultBid(),symbol.Digits()));

   Print("Current ask price: "+DoubleToString(symbol.Ask(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultAsk(),symbol.Digits()));

   Print("Broker comment: "+trade.ResultComment());

   Print("Freeze Level: "+DoubleToString(symbol.FreezeLevel(),0),", Stops Level: "+DoubleToString(symbol.StopsLevel(),0));

   Print("Price of position opening: "+DoubleToString(position.PriceOpen(),symbol.Digits()));

   Print("Price of position's Stop Loss: "+DoubleToString(position.StopLoss(),symbol.Digits()));

   Print("Price of position's Take Profit: "+DoubleToString(position.TakeProfit(),symbol.Digits()));

   Print("Current price by position: "+DoubleToString(position.PriceCurrent(),symbol.Digits()));

  }

//+------------------------------------------------------------------+

//| Close positions                                                  |

//+------------------------------------------------------------------+

void ClosePositions(const ENUM_POSITION_TYPE pos_type)

  {

   double freeze=0.0,stops=0.0;

   FreezeStopsLevels(freeze,stops);

   /*

   SYMBOL_TRADE_FREEZE_LEVEL shows the distance of freezing the trade operations

      for pending orders and open positions in points

   ------------------------|--------------------|--------------------------------------------

   Type of order/position  |  Activation price  |  Check

   ------------------------|--------------------|--------------------------------------------

   Buy Limit order         |  Ask               |  Ask-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy Stop order          |  Ask               |  OpenPrice-Ask  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Limit order        |  Bid               |  OpenPrice-Bid  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Stop order         |  Bid               |  Bid-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy position            |  Bid               |  TakeProfit-Bid >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  Bid-StopLoss   >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell position           |  Ask               |  Ask-TakeProfit >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  StopLoss-Ask   >= SYMBOL_TRADE_FREEZE_LEVEL

   ------------------------------------------------------------------------------------------

   */

   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of current positions

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)

            if(m_position.PositionType()==pos_type)

              {

               if(m_position.PositionType()==POSITION_TYPE_BUY)

                 {

                  bool take_profit_level=((m_position.TakeProfit()!=0.0 && m_position.TakeProfit()-m_position.PriceCurrent()>=freeze) || m_position.TakeProfit()==0.0);

                  bool stop_loss_level=((m_position.StopLoss()!=0.0 && m_position.PriceCurrent()-m_position.StopLoss()>=freeze) || m_position.StopLoss()==0.0);

                  if(take_profit_level && stop_loss_level)

                     if(!m_trade.PositionClose(m_position.Ticket())) // close a position by the specified m_symbol

                        if(InpPrintLog)

                           Print(__FILE__," ",__FUNCTION__,", ERROR: ","BUY PositionClose ",m_position.Ticket(),", ",m_trade.ResultRetcodeDescription());

                 }

               if(m_position.PositionType()==POSITION_TYPE_SELL)

                 {

                  bool take_profit_level=((m_position.TakeProfit()!=0.0 && m_position.PriceCurrent()-m_position.TakeProfit()>=freeze) || m_position.TakeProfit()==0.0);

                  bool stop_loss_level=((m_position.StopLoss()!=0.0 && m_position.StopLoss()-m_position.PriceCurrent()>=freeze) || m_position.StopLoss()==0.0);

                  if(take_profit_level && stop_loss_level)

                     if(!m_trade.PositionClose(m_position.Ticket())) // close a position by the specified m_symbol

                        if(InpPrintLog)

                           Print(__FILE__," ",__FUNCTION__,", ERROR: ","SELL PositionClose ",m_position.Ticket(),", ",m_trade.ResultRetcodeDescription());

                 }

              }

  }

//+------------------------------------------------------------------+

//| Calculate all positions                                          |

//|  'lots_limit=true' - only for 'if(m_symbol.LotsLimit()>0.0)'     |

//+------------------------------------------------------------------+

void CalculateAllPositions(int &count_buys,double &volume_buys,double &volume_biggest_buys,

                           int &count_sells,double &volume_sells,double &volume_biggest_sells,

                           bool lots_limit=false)

  {

   count_buys  = 0;

   volume_buys   = 0.0;

   volume_biggest_buys  = 0.0;

   count_sells = 0;

   volume_sells  = 0.0;

   volume_biggest_sells = 0.0;

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==m_symbol.Name() && (lots_limit || (!lots_limit && m_position.Magic()==InpMagic)))

           {

            if(m_position.PositionType()==POSITION_TYPE_BUY)

              {

               count_buys++;

               volume_buys+=m_position.Volume();

               if(m_position.Volume()>volume_biggest_buys)

                  volume_biggest_buys=m_position.Volume();

               continue;

              }

            else

               if(m_position.PositionType()==POSITION_TYPE_SELL)

                 {

                  count_sells++;

                  volume_sells+=m_position.Volume();

                  if(m_position.Volume()>volume_biggest_sells)

                     volume_biggest_sells=m_position.Volume();

                 }

           }

  }

//+------------------------------------------------------------------+

//| Search trading signals                                           |

//+------------------------------------------------------------------+

bool SearchTradingSignals(void)

  {

   if(iTime(m_symbol.Name(),InpWorkingPeriod,0)==m_last_deal_in) // on one bar - only one deal

      return(true);

   MqlRates rates[];

   ArraySetAsSeries(rates,true);

   int start_pos=0,count=(InpPendingWindowWidth<3)?3:InpPendingWindowWidth;

   if(CopyRates(m_symbol.Name(),Period(),start_pos,count,rates)!=count)

      return(false);

   double price_max=DBL_MIN,price_min=DBL_MAX;

   datetime time_max=0,time_min=0;

   for(int i=0; i<count; i++)

     {

      if(rates[i].high>price_max)

        {

         price_max=rates[i].high;

         time_max=rates[i].time;

        }

      if(rates[i].low<price_min)

        {

         price_min=rates[i].low;

         time_min=rates[i].time;

        }

     }

   if(price_max==DBL_MIN || price_min==DBL_MAX)

      return(false);

   if(ObjectFind(0,m_rectangles_name)<0)

     {

      RectangleCreate(0,m_rectangles_name,0,rates[count-1].time/*time_max*/,price_max,rates[0].time/*time_min*/,price_min,

                      Inp_Rectangle_Color,Inp_Rectangle_Style,Inp_Rectangle_Width,Inp_Rectangle_Fill,Inp_Rectangle_Back,

                      Inp_Rectangle_Selection,Inp_Rectangle_Hidden,Inp_Rectangle_ZOrder);

     }

   else

     {

      RectanglePointChange(0,m_rectangles_name,0,rates[count-1].time/*time_max*/,price_max);

      RectanglePointChange(0,m_rectangles_name,1,rates[0].time/*time_min*/,price_min);

     }

   int count_buy_limits=0,count_sell_limits=0,count_buy_stops=0,count_sell_stops=0;

   CalculateAllPendingOrders(count_buy_limits,count_sell_limits,count_buy_stops,count_sell_stops);

//---

   int size_need_pending=ArraySize(SPending);

   if(size_need_pending>0)

      return(true);

//---

   if(InpPendingTypeMax==sell_limit && count_sell_limits==0)

     {

      ArrayResize(SPending,size_need_pending+1);

      SPending[size_need_pending].pending_type=ORDER_TYPE_BUY_LIMIT;

      SPending[size_need_pending].price=(m_pending_indent>0.0)?price_max+m_pending_indent:price_max;

      if(InpPendingExpiration>0)

         SPending[size_need_pending].expiration=(long)(InpPendingExpiration*60);

      if(InpPrintLog)

         Print(__FILE__," ",__FUNCTION__,", OK: ","Signal BUY LIMIT");

     }

   else

      if(InpPendingTypeMax==buy_stop && count_buy_stops==0)

        {

         ArrayResize(SPending,size_need_pending+1);

         SPending[size_need_pending].pending_type=ORDER_TYPE_BUY_STOP;

         SPending[size_need_pending].price=(m_pending_indent>0.0)?price_max+m_pending_indent:price_max;

         if(InpPendingExpiration>0)

            SPending[size_need_pending].expiration=(long)(InpPendingExpiration*60);

         if(InpPrintLog)

            Print(__FILE__," ",__FUNCTION__,", OK: ","Signal BUY STOP");

        }

//---

   size_need_pending=ArraySize(SPending);

   if(InpPendingTypeMin==buy_limit && count_buy_limits==0)

     {

      ArrayResize(SPending,size_need_pending+1);

      SPending[size_need_pending].pending_type=ORDER_TYPE_BUY_LIMIT;

      SPending[size_need_pending].price=(m_pending_indent>0.0)?price_min-m_pending_indent:price_min;

      if(InpPendingExpiration>0)

         SPending[size_need_pending].expiration=(long)(InpPendingExpiration*60);

      if(InpPrintLog)

         Print(__FILE__," ",__FUNCTION__,", OK: ","Signal BUY LIMIT");

     }

   else

      if(InpPendingTypeMin==sell_stop && count_sell_stops==0)

        {

         ArrayResize(SPending,size_need_pending+1);

         SPending[size_need_pending].pending_type=ORDER_TYPE_SELL_STOP;

         SPending[size_need_pending].price=(m_pending_indent>0.0)?price_min-m_pending_indent:price_min;

         if(InpPendingExpiration>0)

            SPending[size_need_pending].expiration=(long)(InpPendingExpiration*60);

         if(InpPrintLog)

            Print(__FILE__," ",__FUNCTION__,", OK: ","Signal SEL STOP");

        }

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Delete all pending orders                                        |

//+------------------------------------------------------------------+

void DeleteAllPendingOrders(void)

  {

   double freeze=0.0,stops=0.0;

   FreezeStopsLevels(freeze,stops);

   /*

   SYMBOL_TRADE_FREEZE_LEVEL shows the distance of freezing the trade operations

      for pending orders and open positions in points

   ------------------------|--------------------|--------------------------------------------

   Type of order/position  |  Activation price  |  Check

   ------------------------|--------------------|--------------------------------------------

   Buy Limit order         |  Ask               |  Ask-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy Stop order          |  Ask               |  OpenPrice-Ask  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Limit order        |  Bid               |  OpenPrice-Bid  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Stop order         |  Bid               |  Bid-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy position            |  Bid               |  TakeProfit-Bid >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  Bid-StopLoss   >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell position           |  Ask               |  Ask-TakeProfit >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  StopLoss-Ask   >= SYMBOL_TRADE_FREEZE_LEVEL

   ------------------------------------------------------------------------------------------

   */

//---

   for(int i=OrdersTotal()-1; i>=0; i--) // returns the number of current orders

      if(m_order.SelectByIndex(i))     // selects the pending order by index for further access to its properties

         if(m_order.Symbol()==m_symbol.Name() && m_order.Magic()==InpMagic)

           {

            if(m_order.OrderType()==ORDER_TYPE_BUY_LIMIT)

              {

               if(m_symbol.Ask()-m_order.PriceOpen()>=freeze)

                  if(!m_trade.OrderDelete(m_order.Ticket()))

                     if(InpPrintLog)

                        Print(__FILE__," ",__FUNCTION__,", ERROR: ","CTrade.OrderDelete ",m_order.Ticket());

               continue;

              }

            if(m_order.OrderType()==ORDER_TYPE_BUY_STOP)

              {

               if(m_order.PriceOpen()-m_symbol.Ask()>=freeze)

                  if(!m_trade.OrderDelete(m_order.Ticket()))

                     if(InpPrintLog)

                        Print(__FILE__," ",__FUNCTION__,", ERROR: ","CTrade.OrderDelete ",m_order.Ticket());

               continue;

              }

            if(m_order.OrderType()==ORDER_TYPE_SELL_LIMIT)

              {

               if(m_order.PriceOpen()-m_symbol.Bid()>=freeze)

                  if(!m_trade.OrderDelete(m_order.Ticket()))

                     if(InpPrintLog)

                        Print(__FILE__," ",__FUNCTION__,", ERROR: ","CTrade.OrderDelete ",m_order.Ticket());

               continue;

              }

            if(m_order.OrderType()==ORDER_TYPE_SELL_STOP)

              {

               if(m_symbol.Bid()-m_order.PriceOpen()>=freeze)

                  if(!m_trade.OrderDelete(m_order.Ticket()))

                     if(InpPrintLog)

                        Print(__FILE__," ",__FUNCTION__,", ERROR: ","CTrade.OrderDelete ",m_order.Ticket());

               continue;

              }

           }

  }

//+------------------------------------------------------------------+

//| Is pending orders exists                                         |

//+------------------------------------------------------------------+

bool IsPendingOrdersExists(void)

  {

   for(int i=OrdersTotal()-1; i>=0; i--) // returns the number of current orders

      if(m_order.SelectByIndex(i))     // selects the pending order by index for further access to its properties

         if(m_order.Symbol()==m_symbol.Name() && m_order.Magic()==InpMagic)

            return(true);

//---

   return(false);

  }

//+------------------------------------------------------------------+

//| Place Orders                                                     |

//+------------------------------------------------------------------+

void PlaceOrders(const int index)

  {

   double freeze=0.0,stops=0.0;

   FreezeStopsLevels(freeze,stops);

   /*

   SYMBOL_TRADE_STOPS_LEVEL determines the number of points for minimum indentation of the

      StopLoss and TakeProfit levels from the current closing price of the open position

   ------------------------------------------------|------------------------------------------

   Buying is done at the Ask price                 |  Selling is done at the Bid price

   ------------------------------------------------|------------------------------------------

   TakeProfit        >= Bid                        |  TakeProfit        <= Ask

   StopLoss          <= Bid                        |  StopLoss          >= Ask

   TakeProfit - Bid  >= SYMBOL_TRADE_STOPS_LEVEL   |  Ask - TakeProfit  >= SYMBOL_TRADE_STOPS_LEVEL

   Bid - StopLoss    >= SYMBOL_TRADE_STOPS_LEVEL   |  StopLoss - Ask    >= SYMBOL_TRADE_STOPS_LEVEL

   ------------------------------------------------------------------------------------------

   */

   double spread=m_symbol.Ask()-m_symbol.Bid();

   if(m_pending_max_spread>0.0 && spread>m_pending_max_spread)

     {

      m_waiting_pending_order=false;

      if(InpPrintLog)

         Print(__FILE__," ",__FUNCTION__,

               ", ERROR: ","Spread Ask-Bid (",DoubleToString(spread,m_symbol.Digits()),")",

               " > Maximum spread (",DoubleToString(m_pending_max_spread,m_symbol.Digits()),")");

      return;

     }

//--- lot martingale

   if(ProfitAllPositions()<0.0)

     {

      SPending[index].volume=m_last_volume_in*InpCoefficient;

      //--- protection

      if(SPending[index].volume==0.0)

         DebugBreak();

     }

//--- buy limit

   if(SPending[index].pending_type==ORDER_TYPE_BUY_LIMIT)

     {

      if(SPending[index].price==0.0)

         SPending[index].price=m_symbol.Ask()-m_pending_indent;

      if(m_symbol.Ask()-SPending[index].price<stops) // check price

         SPending[index].price=m_symbol.Ask()-stops;

      SPending[index].stop_loss=(m_stop_loss==0.0)?0.0:SPending[index].price-m_stop_loss;

      SPending[index].take_profit=(m_take_profit==0.0)?0.0:SPending[index].price+m_take_profit;

      double sl=SPending[index].stop_loss;

      if(sl<=0.0) // check sl

         sl=0.0;

      else

         if(SPending[index].price-sl<stops)

            sl=SPending[index].price-stops;

      double tp=SPending[index].take_profit;

      if(tp<=0.0) // check tp

         tp=0.0;

      else

         if(tp-SPending[index].price<stops)

            tp=SPending[index].price+stops;

      PendingOrder(index,sl,tp);

      ArrayRemove(SPending,index,1);

      m_waiting_pending_order=false;

      return;

     }

//--- sell limit

   if(SPending[index].pending_type==ORDER_TYPE_SELL_LIMIT)

     {

      if(SPending[index].price==0.0)

         SPending[index].price=m_symbol.Bid()+m_pending_indent;

      if(SPending[index].price-m_symbol.Bid()<stops) // check price

         SPending[index].price=m_symbol.Bid()+stops;

      SPending[index].stop_loss=(m_stop_loss==0.0)?0.0:SPending[index].price+m_stop_loss;

      SPending[index].take_profit=(m_take_profit==0.0)?0.0:SPending[index].price-m_take_profit;

      double sl=SPending[index].stop_loss;

      if(sl<=0.0) // check sl

         sl=0.0;

      else

         if(sl-SPending[index].price<stops)

            sl=SPending[index].price+stops;

      double tp=SPending[index].take_profit;

      if(tp<=0.0) // check tp

         tp=0.0;

      else

         if(SPending[index].price-tp<stops)

            tp=SPending[index].price-stops;

      PendingOrder(index,sl,tp);

      ArrayRemove(SPending,index,1);

      m_waiting_pending_order=false;

      return;

     }

//--- buy stop

   if(SPending[index].pending_type==ORDER_TYPE_BUY_STOP)

     {

      if(SPending[index].price==0.0)

         SPending[index].price=m_symbol.Ask()+m_pending_indent;

      if(SPending[index].price-m_symbol.Ask()<stops) // check price

         SPending[index].price=m_symbol.Ask()+stops;

      SPending[index].stop_loss=(m_stop_loss==0.0)?0.0:SPending[index].price-m_stop_loss;

      SPending[index].take_profit=(m_take_profit==0.0)?0.0:SPending[index].price+m_take_profit;

      double sl=SPending[index].stop_loss;

      if(sl<=0.0)// check sl

         sl=0.0;

      else

         if(SPending[index].price-sl<stops)

            sl=SPending[index].price-stops;

      double tp=SPending[index].take_profit;

      if(tp<=0.0) // check tp

         tp=0.0;

      else

         if(tp-SPending[index].price<stops)

            tp=SPending[index].price+stops;

      PendingOrder(index,sl,tp);

      ArrayRemove(SPending,index,1);

      m_waiting_pending_order=false;

      return;

     }

//--- sell stop

   if(SPending[index].pending_type==ORDER_TYPE_SELL_STOP)

     {

      if(SPending[index].price==0.0)

         SPending[index].price=m_symbol.Bid()-m_pending_indent;

      if(m_symbol.Bid()-SPending[index].price<stops) // check price

         SPending[index].price=m_symbol.Bid()-stops;

      SPending[index].stop_loss=(m_stop_loss==0.0)?0.0:SPending[index].price+m_stop_loss;

      SPending[index].take_profit=(m_take_profit==0.0)?0.0:SPending[index].price-m_take_profit;

      double sl=SPending[index].stop_loss;

      if(sl<=0.0) // check sl

         sl=0.0;

      else

         if(sl-SPending[index].price<stops)

            sl=SPending[index].price+stops;

      double tp=SPending[index].take_profit;

      if(tp<=0.0) // check tp

         tp=0.0;

      else

         if(SPending[index].price-tp<stops)

            tp=SPending[index].price-stops;

      PendingOrder(index,sl,tp);

      ArrayRemove(SPending,index,1);

      m_waiting_pending_order=false;

      return;

     }

  }

//+------------------------------------------------------------------+

//| Pending order                                                    |

//+------------------------------------------------------------------+

bool PendingOrder(const int index,double sl,double tp)

  {

   sl=m_symbol.NormalizePrice(sl);

   tp=m_symbol.NormalizePrice(tp);

   ENUM_ORDER_TYPE check_order_type=WRONG_VALUE;

   double long_lot=0.0;

   double short_lot=0.0;

   double check_lot=0.0;

   double check_price=0.0;

//--- check volume before OrderSend to avoid "not enough money" error (CTrade)

   switch(SPending[index].pending_type)

     {

      case  ORDER_TYPE_BUY:

         check_order_type=ORDER_TYPE_BUY;

         break;

      case ORDER_TYPE_SELL:

         check_order_type=ORDER_TYPE_SELL;

         break;

      case ORDER_TYPE_BUY_LIMIT:

         check_order_type=ORDER_TYPE_BUY;

         break;

      case ORDER_TYPE_SELL_LIMIT:

         check_order_type=ORDER_TYPE_SELL;

         break;

      case ORDER_TYPE_BUY_STOP:

         check_order_type=ORDER_TYPE_BUY;

         break;

      case ORDER_TYPE_SELL_STOP:

         check_order_type=ORDER_TYPE_SELL;

         break;

      default:

         return(false);

         break;

     }

   if(SPending[index].volume>0.0)

      check_lot=SPending[index].volume;

   else

     {

      //---

      if(InpLotOrRisk==risk)

        {

         bool error=false;

         long_lot=m_money.CheckOpenLong(m_symbol.Ask(),sl);

         if(InpPrintLog)

            Print(__FILE__," ",__FUNCTION__,", OK: ","sl=",DoubleToString(sl,m_symbol.Digits()),

                  ", CheckOpenLong: ",DoubleToString(long_lot,2),

                  ", Balance: ",    DoubleToString(m_account.Balance(),2),

                  ", Equity: ",     DoubleToString(m_account.Equity(),2),

                  ", FreeMargin: ", DoubleToString(m_account.FreeMargin(),2));

         if(long_lot==0.0)

           {

            if(InpPrintLog)

               Print(__FILE__," ",__FUNCTION__,", ERROR: ","CMoneyFixedMargin.CheckOpenLong returned the value of \"0.0\"");

            error=true;

           }

         //---

         short_lot=m_money.CheckOpenShort(m_symbol.Bid(),sl);

         if(InpPrintLog)

            Print(__FILE__," ",__FUNCTION__,", OK: ","sl=",DoubleToString(sl,m_symbol.Digits()),

                  ", CheckOpenLong: ",DoubleToString(short_lot,2),

                  ", Balance: ",    DoubleToString(m_account.Balance(),2),

                  ", Equity: ",     DoubleToString(m_account.Equity(),2),

                  ", FreeMargin: ", DoubleToString(m_account.FreeMargin(),2));

         if(short_lot==0.0)

           {

            if(InpPrintLog)

               Print(__FILE__," ",__FUNCTION__,", ERROR: ","CMoneyFixedMargin.CheckOpenShort returned the value of \"0.0\"");

            error=true;

           }

         //---

         if(error)

            return(false);

        }

      else

         if(InpLotOrRisk==lot)

           {

            long_lot=InpVolumeLotOrRisk;

            short_lot=InpVolumeLotOrRisk;

           }

         else

            if(InpLotOrRisk==lots_min)

              {

               long_lot=m_symbol.LotsMin();

               short_lot=m_symbol.LotsMin();

              }

            else

               return(false);

     }

//--- check volume before OrderSend to avoid "not enough money" error (CTrade)

   if(check_order_type==ORDER_TYPE_BUY)

     {

      check_price=m_symbol.Ask();

      if(SPending[index].volume==0.0)

         check_lot=long_lot;

     }

   else

     {

      check_price=m_symbol.Bid();

      if(SPending[index].volume==0.0)

         check_lot=short_lot;

     }

//---

   if(m_symbol.LotsLimit()>0.0)

     {

      double volume_buys        = 0.0;

      double volume_sells       = 0.0;

      double volume_buy_limits  = 0.0;

      double volume_sell_limits = 0.0;

      double volume_buy_stops   = 0.0;

      double volume_sell_stops  = 0.0;

      CalculateAllVolumes(volume_buys,volume_sells,

                          volume_buy_limits,volume_sell_limits,

                          volume_buy_stops,volume_sell_stops);

      if(volume_buys+volume_sells+

         volume_buy_limits+volume_sell_limits+

         volume_buy_stops+volume_sell_stops+check_lot>m_symbol.LotsLimit())

        {

         if(InpPrintLog)

            Print(__FILE__," ",__FUNCTION__,", ERROR: ","#0 ,",EnumToString(SPending[index].pending_type),", ",

                  "Volume Buy's (",DoubleToString(volume_buys,2),")",

                  "Volume Sell's (",DoubleToString(volume_sells,2),")",

                  "Volume Buy limit's (",DoubleToString(volume_buy_limits,2),")",

                  "Volume Sell limit's (",DoubleToString(volume_sell_limits,2),")",

                  "Volume Buy stops's (",DoubleToString(volume_buy_stops,2),")",

                  "Volume Sell stops's (",DoubleToString(volume_sell_stops,2),")",

                  "Check lot (",DoubleToString(check_lot,2),")",

                  " > Lots Limit (",DoubleToString(m_symbol.LotsLimit(),2),")");

         return(false);

        }

     }

//--- check maximal number of allowed pending orders

   int account_limit_orders=m_account.LimitOrders();

   if(account_limit_orders>0)

     {

      int all_pending_orders=CalculateAllPendingOrders();

      /*

            there is 8,  and there will be  9 > restriction 10 -> OK

            there is 9,  and there will be 10 > restriction 10 -> OK

            there is 10, and there will be 11 > restriction 10 -> ERROR

      */

      if(all_pending_orders+1>account_limit_orders)

         return(false);

     }

//--- lot protection

   if(InpMaxLot>0.0 && check_lot>=InpMaxLot)

     {

      m_need_close_all=true;

      m_need_delete_all=true;

      m_last_volume_in=0.0;

      ArrayFree(SPending);

      if(InpPrintLog)

         Print(__FILE__," ",__FUNCTION__,", ERROR: ","check_lot (",DoubleToString(check_lot,2),") >= 'Maximum lot' (",DoubleToString(InpMaxLot,2),")");

      return(false);

     }

//--- check volume before OrderSend to avoid "not enough money" error (CTrade)

   double free_margin_check=m_account.FreeMarginCheck(m_symbol.Name(),

                            check_order_type,check_lot,check_price);

   double margin_check=m_account.MarginCheck(m_symbol.Name(),

                       check_order_type,check_lot,SPending[index].price);

   if(free_margin_check>margin_check)

     {

      bool result=false;

      if(SPending[index].expiration>0)

        {

         datetime time_expiration=TimeCurrent()+(datetime)SPending[index].expiration;

         result=m_trade.OrderOpen(m_symbol.Name(),

                                  SPending[index].pending_type,check_lot,0.0,

                                  m_symbol.NormalizePrice(SPending[index].price),

                                  m_symbol.NormalizePrice(sl),

                                  m_symbol.NormalizePrice(tp),

                                  ORDER_TIME_SPECIFIED,

                                  time_expiration);

        }

      else

        {

         result=m_trade.OrderOpen(m_symbol.Name(),

                                  SPending[index].pending_type,check_lot,0.0,

                                  m_symbol.NormalizePrice(SPending[index].price),

                                  m_symbol.NormalizePrice(sl),

                                  m_symbol.NormalizePrice(tp));

        }

      if(result)

        {

         if(m_trade.ResultOrder()==0)

           {

            if(InpPrintLog)

               Print(__FILE__," ",__FUNCTION__,", ERROR: ","#1 ",EnumToString(SPending[index].pending_type)," -> false. Result Retcode: ",m_trade.ResultRetcode(),

                     ", description of result: ",m_trade.ResultRetcodeDescription());

            if(InpPrintLog)

               PrintResultTrade(m_trade,m_symbol);

            return(false);

           }

         else

           {

            if(InpPrintLog)

               Print(__FILE__," ",__FUNCTION__,", OK: ","#2 ",EnumToString(SPending[index].pending_type)," -> true. Result Retcode: ",m_trade.ResultRetcode(),

                     ", description of result: ",m_trade.ResultRetcodeDescription());

            if(InpPrintLog)

               PrintResultTrade(m_trade,m_symbol);

            return(true);

           }

        }

      else

        {

         if(InpPrintLog)

            Print(__FILE__," ",__FUNCTION__,", ERROR: ","#3 ",EnumToString(SPending[index].pending_type)," -> false. Result Retcode: ",m_trade.ResultRetcode(),

                  ", description of result: ",m_trade.ResultRetcodeDescription());

         if(InpPrintLog)

            PrintResultTrade(m_trade,m_symbol);

         return(false);

        }

     }

   else

     {

      if(InpPrintLog)

         Print(__FILE__," ",__FUNCTION__,", ERROR: CAccountInfo.FreeMarginCheck returned the value ",DoubleToString(free_margin_check,2));

      return(false);

     }

//---

   return(false);

  }

//+------------------------------------------------------------------+

//| Calculate all volumes                                            |

//+------------------------------------------------------------------+

void CalculateAllVolumes(double &volumne_buys,double &volumne_sells,

                         double &volumne_buy_limits,double &volumne_sell_limits,

                         double &volumne_buy_stops,double &volumne_sell_stops)

  {

   volumne_buys         = 0.0;

   volumne_sells        = 0.0;

   volumne_buy_limits   = 0.0;

   volumne_sell_limits  = 0.0;

   volumne_buy_stops    = 0.0;

   volumne_sell_stops   = 0.0;

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==m_symbol.Name())

           {

            if(m_position.PositionType()==POSITION_TYPE_BUY)

               volumne_buys+=m_position.Volume();

            else

               if(m_position.PositionType()==POSITION_TYPE_SELL)

                  volumne_sells+=m_position.Volume();

           }

   for(int i=OrdersTotal()-1; i>=0; i--) // returns the number of current orders

      if(m_order.SelectByIndex(i)) // selects the pending order by index for further access to its properties

         if(m_order.Symbol()==m_symbol.Name())

           {

            if(m_order.OrderType()==ORDER_TYPE_BUY_LIMIT)

               volumne_buy_limits+=m_order.VolumeInitial();

            else

               if(m_order.OrderType()==ORDER_TYPE_SELL_LIMIT)

                  volumne_sell_limits+=m_order.VolumeInitial();

               else

                  if(m_order.OrderType()==ORDER_TYPE_BUY_STOP)

                     volumne_buy_stops+=m_order.VolumeInitial();

                  else

                     if(m_order.OrderType()==ORDER_TYPE_SELL_STOP)

                        volumne_sell_stops+=m_order.VolumeInitial();

           }

  }

//+------------------------------------------------------------------+

//| Is position exists                                               |

//+------------------------------------------------------------------+

bool IsPositionExists(void)

  {

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)

            return(true);

//---

   return(false);

  }

//+------------------------------------------------------------------+

//| Close all positions                                              |

//+------------------------------------------------------------------+

void CloseAllPositions(void)

  {

   double freeze=0.0,stops=0.0;

   FreezeStopsLevels(freeze,stops);

   /*

   SYMBOL_TRADE_FREEZE_LEVEL shows the distance of freezing the trade operations

      for pending orders and open positions in points

   ------------------------|--------------------|--------------------------------------------

   Type of order/position  |  Activation price  |  Check

   ------------------------|--------------------|--------------------------------------------

   Buy Limit order         |  Ask               |  Ask-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy Stop order          |  Ask               |  OpenPrice-Ask  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Limit order        |  Bid               |  OpenPrice-Bid  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Stop order         |  Bid               |  Bid-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy position            |  Bid               |  TakeProfit-Bid >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  Bid-StopLoss   >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell position           |  Ask               |  Ask-TakeProfit >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  StopLoss-Ask   >= SYMBOL_TRADE_FREEZE_LEVEL

   ------------------------------------------------------------------------------------------

   */

   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of current positions

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)

           {

            if(m_position.PositionType()==POSITION_TYPE_BUY)

              {

               bool take_profit_level=(m_position.TakeProfit()!=0.0 && m_position.TakeProfit()-m_position.PriceCurrent()>=freeze) || m_position.TakeProfit()==0.0;

               bool stop_loss_level=(m_position.StopLoss()!=0.0 && m_position.PriceCurrent()-m_position.StopLoss()>=freeze) || m_position.StopLoss()==0.0;

               if(take_profit_level && stop_loss_level)

                  if(!m_trade.PositionClose(m_position.Ticket())) // close a position by the specified m_symbol

                     if(InpPrintLog)

                        Print(__FILE__," ",__FUNCTION__,", ERROR: ","BUY PositionClose ",m_position.Ticket(),", ",m_trade.ResultRetcodeDescription());

              }

            if(m_position.PositionType()==POSITION_TYPE_SELL)

              {

               bool take_profit_level=(m_position.TakeProfit()!=0.0 && m_position.PriceCurrent()-m_position.TakeProfit()>=freeze) || m_position.TakeProfit()==0.0;

               bool stop_loss_level=(m_position.StopLoss()!=0.0 && m_position.StopLoss()-m_position.PriceCurrent()>=freeze) || m_position.StopLoss()==0.0;

               if(take_profit_level && stop_loss_level)

                  if(!m_trade.PositionClose(m_position.Ticket())) // close a position by the specified m_symbol

                     if(InpPrintLog)

                        Print(__FILE__," ",__FUNCTION__,", ERROR: ","SELL PositionClose ",m_position.Ticket(),", ",m_trade.ResultRetcodeDescription());

              }

           }

  }

//+------------------------------------------------------------------+

//| Calculate all pending orders                                     |

//+------------------------------------------------------------------+

int CalculateAllPendingOrders(void)

  {

   int count=0;

   for(int i=OrdersTotal()-1; i>=0; i--) // returns the number of current orders

      if(m_order.SelectByIndex(i))     // selects the pending order by index for further access to its properties

         count++;

//---

   return(count);

  }

//+------------------------------------------------------------------+

//| Calculate all pending orders                                     |

//+------------------------------------------------------------------+

void CalculateAllPendingOrders(int &count_buy_limits,int &count_sell_limits,int &count_buy_stops,int &count_sell_stops)

  {

   count_buy_limits  = 0;

   count_sell_limits = 0;

   count_buy_stops   = 0;

   count_sell_stops  = 0;

   for(int i=OrdersTotal()-1; i>=0; i--) // returns the number of current orders

      if(m_order.SelectByIndex(i))     // selects the pending order by index for further access to its properties

         if(m_order.Symbol()==m_symbol.Name() && m_order.Magic()==InpMagic)

           {

            if(m_order.OrderType()==ORDER_TYPE_BUY_LIMIT)

               count_buy_limits++;

            else

               if(m_order.OrderType()==ORDER_TYPE_SELL_LIMIT)

                  count_sell_limits++;

               else

                  if(m_order.OrderType()==ORDER_TYPE_BUY_STOP)

                     count_buy_stops++;

                  else

                     if(m_order.OrderType()==ORDER_TYPE_SELL_STOP)

                        count_sell_stops++;

           }

  }

//+------------------------------------------------------------------+

//| Profit all positions                                             |

//+------------------------------------------------------------------+

double ProfitAllPositions(void)

  {

   double profit=0.0;

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==m_symbol.Name() && m_position.Magic()==InpMagic)

            profit+=m_position.Commission()+m_position.Swap()+m_position.Profit();

//---

   return(profit);

  }

//+------------------------------------------------------------------+

//| Create rectangle by the given coordinates                        |

//+------------------------------------------------------------------+

bool RectangleCreate(const long            chart_ID=0,        // chart's ID

                     const string          name="Rectangle",  // rectangle name

                     const int             sub_window=0,      // subwindow index

                     datetime              time1=0,           // first point time

                     double                price1=0,          // first point price

                     datetime              time2=0,           // second point time

                     double                price2=0,          // second point price

                     const color           clr=clrRed,        // rectangle color

                     const ENUM_LINE_STYLE style=STYLE_SOLID, // style of rectangle lines

                     const int             width=1,           // width of rectangle lines

                     const bool            fill=false,        // filling rectangle with color

                     const bool            back=false,        // in the background

                     const bool            selection=true,    // highlight to move

                     const bool            hidden=true,       // hidden in the object list

                     const long            z_order=0)         // priority for mouse click

  {

////--- set anchor points' coordinates if they are not set

//ChangeRectangleEmptyPoints(time1,price1,time2,price2);

//--- reset the error value

   ResetLastError();

//--- create a rectangle by the given coordinates

   if(!ObjectCreate(chart_ID,name,OBJ_RECTANGLE,sub_window,time1,price1,time2,price2))

     {

      Print(__FUNCTION__,

            ": failed to create a rectangle! Error code = ",GetLastError());

      return(false);

     }

//--- set rectangle color

   ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);

//--- set the style of rectangle lines

   ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);

//--- set width of the rectangle lines

   ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);

//--- enable (true) or disable (false) the mode of filling the rectangle

   ObjectSetInteger(chart_ID,name,OBJPROP_FILL,fill);

//--- display in the foreground (false) or background (true)

   ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);

//--- enable (true) or disable (false) the mode of highlighting the rectangle for moving

//--- when creating a graphical object using ObjectCreate function, the object cannot be

//--- highlighted and moved by default. Inside this method, selection parameter

//--- is true by default making it possible to highlight and move the object

   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);

   ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);

//--- hide (true) or display (false) graphical object name in the object list

   ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);

//--- set the priority for receiving the event of a mouse click in the chart

   ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);

//--- successful execution

   return(true);

  }

//+------------------------------------------------------------------+

//| Move the rectangle anchor point                                  |

//+------------------------------------------------------------------+

bool RectanglePointChange(const long   chart_ID=0,       // chart's ID

                          const string name="Rectangle", // rectangle name

                          const int    point_index=0,    // anchor point index

                          datetime     time=0,           // anchor point time coordinate

                          double       price=0)          // anchor point price coordinate

  {

//--- if point position is not set, move it to the current bar having Bid price

   if(!time)

      time=TimeCurrent();

   if(!price)

      price=SymbolInfoDouble(Symbol(),SYMBOL_BID);

//--- reset the error value

   ResetLastError();

//--- move the anchor point

   if(!ObjectMove(chart_ID,name,point_index,time,price))

     {

      Print(__FUNCTION__,

            ": failed to move the anchor point! Error code = ",GetLastError());

      return(false);

     }

//--- successful execution

   return(true);

  }

//+------------------------------------------------------------------+