MACD Sample_v1

Profit factor:
0.85
Orders Execution
Checks for the total of open ordersIt automatically opens orders when conditions are reachedIt Closes Orders by itself It can change open orders parameters, due to possible stepping strategy
Indicators Used
MACD HistogramMoving average indicator
9 Views
0 Downloads
0 Favorites
MACD Sample_v1
//+------------------------------------------------------------------+
//|                                                  MACD Sample.mq4 |
//|                      Copyright © 2005, MetaQuotes Software Corp. |
//|                                       http://www.metaquotes.net/ |
//+------------------------------------------------------------------+

extern double TakeProfit = 50;
extern double Lots = 0.1;
extern double TrailingStop = 30;
extern double MACDOpenLevel=3;
extern double MACDCloseLevel=2;
extern double MATrendPeriod=26;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int start()
  {
   double MacdCurrent, MacdPrevious, SignalCurrent;
   double SignalPrevious, MaCurrent, MaPrevious;
   int cnt, ticket, total;
// initial data checks
// it is important to make sure that the expert works with a normal
// chart and the user did not make any mistakes setting external 
// variables (Lots, StopLoss, TakeProfit, 
// TrailingStop) in our case, we check TakeProfit
// on a chart of less than 100 bars
   if(Bars<100)
     {
      Print("bars less than 100");
      return(0);  
     }
   if(TakeProfit<10)
     {
      Print("TakeProfit less than 10");
      return(0);  // check TakeProfit
     }
// to simplify the coding and speed up access
// data are put into internal variables
   MacdCurrent=iMACD(NULL,0,12,26,9,PRICE_CLOSE,MODE_MAIN,0);
   MacdPrevious=iMACD(NULL,0,12,26,9,PRICE_CLOSE,MODE_MAIN,1);
   SignalCurrent=iMACD(NULL,0,12,26,9,PRICE_CLOSE,MODE_SIGNAL,0);
   SignalPrevious=iMACD(NULL,0,12,26,9,PRICE_CLOSE,MODE_SIGNAL,1);
   MaCurrent=iMA(NULL,0,MATrendPeriod,0,MODE_EMA,PRICE_CLOSE,0);
   MaPrevious=iMA(NULL,0,MATrendPeriod,0,MODE_EMA,PRICE_CLOSE,1);

   total=OrdersTotal();
   if(total<1) 
     {
      // no opened orders identified
      if(AccountFreeMargin()<(1000*Lots))
        {
         Print("We have no money. Free Margin = ", AccountFreeMargin());
         return(0);  
        }
      // check for long position (BUY) possibility
      if(MacdCurrent<0 && MacdCurrent>SignalCurrent && MacdPrevious<SignalPrevious &&
         MathAbs(MacdCurrent)>(MACDOpenLevel*Point) && MaCurrent>MaPrevious)
        {
         ticket=OrderSend(Symbol(),OP_BUY,Lots,Ask,3,0,Ask+TakeProfit*Point,"macd sample",16384,0,Green);
         if(ticket>0)
           {
            if(OrderSelect(ticket,SELECT_BY_TICKET,MODE_TRADES)) Print("BUY order opened : ",OrderOpenPrice());
           }
         else Print("Error opening BUY order : ",GetLastError()); 
         return(0); 
        }
      // check for short position (SELL) possibility
      if(MacdCurrent>0 && MacdCurrent<SignalCurrent && MacdPrevious>SignalPrevious && 
         MacdCurrent>(MACDOpenLevel*Point) && MaCurrent<MaPrevious)
        {
         ticket=OrderSend(Symbol(),OP_SELL,Lots,Bid,3,0,Bid-TakeProfit*Point,"macd sample",16384,0,Red);
         if(ticket>0)
           {
            if(OrderSelect(ticket,SELECT_BY_TICKET,MODE_TRADES)) Print("SELL order opened : ",OrderOpenPrice());
           }
         else Print("Error opening SELL order : ",GetLastError()); 
         return(0); 
        }
      return(0);
     }
   // it is important to enter the market correctly, 
   // but it is more important to exit it correctly...   
   for(cnt=0;cnt<total;cnt++)
     {
      OrderSelect(cnt, SELECT_BY_POS, MODE_TRADES);
      if(OrderType()<=OP_SELL &&   // check for opened position 
         OrderSymbol()==Symbol())  // check for symbol
        {
         if(OrderType()==OP_BUY)   // long position is opened
           {
            // should it be closed?
            if(MacdCurrent>0 && MacdCurrent<SignalCurrent && MacdPrevious>SignalPrevious &&
               MacdCurrent>(MACDCloseLevel*Point))
                {
                 OrderClose(OrderTicket(),OrderLots(),Bid,3,Violet); // close position
                 return(0); // exit
                }
            // check for trailing stop
            if(TrailingStop>0)  
              {                 
               if(Bid-OrderOpenPrice()>Point*TrailingStop)
                 {
                  if(OrderStopLoss()<Bid-Point*TrailingStop)
                    {
                     OrderModify(OrderTicket(),OrderOpenPrice(),Bid-Point*TrailingStop,OrderTakeProfit(),0,Green);
                     return(0);
                    }
                 }
              }
           }
         else // go to short position
           {
            // should it be closed?
            if(MacdCurrent<0 && MacdCurrent>SignalCurrent &&
               MacdPrevious<SignalPrevious && MathAbs(MacdCurrent)>(MACDCloseLevel*Point))
              {
               OrderClose(OrderTicket(),OrderLots(),Ask,3,Violet); // close position
               return(0); // exit
              }
            // check for trailing stop
            if(TrailingStop>0)  
              {                 
               if((OrderOpenPrice()-Ask)>(Point*TrailingStop))
                 {
                  if((OrderStopLoss()>(Ask+Point*TrailingStop)) || (OrderStopLoss()==0))
                    {
                     OrderModify(OrderTicket(),OrderOpenPrice(),Ask+Point*TrailingStop,OrderTakeProfit(),0,Red);
                     return(0);
                    }
                 }
              }
           }
        }
     }
   return(0);
  }
