LotSize

ÿþ//+------------------------------------------------------------------+

//|                                                      LotSize.mq5 |

//|                              Copyright © 2018, Vladimir Karputov |

//|                                           http://wmua.ru/slesar/ |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2018, Vladimir Karputov"

#property link      "http://wmua.ru/slesar/"

#property version   "1.000"

//---

#include <Trade\PositionInfo.mqh>

#include <Trade\Trade.mqh>

#include <Trade\SymbolInfo.mqh>  

#include <Trade\AccountInfo.mqh>

#include <Expert\Money\MoneyFixedMargin.mqh>

#include <Expert\Money\MoneyFixedRisk.mqh>

CPositionInfo  m_position;                   // trade position object

CTrade         m_trade;                      // trading object

CSymbolInfo    m_symbol;                     // symbol info object

CAccountInfo   m_account;                    // account info wrapper

CMoneyFixedMargin *m_money_margin;

CMoneyFixedRisk   *m_money_risk;

//+------------------------------------------------------------------+

//| Enum Lor or Risk                                                 |

//+------------------------------------------------------------------+

enum ENUM_MONEY

  {

   margin= 0,  // with predefined fixed margin

   risk  = 1,  // with predefined risk

  };

//--- input parameters

input ushort   InpStopLoss       = 50;       // Stop Loss, in pips (1.00045-1.00055=1 pips)

input ushort   InpTakeProfit     = 140;      // Take Profit, in pips (1.00045-1.00055=1 pips)

input ENUM_MONEY InpMoney        = margin;   // Trading 

input double   InpVolumeLotOrRisk= 3.0;      // Risk in percent for a deal

//---

double ExtStopLoss      = 0.0;               // Stop Loss      -> double

double ExtTakeProfit    = 0.0;               // Take Profit    -> double

double m_adjusted_point;                     // point value adjusted for 3 or 5 points

static datetime PrevBars=0;

//+------------------------------------------------------------------+

//| Expert initialization function                                   |

//+------------------------------------------------------------------+

