CCI - JMA based

ÿþ//------------------------------------------------------------------

#property copyright "© mladen, 2018"

#property link      "mladenfx@gmail.com"

#property version   "1.00"

//------------------------------------------------------------------

#property indicator_separate_window

#property indicator_buffers 5

#property indicator_plots   4

#property indicator_label1  "shadow"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrGray

#property indicator_width1  6

#property indicator_label2  "up level"

#property indicator_type2   DRAW_LINE

#property indicator_color2  clrLimeGreen

#property indicator_style2  STYLE_DOT

#property indicator_label3  "down level"

#property indicator_type3   DRAW_LINE

#property indicator_color3  clrRed

#property indicator_style3  STYLE_DOT

#property indicator_label4  "value"

#property indicator_type4   DRAW_COLOR_LINE

#property indicator_color4  clrSilver,clrLimeGreen,clrRed

#property indicator_width4  2

//

//---

//

input int                inpCciPeriod       = 32;            // CCI period

input ENUM_APPLIED_PRICE inpCciPrice        = PRICE_TYPICAL; // Price

input int                inpSmoothPeriod    = 32;            // Smoothing period

input double             inpSmoothPhase     = 0.0;           // Smoothing phase

input double             inpLevelUp         =  100;          // Level up

input double             inpLevelDown       = -100;          // Level down

                                                             //

//---

//

double  val[],valc[],vals[],levelUp[],levelDn[];

//------------------------------------------------------------------

//

//------------------------------------------------------------------

void OnInit()

  {

   SetIndexBuffer(0,vals,INDICATOR_DATA);

   SetIndexBuffer(1,levelUp,INDICATOR_DATA);

   SetIndexBuffer(2,levelDn,INDICATOR_DATA);

   SetIndexBuffer(3,val,INDICATOR_DATA);

   SetIndexBuffer(4,valc,INDICATOR_COLOR_INDEX);

   IndicatorSetString(INDICATOR_SHORTNAME,"CCI - JMA based ("+(string)inpCciPeriod+","+(string)inpSmoothPeriod+")");

  }

//------------------------------------------------------------------

//

//------------------------------------------------------------------

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

   int i=(int)MathMax(prev_calculated-1,0); for(; i<rates_total && !_StopFlag; i++)

     {

      double _price = iSmooth(getPrice(inpCciPrice,open,close,high,low,i,rates_total),inpSmoothPeriod,inpSmoothPhase,i,1);

      double avg    = iSmooth(_price,inpCciPeriod,inpSmoothPhase,i,0);

      double dev    = MathMax(iEmaDeviation(_price,inpCciPeriod,i),DBL_MIN);



      //

      //---

      //



      val[i]=(dev!=0) ?(_price-avg)/(0.015*dev) : 0; vals[i] = val[i];

      levelUp[i] = inpLevelUp;

      levelDn[i] = inpLevelDown;

      valc[i]    = (val[i]>levelUp[i]) ? 1 : (val[i]<levelDn[i]) ? 2 : (i>0) ? (val[i]==val[i-1]) ? valc[i-1]: 0 : 0;

     }

   return(i);

  }

//+------------------------------------------------------------------+

//| Custom functions                                                 |

//+------------------------------------------------------------------+

#define _smoothInstances     2

#define _smoothInstancesSize 10

#define _smoothRingSize      11

double workSmooth[_smoothRingSize][_smoothInstances*_smoothInstancesSize];

#define bsmax  5

#define bsmin  6

#define volty  7

#define vsum   8

#define avolty 9

//

//

//

double iSmooth(double price, double length, double phase, int i, int instance=0)

