AO Three Patterns

ÿþ//+------------------------------------------------------------------+

//|                                            AO Three Patterns.mq5 |

//|                              Copyright © 2020, Vladimir Karputov |

//|                     https://www.mql5.com/ru/market/product/43516 |

//+------------------------------------------------------------------+

#property copyright "Copyright © 2020, Vladimir Karputov"

#property link      "https://www.mql5.com/ru/market/product/43516"

#property version   "1.000"

#property indicator_separate_window

#property indicator_buffers 8

#property indicator_plots   7

//--- bars minimum for calculation

#define DATA_LIMIT 33

//--- plot AO

#property indicator_label1  "AO"

#property indicator_type1   DRAW_COLOR_HISTOGRAM

#property indicator_color1  clrLimeGreen,clrRed

#property indicator_style1  STYLE_SOLID

#property indicator_width1  2

//--- plot BuySaucer

#property indicator_label2  "Buy Saucer"

#property indicator_type2   DRAW_ARROW

#property indicator_color2  clrBlue

#property indicator_style2  STYLE_SOLID

#property indicator_width2  1

//--- plot BuyCrossing

#property indicator_label3  "Buy Crossing"

#property indicator_type3   DRAW_ARROW

#property indicator_color3  clrBlue

#property indicator_style3  STYLE_SOLID

#property indicator_width3  1

//--- plot BuyTwin

#property indicator_label4  "Buy Twin"

#property indicator_type4   DRAW_ARROW

#property indicator_color4  clrBlue

#property indicator_style4  STYLE_SOLID

#property indicator_width4  1

//--- plot SellSaucer

#property indicator_label5  "Sell Saucer"

#property indicator_type5   DRAW_ARROW

#property indicator_color5  clrRed

#property indicator_style5  STYLE_SOLID

#property indicator_width5  1

//--- plot SellCrossing

#property indicator_label6  "Sell Crossing"

#property indicator_type6   DRAW_ARROW

#property indicator_color6  clrRed

#property indicator_style6  STYLE_SOLID

#property indicator_width6  1

//--- plot SellTwin

#property indicator_label7  "Sell Twin"

#property indicator_type7   DRAW_ARROW

#property indicator_color7  clrRed

#property indicator_style7  STYLE_SOLID

#property indicator_width7  1

//--- input parameters

input group             "Buy Saucer"

input uchar    InpBuySaucerCode        = 241;            // Buy Saucer: Arrow code (font Wingdings)

input int      InpBuySaucerShift       = -10;            // Buy Saucer: Vertical shift of arrows in pixel

input group             "Buy Crossing"

input uchar    InpBuyCrossingCode      = 225;            // Buy Crossing: Arrow code (font Wingdings)

input int      InpBuyCrossingShift     = -10;            // Buy Crossing: Vertical shift of arrows in pixel

input group             "Buy Twin"

input uchar    InpBuyTwinCode          = 233;            // Buy Twin: Arrow code (font Wingdings)

input int      InpBuyTwinShift         = 10;             // Buy Twin: Vertical shift of arrows in pixel

input group             "Sell Saucer"

input uchar    InpSellSaucerCode       = 242;            // Sell Saucer: Arrow code (font Wingdings)

input int      InpSellSaucerShift      = 10;             // Sell Saucer: Vertical shift of arrows in pixel

input group             "Sell Crossing"

input uchar    InpSellCrossingCode     = 226;            // Sell Crossing: Arrow code (font Wingdings)

input int      InpSellCrossingShift    = 10;             // Sell Crossing: Vertical shift of arrows in pixel

input group             "Sell Twin"

input uchar    InpSellTwinCode         = 234;            // Sell Twin: Arrow code (font Wingdings)

input int      InpSellTwinShift        = -10;            // Sell Twin: Vertical shift of arrows in pixel

//--- indicator buffers

double   AOBuffer[];

double   AOColors[];

double   BuySaucerBuffer[];

double   BuyCrossingBuffer[];

double   BuyTwinBuffer[];

double   SellSaucerBuffer[];

double   SellCrossingBuffer[];

double   SellTwinBuffer[];

//---

int      handle_iAO;                                     // variable for storing the handle of the iAO indicator

int      bars_calculated=0;                              // we will keep the number of values in the Awesome Oscillator indicator

datetime m_prev_bars=0;                                  // "0" -> D'1970.01.01 00:00';

//+------------------------------------------------------------------+

//| Custom indicator initialization function                         |

//+------------------------------------------------------------------+

