metro_xrsx_htf_signal

//+------------------------------------------------------------------+ 
//|                                        METRO_XRSX_HTF_Signal.mq5 | 
//|                               Copyright © 2016, Nikolay Kositsin | 
//|                              Khabarovsk,   farria@mail.redcom.ru | 
//+------------------------------------------------------------------+ 
#property copyright "Copyright © 2016, Nikolay Kositsin"
#property link "farria@mail.redcom.ru" 
//---- íîìåð âåðñèè èíäèêàòîðà
#property version   "1.60"
//+------------------------------------------------+ 
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà                 |
//+------------------------------------------------+ 
//---- îòðèñîâêà èíäèêàòîðà â ãëàâíîì îêíå
#property indicator_chart_window 
#property indicator_buffers 1
#property indicator_plots   1
//+------------------------------------------------+ 
//| Îáúÿâëåíèå êîíñòàíò                            |
//+------------------------------------------------+
#define INDICATOR_NAME      "METRO_XRSX"        // Èìÿ èíäèêàòîðà
#define RESET               0                   // Êîíñòàíòà äëÿ âîçâðàòà òåðìèíàëó êîìàíäû íà ïåðåñ÷åò èíäèêàòîðà
#define NAMES_SYMBOLS_FONT  "Georgia"           // Øðèôò äëÿ íàçâàíèÿ èíäèêàòîðà
#define SIGNAL_SYMBOLS_FONT "Wingdings"         // Øðèôò äëÿ ñèìâîëà âõîäà â ïîçèöèþ
#define TREND_SYMBOLS_FONT  "Wingdings"         // Øðèôò äëÿ ñèìâîëà òðåíäà
#define UP_SIGNAL_SYMBOL    "ì"                 // Ñèìâîë äëÿ îòêðûâàíèÿ long
#define DN_SIGNAL_SYMBOL    "î"                 // Ñèìâîë äëÿ îòêðûâàíèÿ short
#define UP_TREND_SYMBOL     "]"                 // Ñèìâîë äëÿ ðàñòóùåãî òðåíäà
#define DN_TREND_SYMBOL     "]"                 // Ñèìâîë äëÿ ïàäàþùåãî òðåíäà
#define BUY_SOUND           "alert.wav"         // Çâóêîâîé ôàéë äëÿ âõîäà â long
#define SELL_SOUND          "alert.wav"         // Çâóêîâîé ôàéë äëÿ âõîäà â short
#define BUY_ALERT_TEXT      "Buy signal"        // Òåêñò àëåðòà äëÿ âõîäà â long
#define SELL_ALERT_TEXT     "Sell signal"       // Òåêñò àëåðòà äëÿ âõîäà â short
#define ENAM_EMPTY_VALUE    0.0                 // Çíà÷åíèå äëÿ EMPTY_VALUE
//+------------------------------------------------+ 
//| Ïåðå÷èñëåíèå äëÿ èíäèêàöèè ñðàáàòûâàíèÿ óðîâíÿ |
//+------------------------------------------------+ 
enum ENUM_ALERT_MODE // òèï êîíñòàíòû
  {
   OnlySound,   // òîëüêî çâóê
   OnlyAlert    // òîëüêî àëåðò
  };
//+----------------------------------------------+
//| Îïèñàíèå êëàññà CXMA                         |
//+----------------------------------------------+
#include <SmoothAlgorithms.mqh> 
//+----------------------------------------------+
//| Îáúÿâëåíèå ïåðå÷èñëåíèé                      |
//+----------------------------------------------+
enum Applied_price_ //òèï êîíñòàíòû
  {
   PRICE_CLOSE_ = 1,     //Close
   PRICE_OPEN_,          //Open
   PRICE_HIGH_,          //High
   PRICE_LOW_,           //Low
   PRICE_MEDIAN_,        //Median Price (HL/2)
   PRICE_TYPICAL_,       //Typical Price (HLC/3)
   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
   PRICE_SIMPL_,         //Simpl Price (OC/2)
   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price
   PRICE_DEMARK_         //Demark Price
  };
