indeX

ÿþ//+------------------------------------------------------------------+

//|                                                        indeX.mq5 |

//|                        Copyright 2019, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2019, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.02"

#property description "indeX"

#property indicator_separate_window

#property indicator_buffers 5   

#property indicator_plots   1

//--- plot 

#property indicator_label1  "Open;High;Low;Close"

#property indicator_type1   DRAW_COLOR_CANDLES

#property indicator_color1  clrGreen,clrRed,clrGray

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- input parameters

input string   nameIndex="USD";

input double   indRatio=50.14348112;

input string   indBasket="EURUSD;USDJPY;GBPUSD;USDCAD;USDSEK;USDCHF";

input string   indPart="57.6;13.6;11.9;9.1;4.2;3.6";

//--- input parameters

input bool InpReverse=false;   // Reverse

//--- indicator buffers

double         BufferUSDX_O[];

double         BufferUSDX_H[];

double         BufferUSDX_L[];

double         BufferUSDX_C[];

double         BufferColors[];

//--- includes

#include <Arrays\ArrayObj.mqh>

//--- global variables

double      scale_factor;

CArrayObj   list_instruments;

//---

string symbols[];

double weights[];

int    timeframes[]={PERIOD_M1,PERIOD_M5,PERIOD_M15,PERIOD_M30,PERIOD_H1,PERIOD_H4,PERIOD_D1,PERIOD_W1,PERIOD_MN1};

//+------------------------------------------------------------------+

//| ;0AA >1J5:B0 8=AB@C<5=B                                         |

//+------------------------------------------------------------------+

class CInstrument : public CObject

  {

private:

   string            m_symbol_name;                      // Symbol name

   double            m_weight;                           // Symbol weight

   int               m_bars;                             // Symbol Bars

   int               m_handle_o;                         // Handle MA Open

   int               m_handle_h;                         // Handle MA High

   int               m_handle_l;                         // Handle MA Low

   int               m_handle_c;                         // Handle MA Close

public:

   double            m_buffer_o[];                       // Buffer[] MA Open

   double            m_buffer_h[];                       // Buffer[] MA High

   double            m_buffer_l[];                       // Buffer[] MA Low

   double            m_buffer_c[];                       // Buffer[] MA Close

   void              HandleO(const int handle)           { this.m_handle_o=handle;     }

   int               HandleO(void)                 const { return this.m_handle_o;     }

   void              HandleH(const int handle)           { this.m_handle_h=handle;     }

   int               HandleH(void)                 const { return this.m_handle_h;     }

   void              HandleL(const int handle)           { this.m_handle_l=handle;     }

   int               HandleL(void)                 const { return this.m_handle_l;     }

   void              HandleC(const int handle)           { this.m_handle_c=handle;     }

   int               HandleC(void)                 const { return this.m_handle_c;     }

   void              Symbol(const string symbol)         { this.m_symbol_name=symbol;  }

   string            Symbol(void)                  const { return this.m_symbol_name;  }

   void              Weight(const double weight)         { this.m_weight=weight;       }

   double            Weight(void)                  const { return this.m_weight;       }

   void              Bars(const int bars)                { this.m_bars=bars;           }

   int               Bars(void)                    const { return this.m_bars;         }

   bool              Refresh(void);

   void              Refresh(const ENUM_TIMEFRAMES timeframe);

                     CInstrument(const string symbol_name);

                    ~CInstrument(void) {;}

  };

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

CInstrument::CInstrument(const string symbol_name) : m_weight(0),m_bars(0)

  {

   this.m_symbol_name=symbol_name;

  }

//+------------------------------------------------------------------+

//| CInstrument >1=>2;5=85 40==KE                                    |

//+------------------------------------------------------------------+

bool CInstrument::Refresh(void)

  {

   datetime array[];

   return(::CopyTime(m_symbol_name,PERIOD_CURRENT,0,1,array)==1);

  }

//+------------------------------------------------------------------+

//|                                                                  |

//+------------------------------------------------------------------+

void CInstrument::Refresh(const ENUM_TIMEFRAMES timeframe)

  {

   datetime array[];

   ::CopyTime(m_symbol_name,timeframe,0,1,array);

  }

//+------------------------------------------------------------------+



//+------------------------------------------------------------------+

//| =8F80;870F8O 8=AB@C<5=B>2  (2AB02:0)                            |

//+------------------------------------------------------------------+

