iTrend_v1

ÿþ//+------------------------------------------------------------------+

//|                                                       iTrend.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property description "iTrend indicator"

#property indicator_separate_window

#property indicator_buffers 4

#property indicator_plots   2

//--- plot Power

#property indicator_label1  "Power"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrDodgerBlue

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- plot Band

#property indicator_label2  "Bands"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrLimeGreen

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- enums

enum ENUM_BANDS_LINE

  {

   BANDS_LINE_BASE   =  BASE_LINE,  // Base line

   BANDS_LINE_UPPER  =  UPPER_BAND, // Upper line

   BANDS_LINE_LOWER  =  LOWER_BAND  // Lower line

  };

//--- input parameters

input uint                 InpPeriodPow         =  20;               // Power MA period

input ENUM_MA_METHOD       InpMethodPow         =  MODE_EMA;         // Power MA method

input ENUM_APPLIED_PRICE   InpAppliedPricePow   =  PRICE_CLOSE;      // Power applied price

input uint                 InpPeriodBands       =  21;               // Bands period

input ENUM_APPLIED_PRICE   InpAppliedPriceBands =  PRICE_CLOSE;      // Bands applied price

input ENUM_BANDS_LINE      InpModeBands         =  BANDS_LINE_BASE;  // Bands mode

input double               InpDeviationBands    =  2.0;              // Bands deviation

//--- indicator buffers

double         BufferPower[];

double         BufferBand[];

double         BufferMA[];

double         BufferBB[];

//--- global variables

double         deviation;

int            period_power;

int            period_bands;

int            period_max;

int            handle_ma;

int            handle_bb;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- set global variables

   period_power=int(InpPeriodPow<1 ? 1 : InpPeriodPow);

   period_bands=int(InpPeriodBands<1 ? 1 : InpPeriodBands);

   period_max=fmax(period_bands,period_power);

   deviation=InpDeviationBands;

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferPower,INDICATOR_DATA);

   SetIndexBuffer(1,BufferBand,INDICATOR_DATA);

   SetIndexBuffer(2,BufferMA,INDICATOR_CALCULATIONS);

   SetIndexBuffer(3,BufferBB,INDICATOR_CALCULATIONS);

//--- setting indicator parameters

   IndicatorSetString(INDICATOR_SHORTNAME,"iTrend ("+(string)period_power+","+(string)period_bands+","+DoubleToString(deviation,1)+")");

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferPower,true);

   ArraySetAsSeries(BufferBand,true);

   ArraySetAsSeries(BufferMA,true);

   ArraySetAsSeries(BufferBB,true);

//--- create handles

   ResetLastError();

   handle_ma=iMA(NULL,PERIOD_CURRENT,period_power,0,InpMethodPow,InpAppliedPricePow);

   if(handle_ma==INVALID_HANDLE)

     {

      Print("The iMA (",(string)period_power,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

   handle_bb=iBands(NULL,PERIOD_CURRENT,period_bands,0,deviation,InpAppliedPriceBands);

   if(handle_bb==INVALID_HANDLE)

     {

      Print("The iBands (",(string)period_bands,",",DoubleToString(deviation,1),") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- #AB0=>2:0 <0AA82>2 1CD5@>2 :0: B09<A5@89

   ArraySetAsSeries(high,true);

   ArraySetAsSeries(low,true);

   ArraySetAsSeries(close,true);

//--- @>25@:0 :>;8G5AB20 4>ABC?=KE 10@>2

   if(rates_total<fmax(period_max,4)) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-1;

      ArrayInitialize(BufferPower,EMPTY_VALUE);

      ArrayInitialize(BufferBand,EMPTY_VALUE);

      ArrayInitialize(BufferMA,0);

      ArrayInitialize(BufferBB,0);

     }

//--- >43>B>2:0 40==KE

   int count=(limit>0 ? rates_total : 1),copied=0;

   copied=CopyBuffer(handle_ma,0,0,count,BufferMA);

   if(copied!=count) return 0;

   copied=CopyBuffer(handle_bb,InpModeBands,0,count,BufferBB);

   if(copied!=count) return 0;



//---  0AGQB 8=48:0B>@0

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      BufferPower[i]=-((high[i]-BufferMA[i])+(low[i]-BufferMA[i]));

      BufferBand[i]=close[i]-BufferBB[i];

     }



//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+