BackgroundCandle_PPO_Cloud_HTF

//+----------------------------------------------------------------------+ 
//|                                   BackgroundCandle_PPO_Cloud_HTF.mq5 | 
//|                                   Copyright © 2016, Nikolay Kositsin | 
//|                                  Khabarovsk,   farria@mail.redcom.ru | 
//+----------------------------------------------------------------------+
//| Äëÿ ðàáîòû èíäèêàòîðà ôàéë PPO_Cloud.mq5 ñëåäóåò ïîëîæèòü            |
//| â ïàïêó: êàòàëîã_äàííûõ_òåðìèíàëà\\MQL5\Indicators è îòêîìïèëèðîâàòü |
//+----------------------------------------------------------------------+
#property copyright "Copyright © 2016, Nikolay Kositsin"
#property link "farria@mail.redcom.ru"
//--- íîìåð âåðñèè èíäèêàòîðà
#property version   "1.61"
#property description "Èíäèêàòîð ñâå÷åê ñ îêðàñêîé îò PPO_Cloud ñ âîçìîæíîñòüþ èçìåíåíèÿ òàéìôðåéìà âî âõîäíûõ ïàðàìåòðàõ"
//--- îòðèñîâêà èíäèêàòîðà â îñíîâíîì îêíå
#property indicator_chart_window
//--- êîëè÷åñòâî èíäèêàòîðíûõ áóôåðîâ 12
#property indicator_buffers 12 
//--- èñïîëüçîâàíî øåñòü ãðàôè÷åñêèõ ïîñòðîåíèé
#property indicator_plots   6
//+----------------------------------------------+
//| îáúÿâëåíèå êîíñòàíò                          |
//+----------------------------------------------+
#define RESET 0                                               // Êîíñòàíòà äëÿ âîçâðàòà òåðìèíàëó êîìàíäû íà ïåðåñ÷¸ò èíäèêàòîðà
#define INDICATOR_NAME "BackgroundCandle_PPO_Cloud"           // Êîíñòàíòà äëÿ èìåíè èíäèêàòîðà
#define SIZE  1                                               // Êîíñòàíòà äëÿ êîëè÷åñòâà âûçîâîâ ôóíêöèè CountIndicator â êîäå
#define EMPTYVALUE 0                                          // Êîíñòàíòà äëÿ íåîòîáðàæàåìûõ çíà÷åíèé èíäèêàòîðà
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 1             |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type1   DRAW_FILLING
//--- â êà÷åñòâå öâåòà èíäèêàòîðà èñïîëüçîâàí
#property indicator_color1  clrPaleGreen,clrPlum
//--- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style1  STYLE_SOLID
//--- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label1  "Upper Shade"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 2             |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type2   DRAW_FILLING
//--- â êà÷åñòâå öâåòà èíäèêàòîðà èñïîëüçîâàí
#property indicator_color2  clrLimeGreen,clrMediumOrchid
//--- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style2  STYLE_SOLID
//--- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label2  "Body"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 3             |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type3   DRAW_FILLING
//--- â êà÷åñòâå öâåòà èíäèêàòîðà èñïîëüçîâàí
#property indicator_color3  clrPaleGreen,clrPlum
//--- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style3  STYLE_SOLID
//--- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label3  "Lower Shade"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 4             |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type4   DRAW_FILLING
//--- â êà÷åñòâå öâåòà èíäèêàòîðà èñïîëüçîâàí
#property indicator_color4  clrPaleGreen,clrPlum
//--- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style4  STYLE_SOLID
//--- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label4  "Upper Shade"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 5             |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type5   DRAW_FILLING
//--- â êà÷åñòâå öâåòà èíäèêàòîðà èñïîëüçîâàí
#property indicator_color5  clrLimeGreen,clrMediumOrchid
//--- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style5  STYLE_SOLID
//--- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label5  "Body"
//+----------------------------------------------+
//| Ïàðàìåòðû îòðèñîâêè èíäèêàòîðà 6             |
//+----------------------------------------------+
//--- îòðèñîâêà èíäèêàòîðà â âèäå öâåòíîãî îáëàêà
#property indicator_type6   DRAW_FILLING
//--- â êà÷åñòâå öâåòà èíäèêàòîðà èñïîëüçîâàí
#property indicator_color6  clrPaleGreen,clrPlum
//--- ëèíèÿ èíäèêàòîðà - íåïðåðûâíàÿ êðèâàÿ
#property indicator_style6  STYLE_SOLID
//--- îòîáðàæåíèå ìåòêè èíäèêàòîðà
#property indicator_label6  "Lower Shade"
//+----------------------------------------------+
//|  îáúÿâëåíèå ïåðå÷èñëåíèé                     |
//+----------------------------------------------+
enum Smooth_Method
  {
   MODE_SMA_,  //SMA
   MODE_EMA_,  //EMA
   MODE_SMMA_, //SMMA
   MODE_LWMA_, //LWMA
   MODE_JJMA,  //JJMA
   MODE_JurX,  //JurX
   MODE_ParMA, //ParMA
   MODE_T3,    //T3
   MODE_VIDYA, //VIDYA
   MODE_AMA,   //AMA
  };