//+----------------------------------------------+
//| Îáúÿâëåíèå ïåðå÷èñëåíèé                      |
//+----------------------------------------------+
/*enum Smooth_Method - îáúÿâëåíî â ôàéëå SmoothAlgorithms.mqh
  {
   MODE_SMA_,  //SMA
   MODE_EMA_,  //EMA
   MODE_SMMA_, //SMMA
   MODE_LWMA_, //LWMA
   MODE_JJMA,  //JJMA
   MODE_JurX,  //JurX
   MODE_ParMA, //ParMA
   MODE_T3,    //T3
   MODE_VIDYA, //VIDYA
   MODE_AMA,   //AMA
  }; */
//+------------------------------------------------+ 
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà                   |
//+------------------------------------------------+ 
input string Symbol_="";                               // Ôèíàíñîâûé àêòèâ
input ENUM_TIMEFRAMES Timeframe=PERIOD_H6;             // Òàéìôðåéì èíäèêàòîðà äëÿ ðàñ÷åòà èíäèêàòîðà
input Smooth_Method DSmoothMethod=MODE_JJMA;           // Ìåòîä óñðåäíåíèÿ öåíû
input int DPeriod=15;                                  // Ïåðèîä ñêîëüçÿùåé ñðåäíåé
input int DPhase=100;                                  // Ïàðàìåòð óñðåäíåíèÿ ñêîëüçÿùåé ñðåäíåé
//---- äëÿ JJMA èçìåíÿþùèéñÿ â ïðåäåëàõ -100 ... +100, âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà;
//---- äëÿ VIDIA ýòî ïåðèîä CMO, äëÿ AMA ýòî ïåðèîä ìåäëåííîé ñêîëüçÿùåé
input Smooth_Method SSmoothMethod=MODE_JurX;           // Ìåòîä óñðåäíåíèÿ ñèãíàëüíîé ëèíèè
input int SPeriod=7;                                   // Ïåðèîä ñèãíàëüíîé ëèíèè
input int SPhase=100;                                  // Ïàðàìåòð ñèãíàëüíîé ëèíèè
//---- äëÿ JJMA èçìåíÿþùèéñÿ â ïðåäåëàõ -100 ... +100, âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà;
//---- äëÿ VIDIA ýòî ïåðèîä CMO, äëÿ AMA ýòî ïåðèîä ìåäëåííîé ñêîëüçÿùåé
input Applied_price_ IPC=PRICE_CLOSE;                  // Öåíîâàÿ êîíñòàíòà
input int StepSizeFast=5;                              // Áûñòðûé øàã
input int StepSizeSlow=15;                             // Ìåäëåííûé øàã
//---- íàñòðîéêè âèçóàëüíîãî îòîáðàæåíèÿ èíäèêàòîðà
input uint SignalBar=0;                                // Íîìåð áàðà äëÿ ïîëó÷åíèÿ ñèãíàëà (0 - òåêóùèé áàð)
input string Symbols_Sirname=INDICATOR_NAME"_Label_";  // Íàçâàíèå äëÿ ìåòîê èíäèêàòîðà
input color Upsymbol_Color=clrDodgerBlue;              // Öâåò ñèìâîëà ðîñòà
input color Dnsymbol_Color=clrMagenta;                 // Öâåò ñèìâîëà ïàäåíèÿ
input color IndName_Color=clrDarkOrchid;               // Öâåò íàçâàíèÿ èíäèêàòîðà
input uint Symbols_Size=60;                            // Ðàçìåð ñèìâîëîâ ñèãíàëà
input uint Font_Size=10;                               // Ðàçìåð øðèôòà íàçâàíèÿ èíäèêàòîðà
input int X_1=5;                                       // Ñìåùåíèå íàçâàíèÿ ïî ãîðèçîíòàëè
input int Y_1=-15;                                     // Ñìåùåíèå íàçâàíèÿ ïî âåðòèêàëè
input bool ShowIndName=true;                           // Îòîáðàæåíèå íàçâàíèÿ èíäèêàòîðà
input ENUM_BASE_CORNER  WhatCorner=CORNER_RIGHT_UPPER; // Óãîë ðàñïîëîæåíèÿ
input uint X_=0;                                       // Ñìåùåíèå ïî ãîðèçîíòàëè
input uint Y_=20;                                      // Ñìåùåíèå ïî âåðòèêàëè
//---- íàñòðîéêè àëåðòîâ
input ENUM_ALERT_MODE alert_mode=OnlySound;            // Âàðèàíò èíäèêàöèè ñðàáàòûâàíèÿ
input uint AlertCount=0;                               // Êîëè÷åñòâî ïîäàâàåìûõ àëåðòîâ
//+-----------------------------------+
//---- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ äëÿ õåíäëîâ èíäèêàòîðîâ
int Ind_Handle;
//---- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ íà÷àëà îòñ÷åòà äàííûõ
int min_rates_total;
//---- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ ðàñïîëîæåíèÿ èíäåêñîâ ïî ãîðèçîíòàëè è âåðòèêàëè
uint X_0,Yn,X_1_,Y_1_;
//---- îáúÿâëåíèå ïåðåìåííûõ äëÿ èìåí ìåòîê
string name0,name1,IndName,Symb;
//+------------------------------------------------------------------+
//|  Ïîëó÷åíèå òàéìôðåéìà â âèäå ñòðîêè                              |
//+------------------------------------------------------------------+
string GetStringTimeframe(ENUM_TIMEFRAMES timeframe)
  {
//----
   return(StringSubstr(EnumToString(timeframe),7,-1));
//----
  }