int OnInit()

  {

   PrevBars=0;

//---

   if(!m_symbol.Name(Symbol())) // sets symbol name

      return(INIT_FAILED);

   RefreshRates();

//---

   m_trade.SetMarginMode();

   m_trade.SetTypeFillingBySymbol(m_symbol.Name());

//--- tuning for 3 or 5 digits

   int digits_adjust=1;

   if(m_symbol.Digits()==3 || m_symbol.Digits()==5)

      digits_adjust=10;

   m_adjusted_point=m_symbol.Point()*digits_adjust;



   ExtStopLoss       = InpStopLoss        * m_adjusted_point;

   ExtTakeProfit     = InpTakeProfit      * m_adjusted_point;

//--- check the input parameter "Lots"

   string err_text="";

   if(m_money_margin!=NULL)

      delete m_money_margin;

   if(m_money_risk!=NULL)

      delete m_money_risk;

   if(InpMoney==margin)

     {

      m_money_margin=new CMoneyFixedMargin;

      if(m_money_margin!=NULL)

        {

         if(!m_money_margin.Init(GetPointer(m_symbol),Period(),m_symbol.Point()*digits_adjust))

            return(INIT_FAILED);

         m_money_margin.Percent(InpVolumeLotOrRisk);

        }

      else

        {

         Print(__FUNCTION__,", ERROR: Object CMoneyFixedMargin is NULL");

         return(INIT_FAILED);

        }

     }

   else if(InpMoney==risk)

     {

      m_money_risk=new CMoneyFixedRisk;

      if(m_money_risk!=NULL)

        {

         if(!m_money_risk.Init(GetPointer(m_symbol),Period(),m_symbol.Point()*digits_adjust))

            return(INIT_FAILED);

         m_money_risk.Percent(InpVolumeLotOrRisk);

        }

      else

        {

         Print(__FUNCTION__,", ERROR: Object CMoneyFixedRisk is NULL");

         return(INIT_FAILED);

        }

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Expert deinitialization function                                 |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

//---

   if(m_money_margin!=NULL)

      delete m_money_margin;

   if(m_money_risk!=NULL)

      delete m_money_risk;

  }

//+------------------------------------------------------------------+

//| Expert tick function                                             |

//+------------------------------------------------------------------+

void OnTick()

  {

//--- we work only at the time of the birth of new bar

   datetime time_0=iTime(m_symbol.Name(),Period(),0);

   if(time_0==PrevBars)

      return;

   PrevBars=time_0;

   if(!RefreshRates())

     {

      PrevBars=0;

      return;

     }

//--- 

   Print("");

   string text=(InpMoney==margin)?" with predefined fixed margin":" with predefined risk";

   Print("Trading ",text);

   

   OpenPosition(POSITION_TYPE_BUY);

   OpenPosition(POSITION_TYPE_SELL);

  }

//+------------------------------------------------------------------+

//| TradeTransaction function                                        |

//+------------------------------------------------------------------+

void OnTradeTransaction(const MqlTradeTransaction &trans,

                        const MqlTradeRequest &request,

                        const MqlTradeResult &result)

  {

//---



  }

//+------------------------------------------------------------------+

//| Refreshes the symbol quotes data                                 |

//+------------------------------------------------------------------+

bool RefreshRates(void)

  {

//--- refresh rates

   if(!m_symbol.RefreshRates())

     {

      Print("RefreshRates error");

      return(false);

     }

//--- protection against the return value of "zero"

   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)

      return(false);

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Check the correctness of the position volume                     |

//+------------------------------------------------------------------+

bool CheckVolumeValue(double volume,string &error_description)

  {

//--- minimal allowed volume for trade operations

   double min_volume=m_symbol.LotsMin();

   if(volume<min_volume)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< <5=LH5 <8=8<0;L=> 4>?CAB8<>3> SYMBOL_VOLUME_MIN=%.2f",min_volume);

      else

         error_description=StringFormat("Volume is less than the minimal allowed SYMBOL_VOLUME_MIN=%.2f",min_volume);

      return(false);

     }

//--- maximal allowed volume of trade operations

   double max_volume=m_symbol.LotsMax();

   if(volume>max_volume)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< 1>;LH5 <0:A8<0;L=> 4>?CAB8<>3> SYMBOL_VOLUME_MAX=%.2f",max_volume);

      else

         error_description=StringFormat("Volume is greater than the maximal allowed SYMBOL_VOLUME_MAX=%.2f",max_volume);

      return(false);

     }

//--- get minimal step of volume changing

   double volume_step=m_symbol.LotsStep();

   int ratio=(int)MathRound(volume/volume_step);

   if(MathAbs(ratio*volume_step-volume)>0.0000001)

     {

      if(TerminalInfoString(TERMINAL_LANGUAGE)=="Russian")

         error_description=StringFormat("1J5< =5 :@0B5= <8=8<0;L=><C H03C SYMBOL_VOLUME_STEP=%.2f, 1;8609H89 ?@028;L=K9 >1J5< %.2f",

                                        volume_step,ratio*volume_step);

      else

         error_description=StringFormat("Volume is not a multiple of the minimal step SYMBOL_VOLUME_STEP=%.2f, the closest correct volume is %.2f",

                                        volume_step,ratio*volume_step);

      return(false);

     }

   error_description="Correct volume value";

   return(true);

  }

//+------------------------------------------------------------------+

//| Open position                                                    |

//+------------------------------------------------------------------+

void OpenPosition(const ENUM_POSITION_TYPE pos_type)

  {

//--- buy

   if(pos_type==POSITION_TYPE_BUY)

     {

      double price= m_symbol.Ask();

      double sl   = (InpStopLoss==0)?0.0:price-ExtStopLoss;

      double tp   = (InpTakeProfit==0)?0.0:price+ExtTakeProfit;



      OpenBuy(sl,tp);

     }

//--- sell

   if(pos_type==POSITION_TYPE_SELL)

     {

      double price= m_symbol.Bid();

      double sl   = (InpStopLoss==0)?0.0:price+ExtStopLoss;

      double tp   = (InpTakeProfit==0)?0.0:price-ExtTakeProfit;



      OpenSell(sl,tp);

     }

  }