//+----------------------------------------------+
//|  îáúÿâëåíèå ïåðå÷èñëåíèé                     |
//+----------------------------------------------+
enum Applied_price_ //Òèï êîíñòàíòû
  {
   PRICE_CLOSE_ = 1,     //Close
   PRICE_OPEN_,          //Open
   PRICE_HIGH_,          //High
   PRICE_LOW_,           //Low
   PRICE_MEDIAN_,        //Median Price (HL/2)
   PRICE_TYPICAL_,       //Typical Price (HLC/3)
   PRICE_WEIGHTED_,      //Weighted Close (HLCC/4)
   PRICE_SIMPL_,         //Simpl Price (OC/2)
   PRICE_QUARTER_,       //Quarted Price (HLOC/4) 
   PRICE_TRENDFOLLOW0_,  //TrendFollow_1 Price 
   PRICE_TRENDFOLLOW1_,  //TrendFollow_2 Price
   PRICE_DEMARK_         //Demark Price
  };
//+----------------------------------------------+
//| Âõîäíûå ïàðàìåòðû èíäèêàòîðà                 |
//+----------------------------------------------+
input ENUM_TIMEFRAMES TimeFrame=PERIOD_H4;   // Ïåðèîä ãðàôèêà èíäèêàòîðà
input Smooth_Method FastMethod=MODE_EMA_; //ìåòîä áûñòðîãî óñðåäíåíèÿ
input uint FastLength=12; //ãëóáèíà áûñòðîãî óñðåäíåíèÿ          
input int FastPhase=15; //ïàðàìåòð áûñòðîãî óñðåäíåíèÿ,
//---- äëÿ JJMA èçìåíÿþùèéñÿ â ïðåäåëàõ -100 ... +100, âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà;
//---- Äëÿ VIDIA ýòî ïåðèîä CMO, äëÿ AMA ýòî ïåðèîä ìåäëåííîé ñêîëüçÿùåé
input Smooth_Method SlowMethod=MODE_EMA_; //ìåòîä ìåäëåííîãî óñðåäíåíèÿ
input uint SlowLength=26; //ãëóáèíà ìåäëåííîãî óñðåäíåíèÿ                 
input int SlowPhase=15; //ïàðàìåòð ìåäëåííîãî óñðåäíåíèÿ,
//---- äëÿ JJMA èçìåíÿþùèéñÿ â ïðåäåëàõ -100 ... +100, âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà;
//---- Äëÿ VIDIA ýòî ïåðèîä CMO, äëÿ AMA ýòî ïåðèîä ìåäëåííîé ñêîëüçÿùåé
input Smooth_Method SignMethod=MODE_EMA_; //ìåòîä ñãëàæèâàíèÿ
input uint SignLength=9; //ãëóáèíà ñãëàæèâàíèÿ                    
input int SignPhase=15; //ïàðàìåòð ñãëàæèâàíèÿ,
//---- äëÿ JJMA èçìåíÿþùèéñÿ â ïðåäåëàõ -100 ... +100, âëèÿåò íà êà÷åñòâî ïåðåõîäíîãî ïðîöåññà;
//---- Äëÿ VIDIA ýòî ïåðèîä CMO, äëÿ AMA ýòî ïåðèîä ìåäëåííîé ñêîëüçÿùåé
input Applied_price_ IPC=PRICE_CLOSE_;//öåíîâàÿ êîíñòàíòà
input int Shift=0; // ñäâèã èíäèêàòîðà ïî ãîðèçîíòàëè â áàðàõ 
//+----------------------------------------------+
//--- îáúÿâëåíèå äèíàìè÷åñêèõ ìàññèâîâ, êîòîðûå â äàëüíåéøåì
//--- áóäóò èñïîëüçîâàíû â êà÷åñòâå èíäèêàòîðíûõ áóôåðîâ
double ExtA1Buffer[];
double ExtB1Buffer[];
double ExtA2Buffer[];
double ExtB2Buffer[];
double ExtA3Buffer[];
double ExtB3Buffer[];
double ExtA4Buffer[];
double ExtB4Buffer[];
double ExtA5Buffer[];
double ExtB5Buffer[];
double ExtA6Buffer[];
double ExtB6Buffer[];
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ íà÷àëà îòñ÷¸òà äàííûõ
int min_rates_total;
//--- îáúÿâëåíèå öåëî÷èñëåííûõ ïåðåìåííûõ äëÿ õåíäëîâ èíäèêàòîðîâ
int Ind_Handle;
//+------------------------------------------------------------------+
//|  Ïîëó÷åíèå òàéìôðåéìà â âèäå ñòðîêè                              |
//+------------------------------------------------------------------+
string GetStringTimeframe(ENUM_TIMEFRAMES timeframe)
  {return(StringSubstr(EnumToString(timeframe),7,-1));}