//+------------------------------------------------------------------+
//|  Ñîçäàíèå òåêñòîâîé ìåòêè                                        |
//+------------------------------------------------------------------+
void CreateTLabel(long   chart_id,         // èäåíòèôèêàòîð ãðàôèêà
                  string name,             // èìÿ îáúåêòà
                  int    nwin,             // èíäåêñ îêíà
                  ENUM_BASE_CORNER corner, // ïîëîæåíèå óãëà ïðèâÿçêè
                  ENUM_ANCHOR_POINT point, // ïîëîæåíèå òî÷êè ïðèâÿçêè
                  int    X,                // äèñòàíöèÿ â ïèêñåëÿõ ïî îñè X îò óãëà ïðèâÿçêè
                  int    Y,                // äèñòàíöèÿ â ïèêñåëÿõ ïî îñè Y îò óãëà ïðèâÿçêè
                  string text,             // òåêñò
                  string textTT,           // òåêñò âñïëûâàþùåé ïîäñêàçêè
                  color  Color,            // öâåò òåêñòà
                  string Font,             // øðèôò òåêñòà
                  int    Size)             // ðàçìåð øðèôòà
  {
//----
   ObjectCreate(chart_id,name,OBJ_LABEL,0,0,0);
   ObjectSetInteger(chart_id,name,OBJPROP_CORNER,corner);
   ObjectSetInteger(chart_id,name,OBJPROP_ANCHOR,point);
   ObjectSetInteger(chart_id,name,OBJPROP_XDISTANCE,X);
   ObjectSetInteger(chart_id,name,OBJPROP_YDISTANCE,Y);
   ObjectSetString(chart_id,name,OBJPROP_TEXT,text);
   ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);
   ObjectSetString(chart_id,name,OBJPROP_FONT,Font);
   ObjectSetInteger(chart_id,name,OBJPROP_FONTSIZE,Size);
   ObjectSetString(chart_id,name,OBJPROP_TOOLTIP,textTT);
   ObjectSetInteger(chart_id,name,OBJPROP_BACK,true); //îáúåêò íà çàäíåì ïëàíå
//----
  }
//+------------------------------------------------------------------+
//|  Ïåðåóñòàíîâêà òåêñòîâîé ìåòêè                                   |
//+------------------------------------------------------------------+
void SetTLabel(long   chart_id,         // èäåíòèôèêàòîð ãðàôèêà
               string name,             // èìÿ îáúåêòà
               int    nwin,             // èíäåêñ îêíà
               ENUM_BASE_CORNER corner, // ïîëîæåíèå óãëà ïðèâÿçêè
               ENUM_ANCHOR_POINT point, // ïîëîæåíèå òî÷êè ïðèâÿçêè
               int    X,                // äèñòàíöèÿ â ïèêñåëÿõ ïî îñè X îò óãëà ïðèâÿçêè
               int    Y,                // äèñòàíöèÿ â ïèêñåëÿõ ïî îñè Y îò óãëà ïðèâÿçêè
               string text,             // òåêñò
               string textTT,           // òåêñò âñïëûâàþùåé ïîäñêàçêè
               color  Color,            // öâåò òåêñòà
               string Font,             // øðèôò òåêñòà
               int    Size)             // ðàçìåð øðèôòà
  {
//----
   if(ObjectFind(chart_id,name)==-1)
     {
      CreateTLabel(chart_id,name,nwin,corner,point,X,Y,text,textTT,Color,Font,Size);
     }
   else
     {
      ObjectSetString(chart_id,name,OBJPROP_TEXT,text);
      ObjectSetInteger(chart_id,name,OBJPROP_XDISTANCE,X);
      ObjectSetInteger(chart_id,name,OBJPROP_YDISTANCE,Y);
      ObjectSetInteger(chart_id,name,OBJPROP_COLOR,Color);
      ObjectSetInteger(chart_id,name,OBJPROP_FONTSIZE,Size);
     }
//----
  }
