exp_elderimpulsesystem

//+------------------------------------------------------------------+
//|                                       Exp_ElderImpulseSystem.mq5 |
//|                             Copyright © 2015,   Nikolay Kositsin | 
//|                              Khabarovsk,   farria@mail.redcom.ru | 
//+------------------------------------------------------------------+
#property copyright "Copyright © 2015, Nikolay Kositsin"
#property link      "farria@mail.redcom.ru"
#property version   "1.00"
//+----------------------------------------------+
//| Òîðãîâûå àëãîðèòìû                           |
//+----------------------------------------------+
#include <TradeAlgorithms.mqh>
//+----------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà ýêñïåðòà        |
//+----------------------------------------------+
input double MM=0.1;              // Äîëÿ ôèíàíñîâûõ ðåñóðñîâ îò äåïîçèòà â ñäåëêå
input MarginMode MMMode=LOT;      // Ñïîñîá îïðåäåëåíèÿ ðàçìåðà ëîòà
input int    StopLoss_=1000;      // Stop Loss â ïóíêòàõ
input int    TakeProfit_=2000;    // Òåéêïðîôèò â ïóíêòàõ
input int    Deviation_=10;       // Ìàêñ. îòêëîíåíèå öåíû â ïóíêòàõ
input bool   BuyPosOpen=true;     // Ðàçðåøåíèå äëÿ âõîäà â ëîíã
input bool   SellPosOpen=true;    // Ðàçðåøåíèå äëÿ âõîäà â øîðò
input bool   BuyPosClose=true;    // Ðàçðåøåíèå äëÿ âûõîäà èç ëîíãîâ
input bool   SellPosClose=true;   // Ðàçðåøåíèå äëÿ âûõîäà èç øîðòîâ
//+----------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà                 |
//+----------------------------------------------+
input ENUM_TIMEFRAMES InpInd_Timeframe=PERIOD_H4; // Òàéìôðåéì èíäèêàòîðà ElderImpulseSystem
input uint ma_period=13;                          // Ïåðèîä ñðåäíåé
input uint fast_ema_period = 12;                  // Áûñòðûé ïåðèîä MACD 
input uint slow_ema_period = 26;                  // Ìåäëåííûé ïåðèîä MACD
input uint signal_period=9;                       // Ñèãíàëüíûé ïåðèîä MACD
input uint SignalBar=1;                           // Íîìåð áàðà äëÿ ïîëó÷åíèÿ ñèãíàëà âõîäà
//+----------------------------------------------+
int TimeShiftSec;
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ äëÿ õåíäëîâ èíäèêàòîðîâ
int InpInd_Handle;
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ íà÷àëà îòñ÷åòà äàííûõ
int min_rates_total;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà ElderImpulseSystem
   InpInd_Handle=iCustom(Symbol(),InpInd_Timeframe,"ElderImpulseSystem",ma_period,fast_ema_period,slow_ema_period,signal_period);
   if(InpInd_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà ElderImpulseSystem");
      return(INIT_FAILED);
     }
//--- èíèöèàëèçàöèÿ ïåðåìåííîé äëÿ õðàíåíèÿ ïåðèîäà ãðàôèêà â ñåêóíäàõ  
   TimeShiftSec=PeriodSeconds(InpInd_Timeframe);
//--- èíèöèàëèçàöèÿ ïåðåìåííûõ íà÷àëà îòñ÷åòà äàííûõ
   min_rates_total=int(MathMax(ma_period,signal_period+1)+2);
   min_rates_total+=int(3+SignalBar);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   GlobalVariableDel_(Symbol());
//---
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//--- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷åòà
   if(BarsCalculated(InpInd_Handle)<min_rates_total) return;
//--- ïîäãðóçêà èñòîðèè äëÿ íîðìàëüíîé ðàáîòû ôóíêöèé IsNewBar() è SeriesInfoInteger()  
   LoadHistory(TimeCurrent()-PeriodSeconds(InpInd_Timeframe)-1,Symbol(),InpInd_Timeframe);
//--- îáúÿâëåíèå ëîêàëüíûõ ïåðåìåííûõ
   double Value[2];
//--- îáúÿâëåíèå ñòàòè÷åñêèõ ïåðåìåííûõ
   static bool Recount=true;
   static bool BUY_Open=false,BUY_Close=false;
   static bool SELL_Open=false,SELL_Close=false;
   static datetime UpSignalTime,DnSignalTime;
   static CIsNewBar NB;
//--- îïðåäåëåíèå ñèãíàëîâ äëÿ ñäåëîê
   if(!SignalBar || NB.IsNewBar(Symbol(),InpInd_Timeframe) || Recount) // ïðîâåðêà íà ïîÿâëåíèå íîâîãî áàðà
     {
      //--- îáíóëèì òîðãîâûå ñèãíàëû
      BUY_Open=false;
      SELL_Open=false;
      BUY_Close=false;
      SELL_Close=false;
      Recount=false;
      //--- êîïèðóåì âíîâü ïîÿâèâøèåñÿ äàííûå â ìàññèâû
      if(CopyBuffer(InpInd_Handle,4,SignalBar,2,Value)<=0) {Recount=true; return;}
      //--- ïîëó÷èì ñèãíàëû äëÿ ïîêóïêè
      if(Value[1]==2)
        {
         if(BuyPosOpen) if(Value[0]==1 || Value[0]==0) BUY_Open=true;
         if(SellPosClose) SELL_Close=true;
         UpSignalTime=datetime(SeriesInfoInteger(Symbol(),InpInd_Timeframe,SERIES_LASTBAR_DATE))+TimeShiftSec;
        }
      //--- ïîëó÷èì ñèãíàëû äëÿ ïðîäàæè
      if(Value[1]==1)
        {
         if(SellPosOpen) if(Value[0]==0 || Value[0]==2) SELL_Open=true;
         if(BuyPosClose) BUY_Close=true;
         DnSignalTime=datetime(SeriesInfoInteger(Symbol(),InpInd_Timeframe,SERIES_LASTBAR_DATE))+TimeShiftSec;
        }
     }
//--- ñîâåðøåíèå ñäåëîê
//--- çàêðûâàåì ëîíã
   BuyPositionClose(BUY_Close,Symbol(),Deviation_);
//--- çàêðûâàåì øîðò   
   SellPositionClose(SELL_Close,Symbol(),Deviation_);
//--- îòêðûâàåì ëîíã
   BuyPositionOpen(BUY_Open,Symbol(),UpSignalTime,MM,MMMode,Deviation_,StopLoss_,TakeProfit_);
//--- îòêðûâàåì øîðò
   SellPositionOpen(SELL_Open,Symbol(),DnSignalTime,MM,MMMode,Deviation_,StopLoss_,TakeProfit_);
//---
  }
//+------------------------------------------------------------------+