//+------------------------------------------------------------------+    
//| Custom indicator initialization function                         | 
//+------------------------------------------------------------------+  
int OnInit()
  {
//--- ïðîâåðêà ïåðèîäîâ ãðàôèêîâ íà êîððåêòíîñòü
   if(!TimeFramesCheck(INDICATOR_NAME,TimeFrame)) return(INIT_FAILED);
//--- èíèöèàëèçàöèÿ ïåðåìåííûõ 
   min_rates_total=2;
//--- ïîëó÷åíèå õåíäëà èíäèêàòîðà PPO_Cloud
   Ind_Handle=iCustom(Symbol(),TimeFrame,"PPO_Cloud",FastMethod,FastLength,FastPhase,SlowMethod,SlowLength,SlowPhase,SignMethod,SignLength,SignPhase,IPC,0);
   if(Ind_Handle==INVALID_HANDLE)
     {
      Print(" Íå óäàëîñü ïîëó÷èòü õåíäë èíäèêàòîðà PPO_Cloud");
      return(INIT_FAILED);
     }
//--- ïðåâðàùåíèå äèíàìè÷åñêèõ ìàññèâîâ â èíäèêàòîðíûå áóôåðû
   ArrayInit(0,ExtA1Buffer);
   ArrayInit(1,ExtB1Buffer);
   ArrayInit(2,ExtA2Buffer);
   ArrayInit(3,ExtB2Buffer);
   ArrayInit(4,ExtA3Buffer);
   ArrayInit(5,ExtB3Buffer);
   ArrayInit(6,ExtA4Buffer);
   ArrayInit(7,ExtB4Buffer);
   ArrayInit(8,ExtA5Buffer);
   ArrayInit(9,ExtB5Buffer);
   ArrayInit(10,ExtA6Buffer);
   ArrayInit(11,ExtB6Buffer);
//--- èíèöèàëèçàöèÿ èíäèêàòîðîâ
   PlotInit(0,2,Shift);
   PlotInit(1,2,Shift);
   PlotInit(2,2,Shift);
   PlotInit(3,2,Shift);
   PlotInit(4,2,Shift);
   PlotInit(5,2,Shift);
//--- ñîçäàíèå èìåíè äëÿ îòîáðàæåíèÿ â îòäåëüíîì ïîäîêíå è âî âñïëûâàþùåé ïîäñêàçêå
   string shortname;
   StringConcatenate(shortname,INDICATOR_NAME,"(",GetStringTimeframe(TimeFrame),")");
   IndicatorSetString(INDICATOR_SHORTNAME,shortname);
//--- îïðåäåëåíèå òî÷íîñòè îòîáðàæåíèÿ çíà÷åíèé èíäèêàòîðà
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//--- çàâåðøåíèå èíèöèàëèçàöèè
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+  
//| Custom iteration function                                        | 
//+------------------------------------------------------------------+  
int OnCalculate(const int rates_total,    // êîëè÷åñòâî èñòîðèè â áàðàõ íà òåêóùåì òèêå
                const int prev_calculated,// êîëè÷åñòâî èñòîðèè â áàðàõ íà ïðåäûäóùåì òèêå
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- ïðîâåðêà êîëè÷åñòâà áàðîâ íà äîñòàòî÷íîñòü äëÿ ðàñ÷¸òà
   if(rates_total<min_rates_total) return(RESET);
   if(BarsCalculated(Ind_Handle)<Bars(Symbol(),TimeFrame)) return(prev_calculated);
//--- èíäåêñàöèÿ ýëåìåíòîâ â ìàññèâàõ êàê â òàéìñåðèÿõ  
   ArraySetAsSeries(time,true);
//---
   if(!CountIndicator(0,Symbol(),TimeFrame,Ind_Handle,
      ExtA1Buffer,ExtB1Buffer,ExtA2Buffer,ExtB2Buffer,
      ExtA3Buffer,ExtB3Buffer,ExtA4Buffer,ExtB4Buffer,
      ExtA5Buffer,ExtB5Buffer,ExtA6Buffer,ExtB6Buffer,
      time,rates_total,prev_calculated,min_rates_total)) return(RESET);
//---     
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| CountIndicator                                                   |
//+------------------------------------------------------------------+
bool CountIndicator(uint     Numb,             // Íîìåð ôóíêöèè CountLine ïî ñïèñêó â êîäå èíäèêàòîðà (ñòàðòîâûé íîìåð - 0)
                    string   Symb,             // Ñèìâîë ãðàôèêà
                    ENUM_TIMEFRAMES TFrame,    // Ïåðèîä ãðàôèêà
                    int      IndHandle,        // Õåíäë îáðàáàòûâàåìîãî èíäèêàòîðà
                    double&  ExtA1Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 1
                    double&  ExtB1Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 2
                    double&  ExtA2Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 3
                    double&  ExtB2Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 4
                    double&  ExtA3Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 5
                    double&  ExtB3Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 6
                    double&  ExtA4Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 7
                    double&  ExtB4Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 8
                    double&  ExtA5Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 9
                    double&  ExtB5Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 10
                    double&  ExtA6Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 11
                    double&  ExtB6Buff[],      // Ïðè¸ìíûé áóôåð èíäèêàòîðà 12
                    const datetime &Time[],    // Òàéìñåðèÿ âðåìåíè
                    const int Rates_Total,     // êîëè÷åñòâî èñòîðèè â áàðàõ íà òåêóùåì òèêå
                    const int Prev_Calculated, // êîëè÷åñòâî èñòîðèè â áàðàõ íà ïðåäûäóùåì òèêå
                    const int Min_Rates_Total) // ìèíèìàëüíîå êîëè÷åñòâî èñòîðèè â áàðàõ äëÿ ðàñ÷¸òà
  {
//---
   static int Sign,Trend;
   static datetime LastTime;
   static int LastCountBar[SIZE];
   double iOpen[1],iLow[1],iHigh[1],iClose[1],iUp[1],iDn[1];
   datetime iTime[1];
   int limit;
//--- ñòàðòîâîãî íîìåðà limit äëÿ öèêëà ïåðåñ÷¸òà áàðîâ
   if(Prev_Calculated>Rates_Total || Prev_Calculated<=0)// ïðîâåðêà íà ïåðâûé ñòàðò ðàñ÷¸òà èíäèêàòîðà
     {
      limit=Rates_Total-Min_Rates_Total-1; // ñòàðòîâûé íîìåð äëÿ ðàñ÷¸òà âñåõ áàðîâ
      LastCountBar[Numb]=limit;
      LastTime=0;
      Sign=1;
     }
   else limit=LastCountBar[Numb]+Rates_Total-Prev_Calculated; // ñòàðòîâûé íîìåð äëÿ ðàñ÷¸òà íîâûõ áàðîâ 

//--- îñíîâíîé öèêë ðàñ÷¸òà èíäèêàòîðà
   for(int bar=limit; bar>=0 && !IsStopped(); bar--)
     {
      //--- êîïèðóåì âíîâü ïîÿâèâøèåñÿ äàííûå â ìàññèâ IndTime
      if(CopyTime(Symbol(),TFrame,Time[bar],1,iTime)<=0) return(RESET);

      if(Time[bar]>=iTime[0] && Time[bar+1]<iTime[0])
        {
         LastCountBar[Numb]=bar;
         if(iTime[0]!=LastTime)
           {
            LastTime=iTime[0];
            Sign*=(-1);
           }
         //--- êîïèðóåì âíîâü ïîÿâèâøèåñÿ äàííûå â ìàññèâû
         if(CopyBuffer(IndHandle,0,Time[bar],1,iUp)<=0) return(RESET);
         if(CopyBuffer(IndHandle,1,Time[bar],1,iDn)<=0) return(RESET);
         if(CopyOpen(Symbol(),TFrame,Time[bar],1,iOpen)<=0) return(RESET);
         if(CopyLow(Symbol(),TFrame,Time[bar],1,iLow)<=0) return(RESET);
         if(CopyHigh(Symbol(),TFrame,Time[bar],1,iHigh)<=0) return(RESET);
         if(CopyClose(Symbol(),TFrame,Time[bar],1,iClose)<=0) return(RESET);
         //--- 
         double mathmax=MathMax(iOpen[0],iClose[0]);
         double mathmin=MathMin(iOpen[0],iClose[0]);
         //--- 
         if(Sign>0)
           {
            if(iUp[0]>iDn[0])
              {
               ExtA1Buff[bar]=iHigh[0];
               ExtB1Buff[bar]=mathmax;
               ExtA2Buff[bar]=mathmax;
               ExtB2Buff[bar]=mathmin;
               ExtA3Buff[bar]=mathmin;
               ExtB3Buff[bar]=iLow[0];
               Trend=+1;
              }

            if(iUp[0]<iDn[0])
              {
               ExtB1Buff[bar]=iHigh[0];
               ExtA1Buff[bar]=mathmax;
               ExtB2Buff[bar]=mathmax;
               ExtA2Buff[bar]=mathmin;
               ExtB3Buff[bar]=mathmin;
               ExtA3Buff[bar]=iLow[0];
               Trend=-1;
              }

            if(iUp[0]==iDn[0])
              {
               if(Trend>0)
                 {
                  ExtA1Buff[bar]=iHigh[0];
                  ExtB1Buff[bar]=mathmax;
                  ExtA2Buff[bar]=mathmax;
                  ExtB2Buff[bar]=mathmin;
                  ExtA3Buff[bar]=mathmin;
                  ExtB3Buff[bar]=iLow[0];
                 }

               if(Trend<0)
                 {
                  ExtB1Buff[bar]=iHigh[0];
                  ExtA1Buff[bar]=mathmax;
                  ExtB2Buff[bar]=mathmax;
                  ExtA2Buff[bar]=mathmin;
                  ExtB3Buff[bar]=mathmin;
                  ExtA3Buff[bar]=iLow[0];
                 }

              }

            ExtA4Buff[bar]=EMPTYVALUE;
            ExtB4Buff[bar]=EMPTYVALUE;
            ExtA5Buff[bar]=EMPTYVALUE;
            ExtB5Buff[bar]=EMPTYVALUE;
            ExtA6Buff[bar]=EMPTYVALUE;
            ExtB6Buff[bar]=EMPTYVALUE;
           }
         else
           {
            if(iUp[0]>iDn[0])
              {
               ExtA4Buff[bar]=iHigh[0];
               ExtB4Buff[bar]=mathmax;
               ExtA5Buff[bar]=mathmax;
               ExtB5Buff[bar]=mathmin;
               ExtA6Buff[bar]=mathmin;
               ExtB6Buff[bar]=iLow[0];
               Trend=+1;
              }

            if(iUp[0]<iDn[0])
              {
               ExtB4Buff[bar]=iHigh[0];
               ExtA4Buff[bar]=mathmax;
               ExtB5Buff[bar]=mathmax;
               ExtA5Buff[bar]=mathmin;
               ExtB6Buff[bar]=mathmin;
               ExtA6Buff[bar]=iLow[0];
               Trend=-1;
              }

            if(iUp[0]==iDn[0])
              {
               if(Trend>0)
                 {
                  ExtA4Buff[bar]=iHigh[0];
                  ExtB4Buff[bar]=mathmax;
                  ExtA5Buff[bar]=mathmax;
                  ExtB5Buff[bar]=mathmin;
                  ExtA6Buff[bar]=mathmin;
                  ExtB6Buff[bar]=iLow[0];
                 }

               if(Trend<0)
                 {
                  ExtB4Buff[bar]=iHigh[0];
                  ExtA4Buff[bar]=mathmax;
                  ExtB5Buff[bar]=mathmax;
                  ExtA5Buff[bar]=mathmin;
                  ExtB6Buff[bar]=mathmin;
                  ExtA6Buff[bar]=iLow[0];
                 }
              }

            ExtA1Buff[bar]=EMPTYVALUE;
            ExtB1Buff[bar]=EMPTYVALUE;
            ExtA2Buff[bar]=EMPTYVALUE;
            ExtB2Buff[bar]=EMPTYVALUE;
            ExtA3Buff[bar]=EMPTYVALUE;
            ExtB3Buff[bar]=EMPTYVALUE;
           }
        }
      else
        {
         int bar1=bar+1;
         ExtA1Buff[bar]=ExtA1Buff[bar1];
         ExtB1Buff[bar]=ExtB1Buff[bar1];
         ExtA2Buff[bar]=ExtA2Buff[bar1];
         ExtB2Buff[bar]=ExtB2Buff[bar1];
         ExtA3Buff[bar]=ExtA3Buff[bar1];
         ExtB3Buff[bar]=ExtB3Buff[bar1];
         ExtA4Buff[bar]=ExtA4Buff[bar1];
         ExtB4Buff[bar]=ExtB4Buff[bar1];
         ExtA5Buff[bar]=ExtA5Buff[bar1];
         ExtB5Buff[bar]=ExtB5Buff[bar1];
         ExtA6Buff[bar]=ExtA6Buff[bar1];
         ExtB6Buff[bar]=ExtB6Buff[bar1];
        }
     }
//---     
   return(true);
  }
//+------------------------------------------------------------------+
//| PlotInit()                                                       |
//+------------------------------------------------------------------+    
void PlotInit(uint PlotNumber,
              int DrawBegin,
              int PlotShift)
  {
//--- îñóùåñòâëåíèå ñäâèãà íà÷àëà îòñ÷¸òà îòðèñîâêè èíäèêàòîðà
   PlotIndexSetInteger(PlotNumber,PLOT_DRAW_BEGIN,DrawBegin);
//--- îñóùåñòâëåíèå ñäâèãà èíäèêàòîðà 1 ïî ãîðèçîíòàëè íà Shift
   PlotIndexSetInteger(PlotNumber,PLOT_SHIFT,PlotShift);
//---
  }
//+------------------------------------------------------------------+
//| ArrayInit()                                                      |
//+------------------------------------------------------------------+    
void ArrayInit(uint ArrNumber,
               double &Array[])
  {
//--- ïðåâðàùåíèå äèíàìè÷åñêîãî ìàññèâà â èíäèêàòîðíûé áóôåð
   SetIndexBuffer(ArrNumber,Array,INDICATOR_DATA);
//--- èíäåêñàöèÿ ýëåìåíòîâ â áóôåðå êàê â òàéìñåðèè
   ArraySetAsSeries(Array,true);
//---
  }
//+------------------------------------------------------------------+
//| TimeFramesCheck()                                                |
//+------------------------------------------------------------------+    
bool TimeFramesCheck(string IndName,
                     ENUM_TIMEFRAMES TFrame) //Ïåðèîä ãðàôèêà èíäèêàòîðà
  {
//--- ïðîâåðêà ïåðèîäîâ ãðàôèêîâ íà êîððåêòíîñòü
   if(TFrame<Period() && TFrame!=PERIOD_CURRENT)
     {
      Print("Ïåðèîä ãðàôèêà äëÿ èíäèêàòîðà "+IndName+" íå ìîæåò áûòü ìåíüøå ïåðèîäà òåêóùåãî ãðàôèêà!");
      Print("Ñëåäóåò èçìåíèòü âõîäíûå ïàðàìåòðû èíäèêàòîðà!");
      return(RESET);
     }
//---
   return(true);
  }
//+------------------------------------------------------------------+