Heiken_Ashi_Smoothed_Chl

ÿþ//+------------------------------------------------------------------+

//|                                     Heiken_Ashi_Smoothed_Chl.mq5 |

//|                               Copyright © 2018, Nikolay Kositsin | 

//|                              Khabarovsk,   farria@mail.redcom.ru | 

//+------------------------------------------------------------------+

#property copyright "Copyright © 2018, Nikolay Kositsin"

#property link "farria@mail.redcom.ru"

#property description "Heiken Ashi Smoothed"

//---- =><5@ 25@A88 8=48:0B>@0

#property version   "1.00"

//---- >B@8A>2:0 8=48:0B>@0 2 3;02=>< >:=5

#property indicator_chart_window 

//---- 4;O @0AG5B0 8 >B@8A>2:8 8=48:0B>@0 8A?>;L7>20=> 452OBL 1CD5@>2

#property indicator_buffers 9

//---- 8A?>;L7>20=> 2A53> B@8 3@0D8G5A:8E ?>AB@>5=8O

#property indicator_plots   3

//+----------------------------------------------+

//|  0@0<5B@K >B@8A>2:8 25@E=53> >1;0:0         |

//+----------------------------------------------+

//--- >B@8A>2:0 8=48:0B>@0 2 2845 F25B=>3> >1;0:0

#property indicator_type1   DRAW_FILLING

//--- 2 :0G5AB25 F25B>2 8=48:0B>@0 8A?>;L7>20=K

#property indicator_color1  C'170,255,227'

//--- >B>1@065=85 <5B:8 8=48:0B>@0

#property indicator_label1  "Upper Signal Cloud"

//+----------------------------------------------+

//|  0@0<5B@K >B@8A>2:8 8=48:0B>@0              |

//+----------------------------------------------+

//--- >B@8A>2:0 8=48:0B>@0 2 2845 F25B=>3> >1;0:0

#property indicator_type2   DRAW_FILLING

//--- 2 :0G5AB25 F25B>2 8=48:0B>@0 8A?>;L7>20=K

#property indicator_color2  C'255,170,255'

//--- >B>1@065=85 <5B:8 8=48:0B>@0

#property indicator_label2  "Lower Signal Cloud"

//+----------------------------------------------+

//|  0@0<5B@K >B@8A>2:8  =86=53> >1;0:0         |

//+----------------------------------------------+

//---- 2 :0G5AB25 8=48:0B>@0 8A?>;L7>20=K F25B=K5 A25G8

#property indicator_type3   DRAW_COLOR_CANDLES

#property indicator_color3  clrDodgerBlue,clrRed

//---- >B>1@065=85 <5B:8 8=48:0B>@0

#property indicator_label3  "Heiken Ashi Open;Heiken Ashi High;Heiken Ashi Low;Heiken Ashi Close"



//+----------------------------------------------+

//|  ?8A0=85 :;0AA>2 CA@54=5=89                 |

//+----------------------------------------------+

#include <SmoothAlgorithms.mqh> 

//+----------------------------------------------+

//---- >1JO2;5=85 ?5@5<5==KE :;0AA>2 CXMA 8 CStdDeviation 87 D09;0 SmoothAlgorithms.mqh

CXMA XMAO,XMAL,XMAH,XMAC;

CStdDeviation STDh,STDl;

//+----------------------------------------------+

//|  >1JO2;5=85 ?5@5G8A;5=89                     |

//+----------------------------------------------+

/*enum Smooth_Method - ?5@5G8A;5=85 >1JO2;5=> 2 D09;5 SmoothAlgorithms.mqh

  {

   MODE_SMA_,  //SMA

   MODE_EMA_,  //EMA

   MODE_SMMA_, //SMMA

   MODE_LWMA_, //LWMA

   MODE_JJMA,  //JJMA

   MODE_JurX,  //JurX

   MODE_ParMA, //ParMA

   MODE_T3,    //T3

   MODE_VIDYA, //VIDYA

   MODE_AMA,   //AMA

  }; */

//+----------------------------------------------+

//| E>4=K5 ?0@0<5B@K 8=48:0B>@0                 |

//+----------------------------------------------+

input Smooth_Method HMA_Method=MODE_JJMA;              //5B>4 CA@54=5=8O

input int HLength=30;                                  //3;C18=0 CA@54=5=8O                    

input int HPhase=15;                                   //?0@0<5B@ CA@54=5=8O,

