cycleperiod_v4

//+------------------------------------------------------------------+
//|                                                  CyclePeriod.mq5 |
//|                                                                  |
//| Cycle Period                                                     |
//|                                                                  |
//| Algorithm taken from book                                        |
//|     "Cybernetics Analysis for Stock and Futures"                 |
//| by John F. Ehlers                                                |
//|                                                                  |
//|                                              contact@mqlsoft.com |
//|                                          http://www.mqlsoft.com/ |
//+------------------------------------------------------------------+
//--- àâòîðñòâî èíäèêàòîðà
#property copyright "Coded by Witold Wozniak"
//--- àâòîðñòâî èíäèêàòîðà
#property link      "www.mqlsoft.com"
//--- íîìåð âåðñèè èíäèêàòîðà
#property version   "1.00"
//--- îòðèñîâêà èíäèêàòîðà â îòäåëüíîì îêíå
#property indicator_separate_window
//--- äëÿ ðàñ÷åòà è îòðèñîâêè èíäèêàòîðà èñïîëüçîâàíî äâà áóôåðà
#property indicator_buffers 1
//--- èñïîëüçîâàíî äâà ãðàôè÷åñêèõ ïîñòðîåíèÿ
#property indicator_plots   1
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà Cycle Period  |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà 1 â âèäå ëèíèè
#property indicator_type1   DRAW_LINE
//--- â êà÷åñòâå öâåòà áû÷åé ëèíèè èíäèêàòîðà èñïîëüçîâàí êðàñíûé öâåò
#property indicator_color1  Red
//--- ëèíèÿ èíäèêàòîðà 1 - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style1  STYLE_SOLID
//--- òîëùèíà ëèíèè èíäèêàòîðà 1 ðàâíà 1
#property indicator_width1  1
//--- îòîáðàæåíèå áû÷åé ìåòêè èíäèêàòîðà
#property indicator_label1  "Cycle Period"
//+----------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà                 |
//+----------------------------------------------+
input double Alpha=0.07;// Êîýôôèöèåíò èíäèêàòîðà
//+----------------------------------------------+
//--- îáúÿâëåíèå äèíàìè÷åñêèõ ìàññèâîâ, êîòîðûå â äàëüíåéøåì
//--- áóäóò èñïîëüçîâàíû â êà÷åñòâå èíäèêàòîðíûõ áóôåðîâ
double CPeriodBuffer[];
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ íà÷àëà îòñ÷åòà äàííûõ
int min_rates_total;
//--- îáúÿâëåíèå ãëîáàëüíûõ ïåðåìåííûõ
bool med2;
int median,median2;
double InstPeriod_,CPeriod_;
//--- îáúÿâëåíèå äèíàìè÷åñêèõ ìàññèâîâ, êîòîðûå â äàëüíåéøåì
//--- áóäóò èñïîëüçîâàíû â êà÷åñòâå êîëüöåâûõ áóôåðîâ
int Count1[],Count2[];
double K0,K1,K2,K3,F0,F1,F2,F3;
double Smooth[],Cycle[],Q1[],I1[],DeltaPhase[],M[],Price[];
//+------------------------------------------------------------------+
//| Ïåðåñ÷åò ïîçèöèè ñàìîãî íîâîãî ýëåìåíòà â ìàññèâå                |
//+------------------------------------------------------------------+   
void Recount_ArrayZeroPos1(int &CoArr[]) // Âîçâðàò ïî ññûëêå íîìåðà òåêóùåãî çíà÷åíèÿ öåíîâîãî ðÿäà
  {
//---
   int numb,Max1,Max2;
   static int count=1;
//---
   Max2=7;
   Max1=Max2-1;
//---
   count--;
   if(count<0) count=Max1;
//---
   for(int iii=0; iii<Max2; iii++)
     {
      numb=iii+count;
      if(numb>Max1) numb-=Max2;
      CoArr[iii]=numb;
     }
//---
  }