//+------------------------------------------------------------------+

//| Open Buy position                                                |

//+------------------------------------------------------------------+

void OpenBuy(double sl,double tp)

  {

   sl=m_symbol.NormalizePrice(sl);

   tp=m_symbol.NormalizePrice(tp);



   double long_lot=0.0;

   if(InpMoney==margin)

      long_lot=m_money_margin.CheckOpenLong(m_symbol.Ask(),sl);

   else if(InpMoney==risk)

      long_lot=m_money_risk.CheckOpenLong(m_symbol.Ask(),sl);

   Print(__FUNCTION__,

         ", Risk=",DoubleToString(InpVolumeLotOrRisk,2)," %",

         ", sl=",DoubleToString(sl,m_symbol.Digits())," (",IntegerToString(InpStopLoss),")",

         ", tp=",DoubleToString(tp,m_symbol.Digits())," (",IntegerToString(InpTakeProfit),")",

         ", CheckOpenLong: ",DoubleToString(long_lot,2),

         ", Balance: ",    DoubleToString(m_account.Balance(),2),

         ", Equity: ",     DoubleToString(m_account.Equity(),2),

         ", FreeMargin: ", DoubleToString(m_account.FreeMargin(),2));

   if(long_lot==0.0)

     {

      Print(__FUNCTION__,", ERROR: method CheckOpenLong returned the value of \"0.0\"");

      return;

     }



   if(m_symbol.LotsLimit()>0.0)

     {

      int count_buys=0;    double volume_buys=0.0;    double volume_biggest_buys=0.0;

      int count_sells=0;   double volume_sells=0.0;   double volume_biggest_sells=0.0;

      CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                            count_sells,volume_sells,volume_biggest_sells);

      if(volume_buys+volume_sells+long_lot>m_symbol.LotsLimit())

        {

         Print(__FUNCTION__,", #0 Buy, Volume Buy (",DoubleToString(volume_buys,2),

               ") + Volume Sell (",DoubleToString(volume_sells,2),

               ") + Volume long (",DoubleToString(long_lot,2),

               ") > Lots Limit (",DoubleToString(m_symbol.LotsLimit(),2),")");

         return;

        }

     }

//--- check volume before OrderSend to avoid "not enough money" error (CTrade)

   double free_margin_check= m_account.FreeMarginCheck(m_symbol.Name(),ORDER_TYPE_BUY,long_lot,m_symbol.Ask());

   double margin_check     = m_account.MarginCheck(m_symbol.Name(),ORDER_TYPE_SELL,long_lot,m_symbol.Bid());

   if(free_margin_check>margin_check)

     {

      Print(__FUNCTION__,", Long lot: ",DoubleToString(long_lot,2));

     }

   else

     {

      Print(__FUNCTION__,", ERROR: method CAccountInfo::FreeMarginCheck returned the value ",DoubleToString(free_margin_check,2));

      return;

     }

//---

  }

//+------------------------------------------------------------------+

//| Open Sell position                                               |

//+------------------------------------------------------------------+