bool InitInstruments(void)

  {

   string array_names[],array_parts[];

   double array_weight[];

   int names_count=0,parts_count=0;

   double sum_parts=0.00; bool cust;

   ResetLastError();

   names_count= StringSplit(indBasket,StringGetCharacter(";",0),array_names);

   parts_count= StringSplit(indPart,StringGetCharacter(";",0),array_parts);

// >1@01>B:0 2>7<>6=KE >H81>:

   if(names_count==0){Print("Error (",nameIndex,"): Parameter [indBasket] is empty.");return false;}

   if(parts_count==0){Print("Error (",nameIndex,"): Parameter [indPart] is empty.");return false;}

   if(names_count== -1){Print("Error (",nameIndex,"): ",GetLastError(),". Parameter [indBasket] wrong.");return false;}

   if(parts_count== -1){Print("Error (",nameIndex,"): ",GetLastError(),". Parameter [indPart] wrong.");return false;}

   if(names_count== 1){Print("Error (",nameIndex,"): Parameter [indBasket] wrong. Need more currency.");return false;}

   if(parts_count== 1){Print("Error (",nameIndex,"): Parameter [indPart] wrong. Need more currency.");return false;}

   if(names_count!=parts_count){Print("Error (",nameIndex,"): Parameters [indBasket] & [indPart] of different dimensions (",names_count," & ",parts_count,").");return false;}

// A>740=85 A?8A:0 8=AB@C<5=B>2

   ArrayResize(array_weight,names_count);

   for(int i=0; i<names_count; i++)

     {

      // 45B0;L=0O ?@>25@:0 ?0@0<5B@>2     

      if(!SymbolExist(array_names[i],cust)) {Print("Error (",nameIndex,"): Symbol ",array_names[i]," does not exist.");return false;} // cust =5 ?@>25@O5<

      double cur_part=StringToDouble(array_parts[i]);

      if(!MathIsValidNumber(cur_part)) {Print("Error (",nameIndex,"): Number ",array_parts[i]," is not valid.");return false;}

      sum_parts+=cur_part;

      string first=::StringSubstr(array_names[i],0,3);

      string second=::StringSubstr(array_names[i],3,3);

      array_weight[i]=(nameIndex==first ? 1 :(nameIndex==second ? -1 : 0));

      array_weight[i]*=cur_part/100.0;

      //     instr.Refresh();

     }

   if(NormalizeDouble(100.00-sum_parts,2)!=0) {Print("Error (",nameIndex,"): Sum [indPart] = ",sum_parts,". Must be 100%.");return false;}

   ArrayResize(symbols,names_count);

   ArrayResize(weights,names_count);

   ArrayCopy(symbols,array_names);

   ArrayCopy(weights,array_weight);

// 2K2545< GB> ?>;CG8;>AL

//   string formula="";

//   for(int i=0; i<list_instruments.Total(); i++)

//     {

//      CInstrument *inst=list_instruments.At(i);

//      if(i==0) formula+=inst.Name()+" = "+(string)inst.Ratio()+"*(";

//      formula+=inst.Symbol()+"^("+(string)inst.GetSignOfWeight()+")"+((i+1)<list_instruments.Total()?"*":")");

//     }

//

//   Print("Init: ",formula);

   return true;

  }

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferUSDX_O,INDICATOR_DATA);

   SetIndexBuffer(1,BufferUSDX_H,INDICATOR_DATA);

   SetIndexBuffer(2,BufferUSDX_L,INDICATOR_DATA);

   SetIndexBuffer(3,BufferUSDX_C,INDICATOR_DATA);

   SetIndexBuffer(4,BufferColors,INDICATOR_COLOR_INDEX);

//---

   EventSetTimer(90);