{

   int _indP = (i-1)%_smoothRingSize;

   int _indC = (i  )%_smoothRingSize;

   int _inst = instance*_smoothInstancesSize;



   if(i==0 || length<=1) { int k=0; for(; k<volty; k++) workSmooth[_indC][_inst+k]=price; for(; k<_smoothInstancesSize; k++) workSmooth[_indC][_inst+k]=0; return(price); }



   //

   //

   //



      double len1 = MathMax(MathLog(MathSqrt(0.5*(length-1.0)))/MathLog(2.0)+2.0,0);

      double pow1 = MathMax(len1-2.0,0.5);

      double del1 = price - workSmooth[_indP][_inst+bsmax], absDel1 = MathAbs(del1);

      double del2 = price - workSmooth[_indP][_inst+bsmin], absDel2 = MathAbs(del2);

      int   _indF = (i-MathMin(i,10))%_smoothRingSize;



         workSmooth[_indC][_inst+volty]  = (absDel1 > absDel2) ? absDel1 : (absDel1 < absDel2) ? absDel2 : 0;

         workSmooth[_indC][_inst+vsum]   = workSmooth[_indP][_inst+vsum]+(workSmooth[_indC][_inst+volty]-workSmooth[_indF][_inst+volty])*0.1;

         workSmooth[_indC][_inst+avolty] = workSmooth[_indP][_inst+avolty]+(2.0/(MathMax(4.0*length,30)+1.0))*(workSmooth[_indC][_inst+vsum]-workSmooth[_indP][_inst+avolty]);

      

      double dVolty    = (workSmooth[_indC][_inst+avolty]>0) ? workSmooth[_indC][_inst+volty]/workSmooth[_indC][_inst+avolty]: 0;

      double dVoltyTmp = MathPow(len1,1.0/pow1);

         if (dVolty > dVoltyTmp) dVolty = dVoltyTmp;

         if (dVolty < 1.0)       dVolty = 1.0;



      double pow2 = MathPow(dVolty, pow1);

      double len2 = MathSqrt(0.5*(length-1))*len1;

      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));



         workSmooth[_indC][_inst+bsmax] = (del1 > 0) ? price : price - Kv*del1;

         workSmooth[_indC][_inst+bsmin] = (del2 < 0) ? price : price - Kv*del2;



      //

      //

      //



      double corr  = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;

      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);

      double alpha = MathPow(beta,pow2);



          workSmooth[_indC][_inst+0] = price + alpha*(workSmooth[_indP][_inst+0]-price);

          workSmooth[_indC][_inst+1] = (price - workSmooth[_indC][_inst+0])*(1-beta) + beta*workSmooth[_indP][_inst+1];

          workSmooth[_indC][_inst+2] = (workSmooth[_indC][_inst+0] + corr*workSmooth[_indC][_inst+1]);

          workSmooth[_indC][_inst+3] = (workSmooth[_indC][_inst+2] - workSmooth[_indP][_inst+4])*((1-alpha)*(1-alpha)) + (alpha*alpha)*workSmooth[_indP][_inst+3];

          workSmooth[_indC][_inst+4] = (workSmooth[_indP][_inst+4] + workSmooth[_indC][_inst+3]);

   return(workSmooth[_indC][_inst+4]);



   #undef bsmax

   #undef bsmin

   #undef volty

   #undef vsum

   #undef avolty

}    

//

//---

//

#define _edevInstances 1

#define _edevInstancesSize 2

#define _edevRingSize 5

double workEmaDeviation[_edevRingSize][_edevInstances*_edevInstancesSize];

#define _ema0 0

#define _ema1 1

//

//---

//

double iEmaDeviation(double price,double period, int i, int instance=0)

{

   int _indP = (i-1)%_edevRingSize;

   int _indC = (i  )%_edevRingSize;

   int _inst = instance*_edevInstancesSize;

   

   if (i>0 && period>1)

   {

      double alpha = 2.0/(1.0+period);

         workEmaDeviation[_indC][_inst+_ema0] = workEmaDeviation[_indP][_inst+_ema0]+alpha*(price      -workEmaDeviation[_indP][_inst+_ema0]);

         workEmaDeviation[_indC][_inst+_ema1] = workEmaDeviation[_indP][_inst+_ema1]+alpha*(price*price-workEmaDeviation[_indP][_inst+_ema1]);

   }         

   else for (int k=0; k<_edevInstancesSize; k++) workEmaDeviation[_indC][_inst+k] = price;

   return(MathSqrt(period*(workEmaDeviation[_indC][_inst+_ema1]-workEmaDeviation[_indC][_inst+_ema0]*workEmaDeviation[_indC][_inst+_ema0])/MathMax(period-1,1)));

}

//

//---

//

//

//---

//

double getPrice(ENUM_APPLIED_PRICE tprice,const double &open[],const double &close[],const double &high[],const double &low[],int i,int _bars)

  {

   switch(tprice)

     {

      case PRICE_CLOSE:     return(close[i]);

      case PRICE_OPEN:      return(open[i]);

      case PRICE_HIGH:      return(high[i]);

      case PRICE_LOW:       return(low[i]);

      case PRICE_MEDIAN:    return((high[i]+low[i])/2.0);

      case PRICE_TYPICAL:   return((high[i]+low[i]+close[i])/3.0);

      case PRICE_WEIGHTED:  return((high[i]+low[i]+close[i]+close[i])/4.0);

     }

   return(0);

  }

//+------------------------------------------------------------------+