//+------------------------------------------------------------------+    
//| Custom indicator initialization function                         | 
//+------------------------------------------------------------------+  
int OnInit()
  {
//---- èíèöèàëèçàöèÿ ïåðåìåííûõ íà÷àëà îòñ÷¸òà äàííûõ
   int ATR_Period=15;
   min_rates_total=GetStartBars(DSmoothMethod,DPeriod,DPhase)+1;
   min_rates_total+=GetStartBars(SSmoothMethod,SPeriod,SPhase);
   min_rates_total+=MathMax(min_rates_total,ATR_Period)+1;
   min_rates_total+=int(SignalBar);
//---- èíèöèàëèçàöèÿ ïåðåìåííûõ
   if(Symbol_!="") Symb=Symbol_;
   else Symb=Symbol();
//----
   X_0=X_;
   Yn=Y_+5;
//----
   name0=Symbols_Sirname+"0";
   if(ShowIndName)
     {
      Y_1_=Yn+Y_1;
      X_1_=X_0+X_1;
      name1=Symbols_Sirname+"1";
      StringConcatenate(IndName,INDICATOR_NAME,"(",Symb," ",GetStringTimeframe(Timeframe),")");
     }
//---- ïîëó÷åíèå õåíäëà èíäèêàòîðà METRO_XRSX_Sign
   Ind_Handle=iCustom(Symb,Timeframe,"METRO_XRSX_Sign",DSmoothMethod,DPeriod,DPhase,SSmoothMethod,SPeriod,SPhase,IPC,StepSizeFast,StepSizeSlow);
   if(Ind_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà METRO_XRSX_Sign");
      return(INIT_FAILED);
     }
//--- ñîçäàíèå èìåíè äëÿ îòîáðàæåíèÿ â îòäåëüíîì ïîäîêíå è âî âñïëûâàþùåé ïîäñêàçêå
   IndicatorSetString(INDICATOR_SHORTNAME,INDICATOR_NAME);
//--- îïðåäåëåíèå òî÷íîñòè îòîáðàæåíèÿ çíà÷åíèé èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//---- çàâåðøåíèå èíèöèàëèçàöèè
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+    
void Deinit()
  {
//----
   if(ObjectFind(0,name0)!=-1) ObjectDelete(0,name0);
   if(ObjectFind(0,name1)!=-1) ObjectDelete(0,name1);
//----
  }
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+    
void OnDeinit(const int reason)
  {
//----
   Deinit();
//----
   ChartRedraw(0);
  }
//+------------------------------------------------------------------+  
//| Custom indicator iteration function                              | 
//+------------------------------------------------------------------+  
int OnCalculate(const int rates_total,    // êîëè÷åñòâî èñòîðèè â áàðàõ íà òåêóùåì òèêå
                const int prev_calculated,// êîëè÷åñòâî èñòîðèè â áàðàõ íà ïðåäûäóùåì òèêå
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷åòà
   if(BarsCalculated(Ind_Handle)<min_rates_total) return(RESET);
   if(BarsCalculated(Ind_Handle)<Bars(Symb,Timeframe)) return(prev_calculated);
//---- îáúÿâëåíèå ëîêàëüíûõ ïåðåìåííûõ
   int limit,trend;
   double UpSign[],DnSign[];
   datetime TIME[1];
   color Color0=clrNONE;
   string SignSymbol;
   static datetime prev_time;
   static int trend_;
   bool signal=false;
   static uint buycount=0,sellcount=0;
//---- êîïèðóåì âíîâü ïîÿâèâøèåñÿ äàííûå â ìàññèâû
   if(CopyTime(Symb,Timeframe,SignalBar,1,TIME)<=0) return(RESET);
//---- ðàñ÷åòû íåîáõîäèìîãî êîëè÷åñòâà êîïèðóåìûõ äàííûõ äëÿ ôóíêöèè CopyBuffer
   if(prev_calculated>rates_total || prev_calculated<=0)// ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷åòà èíäèêàòîðà
     {
      prev_time=time[0];
      trend_=0;
     }
//---- êîïèðóåì âíîâü ïîÿâèâøèåñÿ äàííûå â ìàññèâû
   if(CopyBuffer(Ind_Handle,0,TIME[0],prev_time,DnSign)<=0) return(RESET);
   if(CopyBuffer(Ind_Handle,1,TIME[0],prev_time,UpSign)<=0) return(RESET);
//---- ðàñ÷åòû ñòàðòîâîãî íîìåðà limit äëÿ öèêëà ïåðåñ÷åòà áàðîâ  
   limit=ArraySize(UpSign)-1;
   trend=trend_;
//---- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ, êàê â òàéìñåðèÿõ  
   ArraySetAsSeries(DnSign,true);
   ArraySetAsSeries(UpSign,true);
//---- ñòàâèì ñ÷åò÷èêè àëåðòîâ â èñõîäíîå ïîëîæåíèå   
   if(TIME[0]!=prev_time && AlertCount)
     {
      buycount=AlertCount;
      sellcount=AlertCount;
     }
//---- îñíîâíîé öèêë ðàñ÷åòà èíäèêàòîðà
   for(int bar=limit; bar>=0 && !IsStopped(); bar--)
     {
      if(UpSign[bar]&&UpSign[bar]!=ENAM_EMPTY_VALUE) {trend=+1; if(!bar) signal=true;}
      if(DnSign[bar]&&DnSign[bar]!=ENAM_EMPTY_VALUE) {trend=-1; if(!bar) signal=true;}
      if(bar ||  SignalBar) trend_=trend;
     }
//----
   if(trend>0)
     {
      Color0=Upsymbol_Color;
      //----
      if(signal)
        {
         SignSymbol=UP_SIGNAL_SYMBOL;
         if(buycount)
           {
            switch(alert_mode)
              {
               case OnlyAlert: Alert(IndName+": "+BUY_ALERT_TEXT); break;
               case OnlySound: PlaySound(BUY_SOUND); break;
              }
            //----
            buycount--;
           }
        }
      else SignSymbol=UP_TREND_SYMBOL;
     }
//----
   if(trend<0)
     {
      Color0=Dnsymbol_Color;
      //----
      if(signal)
        {
         SignSymbol=DN_SIGNAL_SYMBOL;
         if(sellcount)
           {
            switch(alert_mode)
              {
               case OnlyAlert: Alert(IndName+": "+SELL_ALERT_TEXT); break;
               case OnlySound: PlaySound(SELL_SOUND); break;
              }
            //----
            sellcount--;
           }
        }
      else SignSymbol=DN_TREND_SYMBOL;
     }
//----
   if(trend)
     {
      if(ShowIndName)
         SetTLabel(0,name1,0,WhatCorner,ENUM_ANCHOR_POINT(2*WhatCorner),X_1_,Y_1_,IndName,IndName,IndName_Color,NAMES_SYMBOLS_FONT,Font_Size);
      if(signal) SetTLabel(0,name0,0,WhatCorner,ENUM_ANCHOR_POINT(2*WhatCorner),X_0,Yn,SignSymbol,IndName,Color0,SIGNAL_SYMBOLS_FONT,Symbols_Size);
      else SetTLabel(0,name0,0,WhatCorner,ENUM_ANCHOR_POINT(2*WhatCorner),X_0,Yn,SignSymbol,IndName,Color0,TREND_SYMBOLS_FONT,Symbols_Size);
     }
   else Deinit();
//----
   ChartRedraw(0);
   prev_time=TIME[0];
//----     
   return(rates_total);
  }
//+------------------------------------------------------------------+