int OnInit()

  {

//--- indicator buffers mapping

   SetIndexBuffer(0,AOBuffer,INDICATOR_DATA);

   SetIndexBuffer(1,AOColors,INDICATOR_COLOR_INDEX);

   SetIndexBuffer(2,BuySaucerBuffer,INDICATOR_DATA);

   SetIndexBuffer(3,BuyCrossingBuffer,INDICATOR_DATA);

   SetIndexBuffer(4,BuyTwinBuffer,INDICATOR_DATA);

   SetIndexBuffer(5,SellSaucerBuffer,INDICATOR_DATA);

   SetIndexBuffer(6,SellCrossingBuffer,INDICATOR_DATA);

   SetIndexBuffer(7,SellTwinBuffer,INDICATOR_DATA);

//--- setting a code from the Wingdings charset as the property of PLOT_ARROW

   PlotIndexSetInteger(1,PLOT_ARROW,InpBuySaucerCode);

   PlotIndexSetInteger(2,PLOT_ARROW,InpBuyCrossingCode);

   PlotIndexSetInteger(3,PLOT_ARROW,InpBuyTwinCode);

   PlotIndexSetInteger(4,PLOT_ARROW,InpSellSaucerCode);

   PlotIndexSetInteger(5,PLOT_ARROW,InpSellCrossingCode);

   PlotIndexSetInteger(6,PLOT_ARROW,InpSellTwinCode);

//--- set the vertical shift of arrows in pixels

   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,InpBuySaucerShift);

   PlotIndexSetInteger(2,PLOT_ARROW_SHIFT,InpBuyCrossingShift);

   PlotIndexSetInteger(3,PLOT_ARROW_SHIFT,InpBuyTwinShift);

   PlotIndexSetInteger(4,PLOT_ARROW_SHIFT,InpSellSaucerShift);

   PlotIndexSetInteger(5,PLOT_ARROW_SHIFT,InpSellCrossingShift);

   PlotIndexSetInteger(6,PLOT_ARROW_SHIFT,InpSellTwinShift);

