Close All Positions Type

ÿþ//+------------------------------------------------------------------+

//|                                     Close All Positions Type.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

/*

   barabashkakvn Trading engine 3.137

*/

#include <Trade\PositionInfo.mqh>

#include <Trade\Trade.mqh>

#include <Trade\SymbolInfo.mqh>

//---

CPositionInfo  m_position;                   // object of CPositionInfo class

CTrade         m_trade;                      // object of CTrade class

CSymbolInfo    m_symbol;                     // object of CSymbolInfo class

//+------------------------------------------------------------------+

//| Enum Pos Type                                                    |

//+------------------------------------------------------------------+

enum ENUM_POS_TYPE

  {

   buy=0,      // ... only BUY positions

   sell=1,     // ... only SELL positions

   buy_sell=2, // ... BUY and SELL positions

  };

//+------------------------------------------------------------------+

//| Enum Profit In                                                   |

//+------------------------------------------------------------------+

enum ENUM_PROFIT_IN

  {

   pips=0,     // ... pips (1.00045-1.00055=1 pips)

   points=1,   // ... points (1.00045-1.00055=10 points)

   money=2,    // ... money deposit

  };

//--- input parameters

input ENUM_POS_TYPE        InpPosType        = buy;         // Close positions:

input ENUM_PROFIT_IN       InpProfitIn       = money;       // Profit in:

input double               InpVolumeProfitIn = 3;           // Value 'Profit in'

input ulong                InpDeviation      = 10;          // Deviation

input ulong                InpMagic          = 279415740;   // Magic number

//---

ulong    m_arr_tickets[];                       // array tickets

//+------------------------------------------------------------------+

//| Expert initialization function                                   |

//+------------------------------------------------------------------+

int OnInit()

  {

   m_trade.SetExpertMagicNumber(InpMagic);

   m_trade.SetDeviationInPoints(InpDeviation);

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Expert deinitialization function                                 |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

//---

  }

//+------------------------------------------------------------------+

//| Expert tick function                                             |

//+------------------------------------------------------------------+

void OnTick()

  {

//---

   int size_tickets=ArraySize(m_arr_tickets);

   if(size_tickets>0)

     {

      for(int i=size_tickets-1; i>=0; i--)

        {

         if(m_position.SelectByTicket(m_arr_tickets[i])) // selects the position by tickets for further access to its properties

            ClosePositions(m_arr_tickets[i]);

         else

           {

            ArrayRemove(m_arr_tickets,i,1);

           }

        }

      return;

     }

//---

   for(int i=PositionsTotal()-1; i>=0; i--)

      if(m_position.SelectByIndex(i)) // selects the position by index for further access to its properties

        {

         ENUM_POSITION_TYPE pos_type=m_position.PositionType();

         if(pos_type==POSITION_TYPE_BUY)

           {

            if(InpPosType==sell)

               continue;

            if(InpProfitIn!=money)

              {

               //--- loss or profit

               double profit_in=GetProfitIn(m_position.Symbol());

               if(profit_in==0.0)

                  continue;

               if((InpVolumeProfitIn<0.0 && m_position.PriceCurrent()-m_position.PriceOpen()<=profit_in) ||

                  (InpVolumeProfitIn>0.0 && m_position.PriceCurrent()-m_position.PriceOpen()>=profit_in))

                 {

                  size_tickets=ArraySize(m_arr_tickets);

                  ArrayResize(m_arr_tickets,size_tickets+1,10);

                  m_arr_tickets[size_tickets]=m_position.Ticket();

                  continue;

                 }

              }

            else

              {

               double profit_in=m_position.Commission()+m_position.Swap()+m_position.Profit();

               //--- loss or profit

               if((InpVolumeProfitIn<0.0 && profit_in<=InpVolumeProfitIn) ||

                  (InpVolumeProfitIn>0.0 && profit_in>=InpVolumeProfitIn))

                 {

                  size_tickets=ArraySize(m_arr_tickets);

                  ArrayResize(m_arr_tickets,size_tickets+1,10);

                  m_arr_tickets[size_tickets]=m_position.Ticket();

                  continue;

                 }

              }

           }

         else

           {

            if(InpPosType==buy)

               continue;

            if(InpProfitIn!=money)

              {

               //--- loss or profit

               double profit_in=GetProfitIn(m_position.Symbol());

               if(profit_in==0.0)

                  continue;

               if((InpVolumeProfitIn<0.0 && m_position.PriceOpen()-m_position.PriceCurrent()<=profit_in) ||

                  (InpVolumeProfitIn>0.0 && m_position.PriceOpen()-m_position.PriceCurrent()>=profit_in))

                 {

                  size_tickets=ArraySize(m_arr_tickets);

                  ArrayResize(m_arr_tickets,size_tickets+1,10);

                  m_arr_tickets[size_tickets]=m_position.Ticket();

                  continue;

                 }

              }

            else

              {

               double profit_in=m_position.Commission()+m_position.Swap()+m_position.Profit();

               //--- loss or profit

               if((InpVolumeProfitIn<0.0 && profit_in<=InpVolumeProfitIn) ||

                  (InpVolumeProfitIn>0.0 && profit_in>=InpVolumeProfitIn))

                 {

                  size_tickets=ArraySize(m_arr_tickets);

                  ArrayResize(m_arr_tickets,size_tickets+1,10);

                  m_arr_tickets[size_tickets]=m_position.Ticket();

                  continue;

                 }

              }

           }

        }

//---

  }

