i-gentorlsmaema_v02

//+------------------------------------------------------------------+
//|                                          i-GentorLSMAEMA_v02.mq5 | 
//|                               Copyright © 2007, FX Sniper, KimIV | 
//|                                              http://www.kimiv.ru | 
//+------------------------------------------------------------------+
#property copyright "Copyright © 2007, FX Sniper, KimIV"
#property link "http://www.kimiv.ru"
#property description ""
//--- íîìåð âåðñèè èíäèêàòîðà
#property version   "1.00"
//--- îòðèñîâêà èíäèêàòîðà â îòäåëüíîì îêíå
#property indicator_separate_window
//--- ôèêñèðîâàííàÿ âûñîòà ïîäîêíà èíäèêàòîðà â ïèêñåëÿõ 
#property indicator_height 40
//--- íèæíåå è âåðõíåå îãðàíè÷åíèÿ øêàëû îòäåëüíîãî îêíà èíäèêàòîðà
#property indicator_maximum +3.9
#property indicator_minimum +0.3
//+----------------------------------------------+
//|  îáúÿâëåíèå êîíñòàíò                         |
//+----------------------------------------------+
#define RESET 0      // Êîíñòàíòà äëÿ âîçâðàòà òåðìèíàëó êîìàíäû íà ïåðåñ÷åò èíäèêàòîðà
//+----------------------------------------------+
//--- êîëè÷åñòâî èíäèêàòîðíûõ áóôåðîâ
#property indicator_buffers 4
//--- èñïîëüçîâàíî 2 ãðàôè÷åñêèõ ïîñòðîåíèÿ
#property indicator_plots   2
//+----------------------------------------------+
//|  Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 1            |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà 1 â âèäå ëèíèè
#property indicator_type1   DRAW_COLOR_LINE
//--- â êà÷åñòâå öâåòà ëèíèè èíäèêàòîðà èñïîëüçîâàíû
#property indicator_color1 clrRed,clrGray,clrLime
//--- ëèíèÿ èíäèêàòîðà - øòðèõ
#property indicator_style1  STYLE_SOLID
//--- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 5
#property indicator_width1  5
//--- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label1  "Signal line"
//+----------------------------------------------+
//|  Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 2            |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà â âèäå ÷åòûðåõöâåòíûõ çíà÷êîâ
#property indicator_type2 DRAW_COLOR_LINE
//--- â êà÷åñòâå öâåòîâ ïÿòèöâåòíîé ãèñòîãðàììû èñïîëüçîâàíû
#property indicator_color2 clrYellow,clrGray,clrBlue
//--- ëèíèÿ èíäèêàòîðà - ñïëîøíàÿ
#property indicator_style2 STYLE_SOLID
//--- òîëùèíà ëèíèè èíäèêàòîðà ðàâíà 5
#property indicator_width2 5
//--- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label2  "Signal Arrow"
//+----------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà                 |
//+----------------------------------------------+
input uint                 LSMAPeriod=25;         // Ïåðèîä LSMA
input uint                 MAPeriod=34;           // Ïåðèîä MA
input ENUM_MA_METHOD       MAType=MODE_EMA;       // Òèï óñðåäíåíèÿ
input ENUM_APPLIED_PRICE   MAPrice=PRICE_TYPICAL; // Öåíîâàÿ êîíñòàíòà
//+----------------------------------------------+
//--- îáúÿâëåíèå äèíàìè÷åñêèõ ìàññèâîâ, êîòîðûå â äàëüíåéøåì 
//--- áóäóò èñïîëüçîâàíû â êà÷åñòâå èíäèêàòîðíûõ áóôåðîâ
double Ind1Buffer[];
double ColorInd1Buffer[];
double Ind2Buffer[];
double ColorInd2Buffer[];
//---
double res,lengthvar;
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ äëÿ õåíäëîâ èíäèêàòîðîâ
int MA_Handle;
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ íà÷àëà îòñ÷åòà äàííûõ
int min_rates_total;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- èíèöèàëèçàöèÿ ãëîáàëüíûõ ïåðåìåííûõ   
   min_rates_total=int(MathMax(LSMAPeriod,MAPeriod));
   lengthvar=(LSMAPeriod+1)/3.0;
   res=6.0/(LSMAPeriod*(LSMAPeriod+1.0));
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà iMA
   MA_Handle=iMA(_Symbol,PERIOD_CURRENT,MAPeriod,0,MAType,MAPrice);
   if(MA_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà iMA");
      return(INIT_FAILED);
     }