//--- set as an empty value 0.0

   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,EMPTY_VALUE);

   PlotIndexSetDouble(1,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(2,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(3,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(4,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(5,PLOT_EMPTY_VALUE,0.0);

   PlotIndexSetDouble(6,PLOT_EMPTY_VALUE,0.0);

//--- create handle of the indicator iAO

   handle_iAO=iAO(Symbol(),Period());

//--- if the handle is not created

   if(handle_iAO==INVALID_HANDLE)

     {

      //--- tell about the failure and output the error code

      PrintFormat("Failed to create handle of the iAO indicator for the symbol %s/%s, error code %d",

                  Symbol(),

                  EnumToString(Period()),

                  GetLastError());

      //--- the indicator is stopped early

      return(INIT_FAILED);

     }

//---

   return(INIT_SUCCEEDED);

  }

//+------------------------------------------------------------------+

//| Custom indicator iteration function                              |

//+------------------------------------------------------------------+

int OnCalculate(const int rates_total,

                const int prev_calculated,

                const datetime &time[],

                const double &open[],

                const double &high[],

                const double &low[],

                const double &close[],

                const long &tick_volume[],

                const long &volume[],

                const int &spread[])

  {

//--- check for rates total

   if(rates_total<=DATA_LIMIT)

      return(0);// not enough bars for calculation

//--- number of values copied from the iAO indicator

   int values_to_copy;

//--- determine the number of values calculated in the indicator

   int calculated=BarsCalculated(handle_iAO);

   if(calculated<=0)

     {

      PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());

      return(0);

     }

//--- if it is the first start of calculation of the indicator or if the number of values in the iAO indicator changed

//---or if it is necessary to calculated the indicator for two or more bars (it means something has changed in the price history)

   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)

     {

      //--- if the iAOBuffer array is greater than the number of values in the iAO indicator for symbol/period, then we don't copy everything

      //--- otherwise, we copy less than the size of indicator buffers

      if(calculated>rates_total)

         values_to_copy=rates_total;

      else

         values_to_copy=calculated;

     }

   else

     {

      //--- it means that it's not the first time of the indicator calculation, and since the last call of OnCalculate()

      //--- for calculation not more than one bar is added

      values_to_copy=(rates_total-prev_calculated)+1;

     }

//--- fill the iAOBuffer and iAOColors arrays with values from the Awesome Oscillator indicator

//--- if FillArraysFromBuffer returns false, it means the information is nor ready yet, quit operation

   if(!FillArraysFromBuffer(AOBuffer,AOColors,handle_iAO,values_to_copy))

      return(0);

////--- form the message

//   string comm=StringFormat("%s ==>  Updated value in the indicator %d",

//                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),

//                            values_to_copy);

////--- display the service message on the chart

//   Comment(comm);

//--- memorize the number of values in the Awesome Oscillator indicator

   bars_calculated=calculated;

//--- main loop

   int limit=prev_calculated-1;

   if(prev_calculated==0)

     {

      limit=DATA_LIMIT;

      for(int i=0; i<limit; i++)

        {

         BuySaucerBuffer[i]=0.0;

         BuyCrossingBuffer[i]=0.0;

         BuyTwinBuffer[i]=0.0;

         SellSaucerBuffer[i]=0.0;

         SellCrossingBuffer[i]=0.0;

         SellTwinBuffer[i]=0.0;

        }

     }

   for(int i=rates_total-1; i>=limit; i--)

     {

      BuySaucerBuffer[i]=0.0;

      BuyCrossingBuffer[i]=0.0;

      BuyTwinBuffer[i]=0.0;

      SellSaucerBuffer[i]=0.0;

      SellCrossingBuffer[i]=0.0;

      SellTwinBuffer[i]=0.0;

      //--- Buy Saucer

      if(AOBuffer[i-1]>0.0 && AOBuffer[i-2]>0.0 && AOBuffer[i-3]>0.0)

         if(AOBuffer[i-1]>AOBuffer[i-2] && AOBuffer[i-2]<AOBuffer[i-3])

           {

            BuySaucerBuffer[i]=AOBuffer[i];

            continue;

           }

      //--- Buy Crossing

      if(AOBuffer[i-1]>0.0 && AOBuffer[i-2]<0.0)

        {

         BuyCrossingBuffer[i]=AOBuffer[i];

         continue;

        }

      //--- Buy Twin

      if(AOBuffer[i-1]<0.0 && AOBuffer[i-2]<0.0 && AOBuffer[i-3]<0.0)

         if(AOBuffer[i-1]>AOBuffer[i-2] && AOBuffer[i-2]<AOBuffer[i-3])

           {

            for(int j=i-3; j>=limit; j--)

              {

               if(AOBuffer[j]>=0.0)

                  break;

               if(AOBuffer[j-1]>AOBuffer[j-2] && AOBuffer[j-2]<AOBuffer[j-3])

                 {

                  if(AOBuffer[j-2]<AOBuffer[i-2])

                    {

                     BuyTwinBuffer[i]=AOBuffer[i];

                     continue;

                    }

                  else

                     break;

                 }

              }

           }

      //--- Sell Saucer

      if(AOBuffer[i-1]<0.0 && AOBuffer[i-2]<0.0 && AOBuffer[i-3]<0.0)

         if(AOBuffer[i-1]<AOBuffer[i-2] && AOBuffer[i-2]>AOBuffer[i-3])

           {

            SellSaucerBuffer[i]=AOBuffer[i];

            continue;

           }

      //--- Sell Crossing

      if(AOBuffer[i-1]<0.0 && AOBuffer[i-2]>0.0)

        {

         SellCrossingBuffer[i]=AOBuffer[i];

         continue;

        }

      //--- Sell Twin

      if(AOBuffer[i-1]>0.0 && AOBuffer[i-2]>0.0 && AOBuffer[i-3]>0.0)

         if(AOBuffer[i-1]<AOBuffer[i-2] && AOBuffer[i-2]>AOBuffer[i-3])

           {

            for(int j=i-3; j>=limit; j--)

              {

               if(AOBuffer[j]<0.0)

                  break;

               if(AOBuffer[j-1]<AOBuffer[j-2] && AOBuffer[j-2]>AOBuffer[j-3])

                 {

                  if(AOBuffer[j-2]<AOBuffer[i-2])

                    {

                     SellTwinBuffer[i]=AOBuffer[i];

                     continue;

                    }

                  else

                     break;

                 }

              }

           }

     }

//--- return value of prev_calculated for next call

   return(rates_total);

  }

//+------------------------------------------------------------------+

//| Filling indicator buffers from the iAO indicator                 |

//+------------------------------------------------------------------+

bool FillArraysFromBuffer(double &values[],        // indicator buffer of Awesome Oscillator values

                          double &color_indexes[], // color buffer (for storing of color indexes)

                          int ind_handle,          // handle of the iAO indicator

                          int amount               // number of copied values

                         )

  {

//--- reset error code

   ResetLastError();

//--- fill a part of the iAOBuffer array with values from the indicator buffer that has 0 index

   if(CopyBuffer(ind_handle,0,0,amount,values)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy data from the iAO indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- now copy the indexes of colors

   if(CopyBuffer(ind_handle,1,0,amount,color_indexes)<0)

     {

      //--- if the copying fails, tell the error code

      PrintFormat("Failed to copy color values from the iAO indicator, error code %d",GetLastError());

      //--- quit with zero result - it means that the indicator is considered as not calculated

      return(false);

     }

//--- everything is fine

   return(true);

  }

//+------------------------------------------------------------------+

//| Indicator deinitialization function                              |

//+------------------------------------------------------------------+

void OnDeinit(const int reason)

  {

   if(handle_iAO!=INVALID_HANDLE)

      IndicatorRelease(handle_iAO);

////--- clear the chart after deleting the indicator

//   Comment("");

  }

//+------------------------------------------------------------------+