//+------------------------------------------------------------------+

//| TradeTransaction function                                        |

//+------------------------------------------------------------------+

void OnTradeTransaction(const MqlTradeTransaction &trans,

                        const MqlTradeRequest &request,

                        const MqlTradeResult &result)

  {

//---

  }

//+------------------------------------------------------------------+

//| Refreshes the symbol quotes data                                 |

//+------------------------------------------------------------------+

bool RefreshRates()

  {

//--- refresh rates

   if(!m_symbol.RefreshRates())

      return(false);

//--- protection against the return value of "zero"

   if(m_symbol.Ask()==0 || m_symbol.Bid()==0)

      return(false);

//---

   return(true);

  }

//+------------------------------------------------------------------+

//| Check Freeze and Stops levels                                    |

//+------------------------------------------------------------------+

void FreezeStopsLevels(double &freeze,double &stops)

  {

//--- check Freeze and Stops levels

   /*

   SYMBOL_TRADE_FREEZE_LEVEL shows the distance of freezing the trade operations

      for pending orders and open positions in points

   ------------------------|--------------------|--------------------------------------------

   Type of order/position  |  Activation price  |  Check

   ------------------------|--------------------|--------------------------------------------

   Buy Limit order         |  Ask               |  Ask-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy Stop order          |  Ask               |  OpenPrice-Ask  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Limit order        |  Bid               |  OpenPrice-Bid  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Stop order         |  Bid               |  Bid-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy position            |  Bid               |  TakeProfit-Bid >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  Bid-StopLoss   >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell position           |  Ask               |  Ask-TakeProfit >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  StopLoss-Ask   >= SYMBOL_TRADE_FREEZE_LEVEL

   ------------------------------------------------------------------------------------------



   SYMBOL_TRADE_STOPS_LEVEL determines the number of points for minimum indentation of the

      StopLoss and TakeProfit levels from the current closing price of the open position

   ------------------------------------------------|------------------------------------------

   Buying is done at the Ask price                 |  Selling is done at the Bid price

   ------------------------------------------------|------------------------------------------

   TakeProfit        >= Bid                        |  TakeProfit        <= Ask

   StopLoss          <= Bid                        |  StopLoss          >= Ask

   TakeProfit - Bid  >= SYMBOL_TRADE_STOPS_LEVEL   |  Ask - TakeProfit  >= SYMBOL_TRADE_STOPS_LEVEL

   Bid - StopLoss    >= SYMBOL_TRADE_STOPS_LEVEL   |  StopLoss - Ask    >= SYMBOL_TRADE_STOPS_LEVEL

   ------------------------------------------------------------------------------------------

   */

   double coeff=1;

   if(!RefreshRates() || !m_symbol.Refresh())

      return;

//--- FreezeLevel -> for pending order and modification

   double freeze_level=m_symbol.FreezeLevel()*m_symbol.Point();

   if(freeze_level==0.0)

      freeze_level=(m_symbol.Ask()-m_symbol.Bid())*coeff;

//--- StopsLevel -> for TakeProfit and StopLoss

   double stop_level=m_symbol.StopsLevel()*m_symbol.Point();

   if(stop_level==0.0)

      stop_level=(m_symbol.Ask()-m_symbol.Bid())*coeff;

//---

   freeze=freeze_level;

   stops=stop_level;

//---

   return;

  }