//+------------------------------------------------------------------+
//| Ïåðåñ÷åò ïîçèöèè ñàìîãî íîâîãî ýëåìåíòà â ìàññèâå                |
//+------------------------------------------------------------------+   
void Recount_ArrayZeroPos2(int &CoArr[])// Âîçâðàò ïî ññûëêå íîìåðà òåêóùåãî çíà÷åíèÿ öåíîâîãî ðÿäà
  {
//---
   int numb,Max1,Max2;
   static int count=1;
//---
   Max2=median;
   Max1=Max2-1;
//---
   count--;
   if(count<0) count=Max1;
//---
   for(int iii=0; iii<Max2; iii++)
     {
      numb=iii+count;
      if(numb>Max1) numb-=Max2;
      CoArr[iii]=numb;
     }
//---
  }
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+  
void OnInit()
  {
//--- èíèöèàëèçàöèÿ ïåðåìåííûõ
   K0=MathPow((1.0 - 0.5*Alpha),2);
   K1=2.0;
   K2=K1 *(1.0 - Alpha);
   K3=MathPow((1.0 - Alpha),2);
   F0=0.0962;
   F1=0.5769;
   F2=0.5;
   F3=0.08;
   median=5;
   median2=median/2;
   if(median%2==0) med2=true;
   else            med2=false;
//--- ðàñïðåäåëåíèå ïàìÿòè ïîä ìàññèâû ïåðåìåííûõ  
   ArrayResize(Count1,7);
   ArrayResize(Smooth,7);
   ArrayResize(Cycle,7);
   ArrayResize(Q1,7);
   ArrayResize(I1,7);
   ArrayResize(Price,7);
   ArrayResize(Count2,median);
   ArrayResize(DeltaPhase,median);
   ArrayResize(M,median);
//--- èíèöèàëèçàöèÿ ìàññèâîâ ïåðåìåííûõ
   ArrayInitialize(Smooth,0.0);
   ArrayInitialize(Cycle,0.0);
   ArrayInitialize(Q1,0.0);
   ArrayInitialize(I1,0.0);
   ArrayInitialize(Price,0.0);
   ArrayInitialize(DeltaPhase,0.0);
//--- èíèöèàëèçàöèÿ ïåðåìåííûõ íà÷àëà îòñ÷åòà äàííûõ
   min_rates_total=median+16;
//--- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(0,CPeriodBuffer,INDICATOR_DATA);
//--- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷åòà îòðèñîâêè èíäèêàòîðà
   PlotIndexSetInteger(0,PLOT_DRAW_BEGIN,min_rates_total);
//--- óñòàíîâêà çíà÷åíèé èíäèêàòîðà, êîòîðûå íå áóäóò âèäèìû íà ãðàôèêå
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0.0);
//--- èíèöèàëèçàöèè ïåðåìåííîé äëÿ êîðîòêîãî èìåíè èíäèêàòîðà
   string shortname;
   StringConcatenate(shortname,"Cycle Period(",DoubleToString(Alpha,4),")");
//--- ñîçäàíèå èìåíè äëÿ îòîáðàæåíèÿ â îòäåëüíîì ïîäîêíå è âî âñïëûâàþùåé ïîäñêàçêå
   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
//--- îïðåäåëåíèå òî÷íîñòè îòîáðàæåíèÿ çíà÷åíèé èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits+2);
//---
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,    // êîëè÷åñòâî èñòîðèè â áàðàõ íà òåêóùåì òèêå
                const int prev_calculated,// êîëè÷åñòâî èñòîðèè â áàðàõ íà ïðåäûäóùåì òèêå
                const datetime &time[],
                const double &open[],
                const double& high[],     // öåíîâîé ìàññèâ ìàêñèìóìîâ öåíû äëÿ ðàñ÷åòà èíäèêàòîðà
                const double& low[],      // öåíîâîé ìàññèâ ìèíèìóìîâ öåíû  äëÿ ðàñ÷åòà èíäèêàòîðà
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷åòà
   if(rates_total<min_rates_total) return(0);