//---

   InitInstruments();

   int total=ArraySize(symbols);

   list_instruments.Clear();

   int index_buffer=1;

   for(int i=0; i<total; i++)

     {

      string symbol=symbols[i];

      if(!SymbolCheck(symbol))

         continue;

      CInstrument *instr=new CInstrument(symbol);

      if(instr==NULL)

         continue;

      instr.Weight(weights[i]);

      ResetLastError();

      int handle_o=iMA(symbol,PERIOD_CURRENT,1,0,MODE_SMA,PRICE_OPEN);

      if(handle_o==INVALID_HANDLE)

        {

         Print("The ",symbol," iMA(1) by PRICE_OPEN object was not created: Error ",GetLastError());

         continue;

        }

      int handle_h=iMA(symbol,PERIOD_CURRENT,1,0,MODE_SMA,PRICE_HIGH);

      if(handle_h==INVALID_HANDLE)

        {

         Print("The ",symbol," iMA(1) by PRICE_HIGH object was not created: Error ",GetLastError());

         continue;

        }

      int handle_l=iMA(symbol,PERIOD_CURRENT,1,0,MODE_SMA,PRICE_LOW);

      if(handle_l==INVALID_HANDLE)

        {

         Print("The ",symbol," iMA(1) by PRICE_LOW object was not created: Error ",GetLastError());

         continue;

        }

      int handle_c=iMA(symbol,PERIOD_CURRENT,1,0,MODE_SMA,PRICE_CLOSE);

      if(handle_c==INVALID_HANDLE)

        {

         Print("The ",symbol," iMA(1) by PRICE_CLOSE object was not created: Error ",GetLastError());

         continue;

        }

      instr.HandleO(handle_o);

      instr.HandleH(handle_h);

      instr.HandleL(handle_l);

      instr.HandleC(handle_c);

      index_buffer+=4;

      SetIndexBuffer(index_buffer,instr.m_buffer_o,INDICATOR_CALCULATIONS);

      SetIndexBuffer(index_buffer+1,instr.m_buffer_h,INDICATOR_CALCULATIONS);

      SetIndexBuffer(index_buffer+2,instr.m_buffer_l,INDICATOR_CALCULATIONS);

      SetIndexBuffer(index_buffer+3,instr.m_buffer_c,INDICATOR_CALCULATIONS);

      ArraySetAsSeries(instr.m_buffer_o,true);

      ArraySetAsSeries(instr.m_buffer_h,true);

      ArraySetAsSeries(instr.m_buffer_l,true);

      ArraySetAsSeries(instr.m_buffer_c,true);

      list_instruments.Add(instr);

     }

//--- setting indicator parameters

   IndicatorSetString(INDICATOR_SHORTNAME,"indeX "+nameIndex);

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferUSDX_O,true);

   ArraySetAsSeries(BufferUSDX_H,true);

   ArraySetAsSeries(BufferUSDX_L,true);

   ArraySetAsSeries(BufferUSDX_C,true);

   ArraySetAsSeries(BufferColors,true);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- @>25@:0 =0 <8=8<0;L=>5 :>;85AB2> 10@>2 4;O @0AGQB0

   if(rates_total<4) return 0;

//--- #AB0=>2:0 <0AA82>2 1CD5@>2 :0: B09<A5@89

   ArraySetAsSeries(time,true);

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int total=list_instruments.Total();

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-1;

      ArrayInitialize(BufferUSDX_O,EMPTY_VALUE);

      ArrayInitialize(BufferUSDX_H,EMPTY_VALUE);

      ArrayInitialize(BufferUSDX_L,EMPTY_VALUE);

      ArrayInitialize(BufferUSDX_C,EMPTY_VALUE);

      for(int j=0; j<total; j++)

        {

         CInstrument *instr=list_instruments.At(j);

         if(instr==NULL)

            continue;

         ArrayInitialize(instr.m_buffer_o,0);

         ArrayInitialize(instr.m_buffer_h,0);

         ArrayInitialize(instr.m_buffer_l,0);

         ArrayInitialize(instr.m_buffer_c,0);

         int bars=(instr.Symbol()==Symbol() ? rates_total : Bars(instr.Symbol(),PERIOD_CURRENT));

         instr.Bars(bars);

        }

     }

//--- >43>B>2:0 40==KE

   int min_bars=rates_total;

   for(int j=0; j<total; j++)

     {

      CInstrument *instr=list_instruments.At(j);

      if(instr==NULL)

         continue;

      instr.Refresh();

      int bars=(instr.Symbol()==Symbol() ? rates_total : Bars(instr.Symbol(),PERIOD_CURRENT));

      if(bars<min_bars) min_bars=bars;

      int copied=0,count=(limit==0 ? 1 :(instr.Symbol()==Symbol() ? rates_total : instr.Bars()));

      copied=CopyBuffer(instr.HandleO(),0,0,count,instr.m_buffer_o);

      if(copied<=0) return 0;

      copied=CopyBuffer(instr.HandleH(),0,0,count,instr.m_buffer_h);

      if(copied<=0) return 0;

      copied=CopyBuffer(instr.HandleL(),0,0,count,instr.m_buffer_l);

      if(copied<=0) return 0;

      copied=CopyBuffer(instr.HandleC(),0,0,count,instr.m_buffer_c);

      if(copied<=0) return 0;

     }

   int limit1=(limit>1 ? min_bars-1 : 0);