//+------------------------------------------------------------------+

//| Close positions                                                  |

//+------------------------------------------------------------------+

void ClosePositions(const ulong icket)

  {

   double freeze=0.0,stops=0.0;

   FreezeStopsLevels(freeze,stops);

   /*

   SYMBOL_TRADE_FREEZE_LEVEL shows the distance of freezing the trade operations

      for pending orders and open positions in points

   ------------------------|--------------------|--------------------------------------------

   Type of order/position  |  Activation price  |  Check

   ------------------------|--------------------|--------------------------------------------

   Buy Limit order         |  Ask               |  Ask-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy Stop order          |  Ask               |  OpenPrice-Ask  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Limit order        |  Bid               |  OpenPrice-Bid  >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell Stop order         |  Bid               |  Bid-OpenPrice  >= SYMBOL_TRADE_FREEZE_LEVEL

   Buy position            |  Bid               |  TakeProfit-Bid >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  Bid-StopLoss   >= SYMBOL_TRADE_FREEZE_LEVEL

   Sell position           |  Ask               |  Ask-TakeProfit >= SYMBOL_TRADE_FREEZE_LEVEL

                           |                    |  StopLoss-Ask   >= SYMBOL_TRADE_FREEZE_LEVEL

   ------------------------------------------------------------------------------------------

   */

   bool take_profit_level=((m_position.TakeProfit()!=0.0 && m_position.TakeProfit()-m_position.PriceCurrent()>=freeze) || m_position.TakeProfit()==0.0);

   bool stop_loss_level=((m_position.StopLoss()!=0.0 && m_position.PriceCurrent()-m_position.StopLoss()>=freeze) || m_position.StopLoss()==0.0);

   if(take_profit_level && stop_loss_level)

      if(!m_trade.PositionClose(m_position.Ticket())) // close a position by the specified m_symbol

         Print(__FILE__," ",__FUNCTION__,", ERROR: ","CTrade.PositionClose ",m_position.Ticket());

  }

//+------------------------------------------------------------------+

//| Get Profit In                                                    |

//+------------------------------------------------------------------+

double GetProfitIn(const string name)

  {

   double m_profit_in            = 0.0;      // Profit in:        -> double

   double m_adjusted_point;                  // point value adjusted for 3 or 5 points

   if(!m_symbol.Name(name)) // sets symbol name

     {

      Print(__FILE__," ",__FUNCTION__,", ERROR: CSymbolInfo.Name");

      return(0.0);

     }

   RefreshRates();

//---

   m_trade.SetMarginMode();

   m_trade.SetTypeFillingBySymbol(m_symbol.Name());

//--- tuning for 3 or 5 digits

   int digits_adjust=1;

   if(m_symbol.Digits()==3 || m_symbol.Digits()==5)

      digits_adjust=10;

   m_adjusted_point=m_symbol.Point()*digits_adjust;

   if(InpProfitIn==pips) // Pips (1.00045-1.00055=1 pips)

      m_profit_in                = InpVolumeProfitIn           * m_adjusted_point;

   else

      if(InpProfitIn==points) // Points (1.00045-1.00055=10 points)

         m_profit_in             = InpVolumeProfitIn           * m_symbol.Point();

//---

   return(m_profit_in);

  }

//+------------------------------------------------------------------+