void OpenSell(double sl,double tp)

  {

   sl=m_symbol.NormalizePrice(sl);

   tp=m_symbol.NormalizePrice(tp);



   double short_lot=0.0;

   if(InpMoney==margin)

      short_lot=m_money_margin.CheckOpenShort(m_symbol.Bid(),sl);

   else if(InpMoney==risk)

      short_lot=m_money_risk.CheckOpenShort(m_symbol.Ask(),sl);

   Print(__FUNCTION__,

         ", Risk=",DoubleToString(InpVolumeLotOrRisk,2)," %",

         ", sl=",DoubleToString(sl,m_symbol.Digits())," (",IntegerToString(InpStopLoss),")",

         ", tp=",DoubleToString(tp,m_symbol.Digits())," (",IntegerToString(InpTakeProfit),")",

         ", CheckOpenLong: ",DoubleToString(short_lot,2),

         ", Balance: ",    DoubleToString(m_account.Balance(),2),

         ", Equity: ",     DoubleToString(m_account.Equity(),2),

         ", FreeMargin: ", DoubleToString(m_account.FreeMargin(),2));

   if(short_lot==0.0)

     {

      Print(__FUNCTION__,", ERROR: method CheckOpenShort returned the value of \"0.0\"");

      return;

     }



   if(m_symbol.LotsLimit()>0.0)

     {

      int count_buys=0;    double volume_buys=0.0;    double volume_biggest_buys=0.0;

      int count_sells=0;   double volume_sells=0.0;   double volume_biggest_sells=0.0;

      CalculateAllPositions(count_buys,volume_buys,volume_biggest_buys,

                            count_sells,volume_sells,volume_biggest_sells);

      if(volume_buys+volume_sells+short_lot>m_symbol.LotsLimit())

         Print("#0 Buy, Volume Buy (",DoubleToString(volume_buys,2),

               ") + Volume Sell (",DoubleToString(volume_sells,2),

               ") + Volume short (",DoubleToString(short_lot,2),

               ") > Lots Limit (",DoubleToString(m_symbol.LotsLimit(),2),")");

      return;

     }

//--- check volume before OrderSend to avoid "not enough money" error (CTrade)

   double free_margin_check= m_account.FreeMarginCheck(m_symbol.Name(),ORDER_TYPE_SELL,short_lot,m_symbol.Bid());

   double margin_check     = m_account.MarginCheck(m_symbol.Name(),ORDER_TYPE_SELL,short_lot,m_symbol.Bid());

   if(free_margin_check>margin_check)

     {

      Print(__FUNCTION__,", Short lot: ",DoubleToString(short_lot,2));

     }

   else

     {

      Print(__FUNCTION__,", ERROR: method CAccountInfo::FreeMarginCheck returned the value ",DoubleToString(free_margin_check,2));

      return;

     }

//---

  }

//+------------------------------------------------------------------+

//| Print CTrade result                                              |

//+------------------------------------------------------------------+

void PrintResultTrade(CTrade &trade,CSymbolInfo &symbol)

  {

   Print("File: ",__FILE__,", symbol: ",symbol.Name());

   Print("Code of request result: "+IntegerToString(trade.ResultRetcode()));

   Print("code of request result as a string: "+trade.ResultRetcodeDescription());

   Print("Deal ticket: "+IntegerToString(trade.ResultDeal()));

   Print("Order ticket: "+IntegerToString(trade.ResultOrder()));

   Print("Volume of deal or order: "+DoubleToString(trade.ResultVolume(),2));

   Print("Price, confirmed by broker: "+DoubleToString(trade.ResultPrice(),symbol.Digits()));

   Print("Current bid price: "+DoubleToString(symbol.Bid(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultBid(),symbol.Digits()));

   Print("Current ask price: "+DoubleToString(symbol.Ask(),symbol.Digits())+" (the requote): "+DoubleToString(trade.ResultAsk(),symbol.Digits()));

   Print("Broker comment: "+trade.ResultComment());

   int d=0;

  }

//+------------------------------------------------------------------+

//| Calculate all positions                                          |

//+------------------------------------------------------------------+

void CalculateAllPositions(int &count_buys,double &volume_buys,double &volume_biggest_buys,

                           int &count_sells,double &volume_sells,double &volume_biggest_sells)

  {

   count_buys  =0;   volume_buys   = 0.0; volume_biggest_buys  = 0.0;

   count_sells =0;   volume_sells  = 0.0; volume_biggest_sells = 0.0;

   for(int i=PositionsTotal()-1;i>=0;i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==m_symbol.Name())

           {

            if(m_position.PositionType()==POSITION_TYPE_BUY)

              {

               count_buys++;

               volume_buys+=m_position.Volume();

               if(m_position.Volume()>volume_biggest_buys)

                  volume_biggest_buys=m_position.Volume();

               continue;

              }

            else if(m_position.PositionType()==POSITION_TYPE_SELL)

              {

               count_sells++;

               volume_sells+=m_position.Volume();

               if(m_position.Volume()>volume_biggest_sells)

                  volume_biggest_sells=m_position.Volume();

              }

           }

  }

//+------------------------------------------------------------------+