// the end.

Profitability Reports

GBP/AUD Jul 2025 - Sep 2025
0.48
Total Trades 69
Won Trades 63
Lost trades 6
Win Rate 91.30 %
Expected payoff -2.64
Gross Profit 166.98
Gross Loss -348.84
Total Net Profit -181.86
-100%
-50%
0%
50%
100%
EUR/USD Jul 2025 - Sep 2025
6.19
Total Trades 307
Won Trades 303
Lost trades 4
Win Rate 98.70 %
Expected payoff 3.97
Gross Profit 1452.00
Gross Loss -234.60
Total Net Profit 1217.40
-100%
-50%
0%
50%
100%
AUD/USD Jul 2025 - Sep 2025
1.16
Total Trades 34
Won Trades 32
Lost trades 2
Win Rate 94.12 %
Expected payoff 0.48
Gross Profit 115.90
Gross Loss -99.70
Total Net Profit 16.20
-100%
-50%
0%
50%
100%
USD/JPY Jan 2025 - Jul 2025
0.51
Total Trades 206
Won Trades 199
Lost trades 7
Win Rate 96.60 %
Expected payoff -2.26
Gross Profit 485.30
Gross Loss -951.56
Total Net Profit -466.26
-100%
-50%
0%
50%
100%
USD/CHF Jan 2025 - Jul 2025
0.55
Total Trades 118
Won Trades 108
Lost trades 10
Win Rate 91.53 %
Expected payoff -2.66
Gross Profit 379.96
Gross Loss -693.42
Total Net Profit -313.46
-100%
-50%
0%
50%
100%
USD/CAD Jan 2025 - Jul 2025
1.14
Total Trades 194
Won Trades 185
Lost trades 9
Win Rate 95.36 %
Expected payoff 0.29
Gross Profit 469.48
Gross Loss -412.55
Total Net Profit 56.93
-100%
-50%
0%
50%
100%
NZD/USD Jan 2025 - Jul 2025
0.57
Total Trades 99
Won Trades 91
Lost trades 8
Win Rate 91.92 %
Expected payoff -1.87
Gross Profit 241.30
Gross Loss -426.80
Total Net Profit -185.50
-100%
-50%
0%
50%
100%
GBP/USD Jan 2025 - Jul 2025
3.40
Total Trades 138
Won Trades 136
Lost trades 2
Win Rate 98.55 %
Expected payoff 2.25
Gross Profit 439.80
Gross Loss -129.50
Total Net Profit 310.30
-100%
-50%
0%
50%
100%
GBP/CAD Jan 2025 - Jul 2025
0.10
Total Trades 87
Won Trades 73
Lost trades 14
Win Rate 83.91 %
Expected payoff -18.89
Gross Profit 184.34
Gross Loss -1827.96
Total Net Profit -1643.62
-100%
-50%
0%
50%
100%
GBP/AUD Jan 2025 - Jul 2025
0.13
Total Trades 65
Won Trades 57
Lost trades 8
Win Rate 87.69 %
Expected payoff -14.77
Gross Profit 148.49
Gross Loss -1108.51
Total Net Profit -960.02
-100%
-50%
0%
50%
100%

Comments