//--- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(0,Ind1Buffer,INDICATOR_DATA);
//--- èíäåêñàöèÿ ýëåìåíòîâ â áóôåðå êàê â òàéìñåðèè
   ArraySetAsSeries(Ind1Buffer,true);
//--- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â öâåòîâîé èíäåêñíûé áóôåð   
   SetIndexBuffer(1,ColorInd1Buffer,INDICATOR_COLOR_INDEX);
//--- èíäåêñàöèÿ ýëåìåíòîâ â áóôåðå êàê â òàéìñåðèè
   ArraySetAsSeries(ColorInd1Buffer,true);
//--- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(2,Ind2Buffer,INDICATOR_DATA);
//--- èíäåêñàöèÿ ýëåìåíòîâ â áóôåðå êàê â òàéìñåðèè
   ArraySetAsSeries(Ind2Buffer,true);
//--- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â öâåòîâîé èíäåêñíûé áóôåð   
   SetIndexBuffer(3,ColorInd2Buffer,INDICATOR_COLOR_INDEX);
//--- èíäåêñàöèÿ ýëåìåíòîâ â áóôåðå êàê â òàéìñåðèè
   ArraySetAsSeries(ColorInd2Buffer,true);
//--- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷åòà îòðèñîâêè èíäèêàòîðà
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
//--- óñòàíîâêà çíà÷åíèé èíäèêàòîðà, êîòîðûå íå áóäóò âèäèìû íà ãðàôèêå
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);
//--- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷åòà îòðèñîâêè èíäèêàòîðà
   PlotIndexSetInteger(1,PLOT_DRAW_BEGIN,min_rates_total);
//--- óñòàíîâêà çíà÷åíèé èíäèêàòîðà, êîòîðûå íå áóäóò âèäèìû íà ãðàôèêå
   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,EMPTY_VALUE);
//--- Óñòàíîâêà ôîðìàòà òî÷íîñòè îòîáðàæåíèÿ èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//--- èìÿ äëÿ îêîí äàííûõ è ìåòêà äëÿ ïîäîêîí 
   string short_name="i-GentorLSMAEMA_v02";
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- çàâåðøåíèå èíèöèàëèçàöèè
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷åòà
   if(BarsCalculated(MA_Handle)<rates_total || rates_total<min_rates_total) return(RESET);
//--- îáúÿâëåíèÿ ëîêàëüíûõ ïåðåìåííûõ 
   int to_copy,limit,bar;
   double MA[];
//--- ðàñ÷åòû íåîáõîäèìîãî êîëè÷åñòâà êîïèðóåìûõ äàííûõ è ñòàðòîâîãî íîìåðà limit äëÿ öèêëà ïåðåñ÷åòà áàðîâ
   if(prev_calculated>rates_total || prev_calculated<=0)// ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷åòà èíäèêàòîðà
      limit=rates_total-int(MAPeriod)-1; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà âñåõ áàðîâ
   else limit=rates_total-prev_calculated; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà íîâûõ áàðîâ
   to_copy=limit+1;
//--- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ, êàê â òàéìñåðèÿõ  
   ArraySetAsSeries(MA,true);
   ArraySetAsSeries(close,true);
//--- êîïèðóåì âíîâü ïîÿâèâøèåñÿ äàííûå â ìàññèâ
   if(CopyBuffer(MA_Handle,0,0,to_copy,MA)<=0) return(RESET);
//--- îñíîâíîé öèêë ðàñ÷åòà èíäèêàòîðà 2
   for(bar=limit; bar>=0 && !IsStopped(); bar--)
     {
      Ind2Buffer[bar]=+1.4;
      ColorInd2Buffer[bar]=1;
      if(close[bar]>MA[bar]) ColorInd2Buffer[bar]=2;
      else if(close[bar]<MA[bar]) ColorInd2Buffer[bar]=0;
     }
//---     
   if(prev_calculated>rates_total || prev_calculated<=0) limit=rates_total-int(LSMAPeriod)-1;
//--- îñíîâíîé öèêë ðàñ÷åòà èíäèêàòîðà 1
   for(bar=limit; bar>=0 && !IsStopped(); bar--)
     {
      Ind1Buffer[bar]=+3;
      ColorInd1Buffer[bar]=1;
      double sum=0;
      for(int iii=int(LSMAPeriod); iii>=1; iii--)
        {
         double tmp=(iii-lengthvar)*close[LSMAPeriod-iii+bar];
         sum+=tmp;
        }
      double wt=sum*res;
      //---
      if(wt>close[bar]) ColorInd1Buffer[bar]=0;
      else if(wt<close[bar]) ColorInd1Buffer[bar]=2;
     }
//---     
   return(rates_total);
  }
//+------------------------------------------------------------------+