Close Balance Equity 2

ÿþ//+------------------------------------------------------------------+

//|                                       Close Balance Equity 2.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "2.000"

/*

   barabashkakvn Trading engine 3.144

*/

#include <Trade\PositionInfo.mqh>

#include <Trade\Trade.mqh>

#include <Trade\AccountInfo.mqh>

//---

CPositionInfo  m_position;                   // trade position object

CTrade         m_trade;                      // trading object

CAccountInfo   m_account;                    // account info wrapper

//+------------------------------------------------------------------+

//| Enum Balance Or Equity                                           |

//+------------------------------------------------------------------+

enum ENUM_BALANCE_OR_EQUITY

  {

   balance=0,  // Balance

   equity=1,   // Equity

  };

//--- input parameters

input ushort                  InpSignalsFrequency        = 10;       // Search signals, in seconds (< '10' -> only on a new bar on Current Symbol)

input bool                    InpAllSymbols              = true;     // All Symbol: ('true' -> all symbols, 'false' -> only Current Symbol)

input ENUM_BALANCE_OR_EQUITY  InpBalanceOrEquity         = equity;   // Balance Or Equity:

input double                  InpVolumeBalanceOrEquity   = 100.0;    // The value for 'Balance Or Equity' (in money)

input ulong                   InpMagic                   = 0;        // Magic number ('0' -> all magic's)

//---

double   m_start_balance   = 0.0;

double   m_start_equity    = 0.0;

bool     m_need_close_all  = false;

datetime m_last_signal     = 0;              // "0" -> D'1970.01.01 00:00';

datetime m_prev_bars       = 0;              // "0" -> D'1970.01.01 00:00';

//+------------------------------------------------------------------+

//| Expert initialization function                                   |

//+------------------------------------------------------------------+

int OnInit()

  {

//---

   m_trade.SetExpertMagicNumber(InpMagic);

   m_trade.SetMarginMode();

   m_trade.SetDeviationInPoints(10);

//---

   if(InpBalanceOrEquity==balance)

      m_start_balance=m_account.Balance();

   else

      m_start_equity=m_account.Equity();

//---

   /*string arr_symbols[6]= {"EURUSD","USDJPY","GBPUSD","AUDUSD","EURPLN","GBPCAD"};

   for(int i=0; i<6; i++)

     {

      bool res=false;

      while(!res)

        {

         if(!SymbolInfoInteger(arr_symbols[i],SYMBOL_EXIST))

            res=true;

         else

            res=m_trade.Sell(0.01,arr_symbols[i]);

        }

      Sleep(1000*3600*5);

     }*/

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Expert deinitialization function                                 |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

//---

  }

//+------------------------------------------------------------------+

//| Expert tick function                                             |

//+------------------------------------------------------------------+

void OnTick()

  {

   if(m_need_close_all)

     {

      if(IsPositionExists())

        {

         CloseAllPositions();

         return;

        }

      else

         m_need_close_all=false;

     }

//---

   if(!IsPositionExists())

     {

      if(InpBalanceOrEquity==balance)

         m_start_balance=m_account.Balance();

      else

         m_start_equity=m_account.Equity();

     }

   if(InpSignalsFrequency>=10) // search for trading signals no more than once every 10 seconds

     {

      datetime time_current=TimeCurrent();

      if(time_current-m_last_signal>InpSignalsFrequency)

        {

         //--- search for trading signals

         SearchTradingSignals();

         m_last_signal=time_current;

        }

     }

   else

     {

      //--- we work only at the time of the birth of new bar

      if(InpSignalsFrequency<10)

        {

         datetime time_0=iTime(Symbol(),Period(),0);

         if(time_0==m_prev_bars)

            return;

         m_prev_bars=time_0;

         if(InpSignalsFrequency<10) // search for trading signals only at the time of the birth of new bar

           {

            //--- search for trading signals

            SearchTradingSignals();

           }

        }

     }

  }

//+------------------------------------------------------------------+

//| TradeTransaction function                                        |

//+------------------------------------------------------------------+

void OnTradeTransaction(const MqlTradeTransaction &trans,

                        const MqlTradeRequest &request,

                        const MqlTradeResult &result)

  {

//---

  }

//+------------------------------------------------------------------+

//| Profit all positions                                             |

//+------------------------------------------------------------------+

double ProfitAllPositions(void)

  {

   double profit=0.0;

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==Symbol() || InpAllSymbols)

            if(m_position.Magic()==InpMagic || InpMagic==0)

               profit+=m_position.Commission()+m_position.Swap()+m_position.Profit();

//---

   return(profit);

  }

//+------------------------------------------------------------------+

//| Is position exists                                               |

//+------------------------------------------------------------------+

bool IsPositionExists(void)

  {

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

         if(m_position.Symbol()==Symbol() || InpAllSymbols)

            if(m_position.Magic()==InpMagic || InpMagic==0)

               return(true);

//---

   return(false);

  }

//+------------------------------------------------------------------+

//| Close all positions                                              |

//+------------------------------------------------------------------+

void CloseAllPositions()

  {

   for(int i=PositionsTotal()-1; i>=0; i--) // returns the number of current positions

      if(m_position.SelectByIndex(i))     // selects the position by index for further access to its properties

         if(m_position.Symbol()==Symbol() || InpAllSymbols)

            if(m_position.Magic()==InpMagic || InpMagic==0)

               m_trade.PositionClose(m_position.Ticket()); // close a position by the specified symbol

  }

//+------------------------------------------------------------------+

//| Search trading signals                                           |

//+------------------------------------------------------------------+

void SearchTradingSignals(void)

  {

   if(InpBalanceOrEquity==balance)

     {

      if(InpVolumeBalanceOrEquity>0.0 && m_account.Balance()-m_start_balance>=InpVolumeBalanceOrEquity)

         m_need_close_all=true;

     }

   else

     {

      double profit=ProfitAllPositions();

      if(InpVolumeBalanceOrEquity>0.0 && profit>=InpVolumeBalanceOrEquity)

         m_need_close_all=true;

     }

  }

//+------------------------------------------------------------------+