//---- 4;O JJMA 87<5=ONI89AO 2 ?@545;0E -100 ... +100, 2;8O5B =0 :0G5AB2> ?5@5E>4=>3> ?@>F5AA0;

//---- ;O VIDIA MB> ?5@8>4 CMO, 4;O AMA MB> ?5@8>4 <54;5==>9 A:>;L7OI59

input uint BBLength=10;                                //?5@8>4 >;;8=465@0                                                   

input double BandsDeviation=1.0;                       //45280F8O

//+----------------------------------------------+

//---- >1JO2;5=85 48=0<8G5A:8E <0AA82>2, :>B>@K5 1C4CB 2 40;L=59H5< 8A?>;L7>20=K 2 :0G5AB25 8=48:0B>@=KE 1CD5@>2

double UpUpBuffer[],UpDnBuffer[],DnUpBuffer[],DnDnBuffer[];

double ExtOpenBuffer[];

double ExtHighBuffer[];

double ExtLowBuffer[];

double ExtCloseBuffer[];

double ExtColorBuffer[];

//---- 1JO2;5=85 F5;KE ?5@5<5==KE =0G0;0 >BAGQB0 40==KE

int min_rates_total,min_rates_1;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

void OnInit()

  {

//---- =8F80;870F8O ?5@5<5==KE =0G0;0 >BAGQB0 40==KE

   min_rates_1=GetStartBars(HMA_Method,HLength,HPhase);

   min_rates_total=min_rates_1+int(BBLength);

//--- 8=8F80;870F8O 8=48:0B>@=KE 1CD5@>2  

   IndInit(0,UpUpBuffer,INDICATOR_DATA);

   IndInit(1,UpDnBuffer,INDICATOR_DATA);

//--- 8=8F80;870F8O 8=48:0B>@>2

   PlotInit(0,NULL,min_rates_total,0);

//--- 8=8F80;870F8O 8=48:0B>@=KE 1CD5@>2  

   IndInit(2,DnUpBuffer,INDICATOR_DATA);

   IndInit(3,DnDnBuffer,INDICATOR_DATA);

//--- 8=8F80;870F8O 8=48:0B>@>2

   PlotInit(1,NULL,min_rates_total,0);

//---- ?@52@0I5=85 48=0<8G5A:8E <0AA82>2 2 8=48:0B>@=K5 1CD5@K

   SetIndexBuffer(4,ExtOpenBuffer,INDICATOR_DATA);

   SetIndexBuffer(5,ExtHighBuffer,INDICATOR_DATA);

   SetIndexBuffer(6,ExtLowBuffer,INDICATOR_DATA);

   SetIndexBuffer(7,ExtCloseBuffer,INDICATOR_DATA);

//---- ?@52@0I5=85 48=0<8G5A:>3> <0AA820 2 F25B>2>9, 8=45:A=K9 1CD5@   

   SetIndexBuffer(8,ExtColorBuffer,INDICATOR_COLOR_INDEX);

//--- 8=8F80;870F8O 8=48:0B>@>2

   PlotInit(2,NULL,min_rates_1,0);



//---- CAB0=>2:0 0;5@B>2 =0 =54>?CAB8<K5 7=0G5=8O 2=5H=8E ?5@5<5==KE

   XMAO.XMALengthCheck("HLength", HLength);

   XMAO.XMAPhaseCheck("HPhase", HPhase, HMA_Method);



//---- #AB0=>2:0 D>@<0B0 B>G=>AB8 >B>1@065=8O 8=48:0B>@0

   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);

//---- 8<O 4;O >:>= 40==KE 8 <5B:0 4;O AC1J>:>= 

   string short_name="Heiken_Ashi_Smoothed_Chl("+string(HLength)+")";

   IndicatorSetString(INDICATOR_SHORTNAME,short_name);

//----   

  }

//+------------------------------------------------------------------+

//| =8F80;870F8O 8=48:0B>@=>3> 1CD5@0                               |

//+------------------------------------------------------------------+    

void IndInit(int Number,double &Buffer[],ENUM_INDEXBUFFER_TYPE Type)

  {

//--- ?@52@0I5=85 48=0<8G5A:>3> <0AA820 2 8=48:0B>@=K9 1CD5@

   SetIndexBuffer(Number,Buffer,Type);

//---

  }

//+------------------------------------------------------------------+

//| =8F80;870F8O 8=48:0B>@0                                         |

//+------------------------------------------------------------------+    

