BB-Percentage-Decimal

ÿþ//+------------------------------------------------------------------+

//|                                        BB-Percentage-Decimal.mq5 |

//|                        Copyright 2018, MetaQuotes Software Corp. |

//|                                                 https://mql5.com |

//+------------------------------------------------------------------+

#property copyright "Copyright 2018, MetaQuotes Software Corp."

#property link      "https://mql5.com"

#property version   "1.00"

#property indicator_separate_window

#property indicator_buffers 4

#property indicator_plots   1

//--- plot BB

#property indicator_label1  "BB"

#property indicator_type1   DRAW_LINE

#property indicator_color1  clrLimeGreen

#property indicator_style1  STYLE_SOLID

#property indicator_width1  1

//--- input parameters

input uint                 InpPeriod         =  20;            // Period

input double               InpDeviation      =  2.0;           // Bands Deviation

input ENUM_APPLIED_PRICE   InpAppliedPrice   =  PRICE_CLOSE;   // Applied price

//--- indicator buffers

double         BufferBB[];

double         BufferMA[];

double         BufferMA1[];

double         BufferDev[];

//--- global variables

int            period;

int            handle_ma;

int            handle_ma1;

int            handle_dev;

double         deviation;

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- setting global variables

   period=int(InpPeriod<1 ? 1 : InpPeriod);

   deviation=(InpDeviation<0.1 ? 0.1 : InpDeviation);

//--- indicator buffers mapping

   SetIndexBuffer(0,BufferBB,INDICATOR_DATA);

   SetIndexBuffer(1,BufferMA,INDICATOR_CALCULATIONS);

   SetIndexBuffer(2,BufferMA1,INDICATOR_CALCULATIONS);

   SetIndexBuffer(3,BufferDev,INDICATOR_CALCULATIONS);

//--- settings indicators parameters

   IndicatorSetInteger(INDICATOR_DIGITS,Digits());

   IndicatorSetString(INDICATOR_SHORTNAME,"BB-Percentage-Decimal");

//--- setting buffer arrays as timeseries

   ArraySetAsSeries(BufferBB,true);

   ArraySetAsSeries(BufferMA,true);

   ArraySetAsSeries(BufferMA1,true);

   ArraySetAsSeries(BufferDev,true);

//--- create handles MA(period), MA(1) and StdDev

   ResetLastError();

   handle_ma=iMA(Symbol(),PERIOD_CURRENT,period,0,MODE_SMA,InpAppliedPrice);

   if(handle_ma==INVALID_HANDLE)

     {

      Print("The iMA(",(string)period,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

   ResetLastError();

   handle_ma1=iMA(Symbol(),PERIOD_CURRENT,1,0,MODE_SMA,InpAppliedPrice);

   if(handle_ma1==INVALID_HANDLE)

     {

      Print("The iMA(1) object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

   ResetLastError();

   handle_dev=iStdDev(Symbol(),PERIOD_CURRENT,period,0,MODE_SMA,InpAppliedPrice);

   if(handle_dev==INVALID_HANDLE)

     {

      Print("The iStdDev(",(string)period,") object was not created: Error ",GetLastError());

      return INIT_FAILED;

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- @>25@:0 =0 <8=8<0;L=>5 :>;85AB2> 10@>2 4;O @0AGQB0

   if(rates_total<2) return 0;

//--- @>25@:0 8 @0AGQB :>;8G5AB20 ?@>AG8BK205<KE 10@>2

   int limit=rates_total-prev_calculated;

   if(limit>1)

     {

      limit=rates_total-1;

      ArrayInitialize(BufferBB,EMPTY_VALUE);

      ArrayInitialize(BufferMA,EMPTY_VALUE);

      ArrayInitialize(BufferMA1,EMPTY_VALUE);

      ArrayInitialize(BufferDev,EMPTY_VALUE);

     }

//--- >43>B>2:0 40==KE

   int copied=0,count=(limit>1 ? rates_total : 1);

   copied=CopyBuffer(handle_ma,0,0,count,BufferMA);

   if(copied!=count) return 0;

   copied=CopyBuffer(handle_ma1,0,0,count,BufferMA1);

   if(copied!=count) return 0;

   copied=CopyBuffer(handle_dev,0,0,count,BufferDev);

   if(copied!=count) return 0;

//---  0AGQB 8=48:0B>@0

   for(int i=limit; i>=0 && !IsStopped(); i--)

     {

      if(BufferDev[i]==0) continue;

      BufferBB[i]=(BufferMA1[i]-BufferMA[i]+deviation*BufferDev[i])/(2.0*deviation*BufferDev[i])*100.0;

     }



//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+