//--- îáúÿâëåíèÿ ëîêàëüíûõ ïåðåìåííûõ 
   int first,bar,bar0,bar1,bar2,bar3,bar4,bar6;
   double CPeriod,InstPeriod,MedianDelta,DC;
//--- ðàñ÷åò ñòàðòîâîãî íîìåðà first äëÿ öèêëà ïåðåñ÷åòà áàðîâ
   if(prev_calculated>rates_total || prev_calculated<=0) // ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷åòà èíäèêàòîðà
     {
      first=0; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà âñåõ áàðîâ
      CPeriod_=1.0;
      InstPeriod_=1.0;
      CPeriodBuffer[0]=1.0;
     }
   else first=prev_calculated-1; // ñòàðòîâûé íîìåð äëÿ ðàñ÷åòà íîâûõ áàðîâ
//--- âîññòàíàâëèâàåì çíà÷åíèÿ ïåðåìåííûõ
   InstPeriod=InstPeriod_;
   CPeriod=CPeriod_;
//--- îñíîâíîé öèêë ðàñ÷åòà èíäèêàòîðà
   for(bar=first; bar<rates_total && !IsStopped(); bar++)
     {
      //--- çàïîìèíàåì çíà÷åíèÿ ïåðåìåííûõ ïåðåä ïðîãîíàìè íà òåêóùåì áàðå
      if(rates_total!=prev_calculated && bar==rates_total-1)
        {
         CPeriod_=CPeriod;
         InstPeriod_=InstPeriod;
        }
      //---
      bar0=Count1[0];
      bar1=Count1[1];
      bar2=Count1[2];
      bar3=Count1[3];
      bar4=Count1[4];
      bar6=Count1[6];
      //---
      Price[bar0]=(high[bar]+low[bar])/2.0;
      Smooth[bar0]=(Price[bar0]+2.0*Price[bar1]+2.0*Price[bar2]+Price[bar3])/6.0;
      //---
      if(bar<6) Cycle[bar0]=(Price[bar0]-2.0*Price[bar1]+Price[bar2])/4.0;
      else Cycle[bar0]=K0*(Smooth[bar0]-K1*Smooth[bar1]+Smooth[bar2])+K2*Cycle[bar1]-K3*Cycle[bar2];
      //---
      Q1[bar0]=(F0*Cycle[bar0]+F1*Cycle[bar2]-F1*Cycle[bar4]-F0*Cycle[bar6])*(F2+F3*InstPeriod);
      I1[bar0]= Cycle[Count1[3]];
      //---
      if(Q1[bar0] && Q1[bar1])
         DeltaPhase[Count2[0]]=(I1[bar0]/Q1[bar0]-I1[bar1]/Q1[bar1])/(1.0+I1[bar0]*I1[bar1]/(Q1[bar0]*Q1[bar1]));
      //---
      bar0=Count2[0];
      DeltaPhase[bar0]=MathMax(0.1,DeltaPhase[bar0]);
      DeltaPhase[bar0]=MathMin(1.1,DeltaPhase[bar0]);
      //---
      ArrayCopy(M,DeltaPhase,0,0,WHOLE_ARRAY);
      ArraySort(M);
      //---
      if(med2) MedianDelta=(M[median2]+M[median2+1])/2.0;
      else     MedianDelta=M[median2];
      //---
      if(!MedianDelta) DC=15.0;
      else             DC=6.28318/MedianDelta+0.5;
      //---
      InstPeriod=0.67*InstPeriod+0.33*DC;
      CPeriod=0.85*CPeriod+0.15*InstPeriod;
      CPeriodBuffer[bar]=CPeriod;
      //---
      if(bar<rates_total-1)
        {
         Recount_ArrayZeroPos1(Count1);
         Recount_ArrayZeroPos2(Count2);
        }
     }
//---     
   return(rates_total);
  }
//+------------------------------------------------------------------+