//---  0AGQB 8=48:0B>@0

   for(int i=limit1; i>=0 && !IsStopped(); i--)

     {

      double xO=indRatio;

      double xH=indRatio;

      double xL=indRatio;

      double xC=indRatio;

      for(int j=0; j<total; j++)

        {

         CInstrument *instr=list_instruments.At(j);

         if(instr==NULL)

            continue;

         string symbol=instr.Symbol();

         int bar=BarShift(symbol,PERIOD_CURRENT,Time(symbol,i));

         if(bar==WRONG_VALUE || bar>instr.Bars()-1)

            continue;

         double power=instr.Weight();

         double price_ma_o=instr.m_buffer_o[bar];

         double coeff_o=pow(price_ma_o,power);

         xO*=coeff_o;

         double price_ma_h=instr.m_buffer_h[bar];

         double coeff_h=pow(price_ma_h,power);

         xH*=coeff_h;

         double price_ma_l=instr.m_buffer_l[bar];

         double coeff_l=pow(price_ma_l,power);

         xL*=coeff_l;

         double price_ma_c=instr.m_buffer_c[bar];

         double coeff_c=pow(price_ma_c,power);

         xC*=coeff_c;

        }

      BufferUSDX_O[i]=(InpReverse ? 1/xO : xO);

      BufferUSDX_H[i]=(InpReverse ? 1/xH : xH);

      BufferUSDX_L[i]=(InpReverse ? 1/xL : xL);

      BufferUSDX_C[i]=(InpReverse ? 1/xC : xC);

      //---

      BufferColors[i]=(BufferUSDX_O[i]<BufferUSDX_C[i]? 0 : BufferUSDX_O[i]>BufferUSDX_C[i]? 1 : 2);

     }



//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Custom indicator timer function                                  |

//+------------------------------------------------------------------+

void OnTimer()

  {

   int total=list_instruments.Total();

   for(int i=0;i<total;i++)

     {

      CInstrument *instr=list_instruments.At(i);

      if(instr==NULL)

         continue;

      int count=9;

      for(int j=0;j<count;j++)

        {

         ENUM_TIMEFRAMES timeframe=(ENUM_TIMEFRAMES)timeframes[j];

         instr.Refresh(timeframe);

        }

     }

  }

//+------------------------------------------------------------------+

//| @>25@:0 A8<2>;0                                                 |

//+------------------------------------------------------------------+

bool SymbolCheck(const string symbol_name)

  {

   long select=0;

   ResetLastError();

   if(!SymbolInfoInteger(symbol_name,SYMBOL_SELECT,select))

     {

      int err=GetLastError();

      Print("Error: ",err," Symbol ",symbol_name," does not exist");

      return false;

     }

   else

     {

      if(select) return true;

      ResetLastError();

      if(!SymbolSelect(symbol_name,true))

        {

         int err=GetLastError();

         Print("Error selected ",symbol_name,": ",err);

        }

     }

   return false;

  }

//+------------------------------------------------------------------+

//| >72@0I05B Time                                                  |

//+------------------------------------------------------------------+

datetime Time(const string symbol_name,const int shift)

  {

   datetime array[];

   if(CopyTime(symbol_name,PERIOD_CURRENT,shift,1,array)==1)

      return array[0];

   return 0;

  }

//+------------------------------------------------------------------+

//| >72@0I05B A<5I5=85 10@0 ?> 2@5<5=8                              |

//| https://www.mql5.com/ru/forum/743/page11#comment_7010041         |

//+------------------------------------------------------------------+

int BarShift(const string symbol_name,const ENUM_TIMEFRAMES timeframe,const datetime time,bool exact=false)

  {

   int res=Bars(symbol_name,timeframe,time+1,UINT_MAX);

   if(exact) if((timeframe!=PERIOD_MN1 || time>TimeCurrent()) && res==Bars(symbol_name,timeframe,time-PeriodSeconds(timeframe)+1,UINT_MAX)) return(WRONG_VALUE);

   return res;

  }

//+------------------------------------------------------------------+