void PlotInit(int Number,double Empty_Value,int Draw_Begin,int nShift)

  {

//--- >ACI5AB2;5=85 A42830 =0G0;0 >BAG5B0 >B@8A>2:8 8=48:0B>@0

   PlotIndexSetInteger(Number,PLOT_DRAW_BEGIN,Draw_Begin);

//--- CAB0=>2:0 7=0G5=89 8=48:0B>@0, :>B>@K5 =5 1C4CB 2848<K =0 3@0D8:5

   PlotIndexSetDouble(Number,PLOT_EMPTY_VALUE,Empty_Value);

//--- >ACI5AB2;5=85 A42830 8=48:0B>@0 ?> 3>@87>=B0;8 =0 Shift

   PlotIndexSetInteger(Number,PLOT_SHIFT,nShift);

//---

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//---- ?@>25@:0 :>;8G5AB20 10@>2 =0 4>AB0B>G=>ABL 4;O @0AG5B0

   if(rates_total<min_rates_total) return(0);



//---- >1JO2;5=8O ;>:0;L=KE ?5@5<5==KE 

   int first,bar;

   double XmaOpen,XmaHigh,XmaLow,XmaClose,stdev;



//---- @0AG5B AB0@B>2>3> =><5@0 first 4;O F8:;0 ?5@5AG5B0 10@>2

   if(prev_calculated>rates_total || prev_calculated<=0) // ?@>25@:0 =0 ?5@2K9 AB0@B @0AGQB0 8=48:0B>@0

     {

      first=0; // AB0@B>2K9 =><5@ 4;O @0AG5B0 2A5E 10@>2

      bar=min_rates_1;

      ExtOpenBuffer[bar]=open[bar];

      ExtCloseBuffer[bar]=close[bar];

     }

   else first=prev_calculated-1; // AB0@B>2K9 =><5@ 4;O @0AGQB0 =>2KE 10@>2



//---- A=>2=>9 F8:; @0AG5B0 8=48:0B>@0

   for(bar=first; bar<rates_total && !IsStopped(); bar++)

     {

      //---- '5BK@5 2K7>20 DC=:F88 XMASeries.  

      XmaOpen=XMAO.XMASeries(0,prev_calculated,rates_total,HMA_Method,HPhase,HLength,open[bar],bar,false);

      XmaClose=XMAC.XMASeries(0,prev_calculated,rates_total,HMA_Method,HPhase,HLength,close[bar],bar,false);

      XmaHigh=XMAH.XMASeries(0,prev_calculated,rates_total,HMA_Method,HPhase,HLength,high[bar],bar,false);

      XmaLow=XMAL.XMASeries(0,prev_calculated,rates_total,HMA_Method,HPhase,HLength,low[bar],bar,false);



      if(bar<=min_rates_1)

        {

         ExtOpenBuffer [bar]=XmaOpen;

         ExtCloseBuffer[bar]=XmaClose;

         ExtHighBuffer [bar]=XmaHigh;

         ExtLowBuffer  [bar]=XmaLow;

         continue;

        }

        

      ExtOpenBuffer[bar]=(ExtOpenBuffer[bar-1]+ExtCloseBuffer[bar-1])/2;

      ExtCloseBuffer[bar]=(XmaOpen+XmaHigh+XmaLow+XmaClose)/4;

      ExtHighBuffer[bar]=MathMax(XmaHigh,MathMax(ExtOpenBuffer[bar],ExtCloseBuffer[bar]));

      ExtLowBuffer[bar]=MathMin(XmaLow,MathMin(ExtOpenBuffer[bar],ExtCloseBuffer[bar]));



      //---  0A:@0H820=85 A25G59

      if(ExtOpenBuffer[bar]<ExtCloseBuffer[bar]) ExtColorBuffer[bar]=0.0;

      else ExtColorBuffer[bar]=1.0;      

      //----           

      stdev=STDh.StdDevSeries(min_rates_1+1,prev_calculated,rates_total,BBLength,BandsDeviation,high[bar],ExtHighBuffer[bar],bar,false);

      UpUpBuffer[bar]=ExtHighBuffer[bar]+stdev;     

      UpDnBuffer[bar]=ExtHighBuffer[bar]; 

      DnUpBuffer[bar]=ExtLowBuffer[bar];

      stdev=STDl.StdDevSeries(min_rates_1+1,prev_calculated,rates_total,BBLength,BandsDeviation,low[bar],ExtLowBuffer[bar],bar,false);

      DnDnBuffer[bar]=ExtLowBuffer[bar]-stdev;

     }

//----     

   return(rates_total);

  }

//+------------------------------------------------------------------+